วิธีการเขียนสคริปต์ที่คาดว่าจะติดตั้ง mariadb?

สภาพแวดล้อม: centos7 + mariadb5.5.64 ผมขอแสดงข้อมูลการติดตั้งบนหน้าจอเมื่อมีการเรียกใช้
mysql_secure_installation

# mysql_secure_installation

NOTE: RUNNING ALL PARTS OF THIS SCRIPT IS RECOMMENDED FOR ALL MariaDB
      SERVERS IN PRODUCTION USE!  PLEASE READ EACH STEP CAREFULLY!

In order to log into MariaDB to secure it, we'll need the current
password for the root user.  If you've just installed MariaDB, and
you haven't set the root password yet, the password will be blank,
so you should just press enter here.

Enter current password for root (enter for none): 
OK, successfully used password, moving on...

Setting the root password ensures that nobody can log into the MariaDB
root user without the proper authorisation.

Set root password? [Y/n] y
New password: 
Re-enter new password: 
Password updated successfully!
Reloading privilege tables..
 ... Success!


By default, a MariaDB installation has an anonymous user, allowing anyone
to log into MariaDB without having to have a user account created for
them.  This is intended only for testing, and to make the installation
go a bit smoother.  You should remove them before moving into a
production environment.

Remove anonymous users? [Y/n] y
 ... Success!

Normally, root should only be allowed to connect from 'localhost'.  This
ensures that someone cannot guess at the root password from the network.

Disallow root login remotely? [Y/n] y
 ... Success!

By default, MariaDB comes with a database named 'test' that anyone can
access.  This is also intended only for testing, and should be removed
before moving into a production environment.

Remove test database and access to it? [Y/n] y
 - Dropping test database...
 ... Success!
 - Removing privileges on test database...
 ... Success!

Reloading the privilege tables will ensure that all changes made so far
will take effect immediately.

Reload privilege tables now? [Y/n] y
 ... Success!

Cleaning up...

All done!  If you've completed all of the above steps, your MariaDB
installation should now be secure.

Thanks for using MariaDB!

ฉันเขียนสคริปต์อัตโนมัติคาดหวังว่าจะติดตั้ง mariadb

  vim secure.exp
  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? [Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? [Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? [Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? [Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? [Y/n]" {send "y\r";exp_continue}
  }

เพื่อรัน/usr/bin/expect secure.expฉันพบข้อผิดพลาด:

spawn mysql_secure_installation
invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
          "Enter current password for root (enter for none): " {send "\r";exp_continue}
          "Set root password? [Y/n] " {send "y\r";exp..."
    (file "secure.exp" line 3)

มันไม่มีประโยชน์ที่จะเขียนดังต่อไปนี้:

  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? \\[Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? \\[Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? \\[Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? \\[Y/n]" {send "y\r";exp_continue}
  }

ข้อผิดพลาดเดียวกัน:

invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_conti..."
    (file "secure.exp" line 3)

จะแก้ไขสคริปต์ exp ของฉันได้อย่างไร?

สคริปต์เหล่านี้รอที่จะได้รับผลลัพธ์ที่เลือกได้ ( timeout -1หมายถึง "ไม่มีหมดเวลา") และพวกเขาสามารถบอกการตอบสนองที่แตกต่างกันในขณะที่มันถูกต้องตามและyum install mysql_secure_installationด้วยการ#!/bin/expect -fเป็น shebang chmod +xสคริปต์นี้จะสามารถดำเนินการได้เมื่อพวกเขาถูกกำหนดให้

A) ในการเริ่มต้นด้วย, mariadb_yum.exp(ต้องการsuหรือsudo):

#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
    exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"

spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id

# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
   exp_send "$PASSWORD\r"
}

expect {
    # when the package was already installed
    -ex "Nothing to do" {
        send_user "package was already installed\n"
    }
    # when the package had been installed
    -ex "Complete!" {
        send_user "package had been installed\n"
    }
}

expect eof
close $yum_spawn_id
exit 0

B) แล้วmariadb_sec.exp(ไม่จำเป็นsudo):

#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
    exit 1
}
set PASSWORD [lindex $argv 0];

spawn mysql_secure_installation
set mysql_spawn_id $spawn_id

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"

# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"

expect {
    # await an eventual error message
    -ex "ERROR 1045" {
        send_user "\nMariaDB > An invalid root password had been provided.\n"
        close $mysql_spawn_id
        exit 1
    }
    # when there is a root password set
    -ex "Change the root password? \[Y/n\] " {
        exp_send "n\r"
    }
    # when there is no root password set (could not test this branch).
    -ex "Set root password? \[Y/n\] " {
        exp_send "Y\r"
        expect -ex "New password: "
        exp_send "$PASSWORD\r"
        expect -ex "Re-enter new password: "
        exp_send "$PASSWORD\r"
    }
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"

expect eof
close $mysql_spawn_id
exit 0

สำหรับจุดประสงค์ในการดีบั๊ก - หรือเพื่อตรวจสอบคำตอบหนึ่งสามารถทำงานexpectกับระดับstrace 4บันทึก นี่อาจเป็นที่เชื่อถือได้ในฐานะที่เป็นแหล่งที่มาเมื่อมันมาถึงการเขียนexpectสคริปต์เพราะมันแสดงให้เห็นอย่างชัดเจนว่าเกิดอะไรขึ้นและที่สำคัญที่สุดคือสิ่งที่เกิดขึ้น:

expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]

คำสั่งset exp_internal 1สามารถใช้เพื่อรับเอาต์พุตสำหรับการจับคู่ regex

แหล่งที่มาของความสับสนที่อาจเกิดขึ้นได้คือที่หนึ่งเกิดกระบวนการ - เป็นหนึ่งสามารถวางไข่หลายกระบวนการในโฮสต์ต่างๆเช่น sshในพื้นที่แล้วyumและmysql_secure_installationจากระยะไกล เพิ่ม$spawn_idไปยังสคริปต์; การcloseเรียกหนึ่งบรรทัดล่างอาจซ้ำซ้อนเนื่องจากมีอยู่แล้วEOF(เพื่อแสดงวิธีการspawn& closeกระบวนการ):

Thanks for using MariaDB!
 1  close $mysql_spawn_id
 1  exit 0
 2  rename _close.pre_expect close

สรุป: mariadb_sec.expสคริปต์อาจปรับปรุงได้อีกเช่น เมื่อครั้งแรกที่ไม่มีการส่งรหัสผ่านและดูว่าเกิดอะไรขึ้น - จากนั้นส่งรหัสผ่านไปที่ERROR 1045(เมื่อตั้งรหัสผ่านไว้แล้วก่อนหน้านี้) มันอาจจะประหยัดที่จะสมมติว่ามีการตั้งรหัสผ่านเมื่อเซิร์ฟเวอร์เพิ่งได้รับการติดตั้ง (ยกเว้นที่yum reinstallส่งผลลัพธ์เดียวกัน) เพิ่งไม่มีคอนเทนเนอร์ CentOS ที่ว่างเปล่าเพื่อทดสอบทุกกรณี หากไม่ได้ทำงานในrootเชลล์การส่งรหัสผ่านทั้งสองประเภทไปยังสคริปต์เดียวจะต้องดำเนินการนี้โดยอัตโนมัติจากการติดตั้งจนกว่าจะทำการติดตั้งภายหลัง

น่าจะเป็นที่น่าสังเกตว่าใน GCE sudoจะไม่ขอรหัสผ่าน; มีความแตกต่างเล็กน้อยตามสภาพแวดล้อมเนื่องจากอิมเมจคอนเทนเนอร์ CentOS เหล่านี้ทำงานแตกต่างกัน ในกรณีเช่นนี้ (เนื่องจากไม่มีsuหรือไม่มีการตรวจจับภาพคอนเทนเนอร์) mariadb_yum.expสคริปต์อาจค้างในไม่30กี่วินาทีแล้วดำเนินการต่อ

ส่วนใหญ่แหล่งที่มีชื่อเสียงฉันสามารถให้เป็นexpectคู่มือการเขียนโดยดอนลเบส์ @ NIST และคู่มือ TCL / TK สำหรับexpectพร้อมด้วยนั้นโครงการ SourceForge expectเรียกว่าบังเอิญ

ไม่เพียง แต่เป็นวงเล็บเหลี่ยมที่ใช้สำหรับการทดแทนคำสั่งเท่านั้น แต่ยังมีความพิเศษสำหรับรูปแบบ globด้วย

คุณสามารถใช้-exactสวิตช์ในขณะที่หลีกเลี่ยงวงเล็บเหลี่ยมในเครื่องหมายคำพูด:

spawn mysql_secure_installation
expect {
    ...
    -exact "Set root password? \[Y/n\] " {send "y\r";exp_continue}
    ...
}

หรือใช้เครื่องมือจัดฟันแทนที่จะใส่เครื่องหมายคำพูด:

spawn mysql_secure_installation
expect {
    ...
    {Set root password? \[Y/n\] } {send "y\r";exp_continue}
    ...
}

FYI คุณสามารถสร้างสคริปต์คาดหวังให้กับคุณโดยใช้autoexpect:

autoexpect ./mysql_secure_installation

สิ่งนี้จะสร้างสคริปต์คาดหวังที่เรียกว่าscript.expในไดเรกทอรีการทำงานปัจจุบันของคุณ