ไม่กี่ปีที่ผ่านมาคำถาม แต่ฉันต้องการสิ่งนี้เพื่อสร้างรหัสที่รวดเร็วและสกปรก ฉันเชื่อว่าคนอื่น ๆ ระบุว่ามันง่ายกว่าที่จะกำหนดตารางอุณหภูมิไว้ข้างหน้า แต่วิธีนี้ควรใช้สำหรับการค้นหาโพรซีเดอร์ที่เก็บไว้อย่างง่ายหรือ statments sql
สิ่งนี้จะซับซ้อนเล็กน้อย แต่ยืมมาจากผู้สนับสนุนที่นี่รวมถึงโซลูชันของ Paul White จาก DBA Stack Exchange รับคอลัมน์ผลลัพธ์ประเภทกระบวนงานที่เก็บไว้รับการจัดเก็บผลขั้นตอนคอลัมน์ประเภทอีกครั้งเพื่อย้ำแนวทางและตัวอย่างนี้ไม่ได้ออกแบบมาสำหรับกระบวนการในสภาพแวดล้อมผู้ใช้หลายคน ในกรณีนี้การกำหนดตารางจะถูกกำหนดเป็นเวลาสั้น ๆ ในตารางชั่วคราวทั่วโลกสำหรับการอ้างอิงโดยกระบวนการแม่แบบการสร้างรหัส
ฉันยังไม่ได้ทดสอบอย่างเต็มที่ดังนั้นอาจมีข้อควรระวังดังนั้นคุณอาจต้องการไปที่ลิงก์ MSDN ในคำตอบของ Paul White สิ่งนี้ใช้กับ SQL 2012 และสูงกว่า
ขั้นแรกให้ใช้กระบวนงานที่เก็บไว้sp_describe_first_result_setซึ่งคล้ายกับคำอธิบายของ Oracle
การดำเนินการนี้จะประเมินแถวแรกของชุดผลลัพธ์แรกดังนั้นหากขั้นตอนหรือคำสั่งที่เก็บไว้ของคุณส่งคืนแบบสอบถามจำนวนมากมันจะอธิบายผลลัพธ์แรกเท่านั้น
ฉันสร้าง proc ที่เก็บไว้เพื่อแยกย่อยงานที่ส่งกลับเขตข้อมูลเดียวเพื่อเลือกจากเพื่อสร้างข้อกำหนดของตาราง temp
CREATE OR ALTER PROCEDURE [dbo].[sp_GetTableDefinitionFromSqlBatch_DescribeFirstResultSet]
(
@sql NVARCHAR(4000)
,@table_name VARCHAR(100)
,@TableDefinition NVARCHAR(MAX) OUTPUT
)
AS
BEGIN
SET NOCOUNT ON
DECLARE @TempTableDefinition NVARCHAR(MAX)
DECLARE @NewLine NVARCHAR(4) = CHAR(13)+CHAR(10)
DECLARE @ResultDefinition TABLE ( --The View Definition per MSDN
is_hidden bit NOT NULL
, column_ordinal int NOT NULL
, [name] sysname NULL
, is_nullable bit NOT NULL
, system_type_id int NOT NULL
, system_type_name nvarchar(256) NULL
, max_length smallint NOT NULL
, [precision] tinyint NOT NULL
, scale tinyint NOT NULL
, collation_name sysname NULL
, user_type_id int NULL
, user_type_database sysname NULL
, user_type_schema sysname NULL
, user_type_name sysname NULL
, assembly_qualified_type_name nvarchar(4000)
, xml_collection_id int NULL
, xml_collection_database sysname NULL
, xml_collection_schema sysname NULL
, xml_collection_name sysname NULL
, is_xml_document bit NOT NULL
, is_case_sensitive bit NOT NULL
, is_fixed_length_clr_type bit NOT NULL
, source_server sysname NULL
, source_database sysname NULL
, source_schema sysname NULL
, source_table sysname NULL
, source_column sysname NULL
, is_identity_column bit NULL
, is_part_of_unique_key bit NULL
, is_updateable bit NULL
, is_computed_column bit NULL
, is_sparse_column_set bit NULL
, ordinal_in_order_by_list smallint NULL
, order_by_is_descending smallint NULL
, order_by_list_length smallint NULL
, tds_type_id int NOT NULL
, tds_length int NOT NULL
, tds_collation_id int NULL
, tds_collation_sort_id tinyint NULL
)
--Insert the description into table variable
INSERT @ResultDefinition
EXEC sp_describe_first_result_set @sql
--Now Build the string to create the table via union select statement
;WITH STMT AS (
SELECT N'CREATE TABLE ' + @table_name + N' (' AS TextVal
UNION ALL
SELECT
CONCAT(
CASE column_ordinal
WHEN 1 THEN ' ' ELSE ' , ' END --Determines if comma should precede
, QUOTENAME([name]) , ' ', system_type_name -- Column Name and SQL TYPE
,CASE is_nullable
WHEN 0 THEN ' NOT NULL' ELSE ' NULL' END --NULLABLE CONSTRAINT
) AS TextVal
FROM @ResultDefinition WHERE is_hidden = 0 -- May not be needed
UNION ALL
SELECT N');' + @NewLine
)
--Now Combine the rows to a single String
SELECT @TempTableDefinition = COALESCE (@TempTableDefinition + @NewLine + TextVal, TextVal) FROM STMT
SELECT @TableDefinition = @TempTableDefinition
END
ปริศนาคือคุณต้องใช้ตารางทั่วโลก แต่คุณต้องทำให้มันไม่ซ้ำกันเพื่อให้คุณสามารถวางและสร้างจากมันบ่อยครั้งโดยไม่ต้องกังวลเกี่ยวกับการปะทะกัน
ในตัวอย่างฉันใช้ Guid (FE264BF5_9C32_438F_8462_8A5DC8DEE49E) สำหรับตัวแปรโกลบอลแทนที่ยัติภังค์ด้วยขีดล่าง
DECLARE @sql NVARCHAR(4000) = N'SELECT @@SERVERNAME as ServerName, GETDATE() AS Today;'
DECLARE @GlobalTempTable VARCHAR(100) = N'##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable'
--@sql can be a stored procedure name like dbo.foo without parameters
DECLARE @TableDef NVARCHAR(MAX)
DROP TABLE IF EXISTS #MyTempTable
DROP TABLE IF EXISTS ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
EXEC [dbo].[sp_GetTableDefinitionFromSqlBatch_DescribeFirstResultSet]
@sql, @GlobalTempTable, @TableDef OUTPUT
--Creates the global table ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
EXEC sp_executesql @TableDef
--Now Call the stored procedure, SQL Statement with Params etc.
INSERT ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
EXEC sp_executesql @sql
--Select the results into your undefined Temp Table from the Global Table
SELECT *
INTO #MyTempTable
FROM ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
SELECT * FROM #MyTempTable
DROP TABLE IF EXISTS #MyTempTable
DROP TABLE IF EXISTS ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
อีกครั้งฉันได้ทดสอบเฉพาะกับแบบสอบถามขั้นตอนการจัดเก็บง่ายและแบบสอบถามง่ายๆเพื่อให้ระยะของคุณอาจแตกต่างกันไป หวังว่านี่จะช่วยใครซักคน
