Dim wkbkdestination As Workbook
Dim destsheet As Worksheet

For Each ThisWorkSheet In wkbkorigin.Worksheets 
    'this throws subscript out of range if there is not a sheet in the destination 
    'workbook that has the same name as the current sheet in the origin workbook.
    Set destsheet = wkbkdestination.Worksheets(ThisWorkSheet.Name) 
Next

โดยทั่วไปฉันวนซ้ำแผ่นงานทั้งหมดในสมุดงานต้นทางจากนั้นตั้งค่าdestsheetในสมุดงานปลายทางเป็นแผ่นงานที่มีชื่อเดียวกันกับแผ่นงานที่ทำซ้ำในปัจจุบันในสมุดงานต้นทาง

ฉันจะทดสอบได้อย่างไรว่ามีแผ่นงานนั้นอยู่ สิ่งที่ต้องการ:

If wkbkdestination.Worksheets(ThisWorkSheet.Name) Then 

ชาวบ้านบางคนไม่ชอบแนวทางนี้เนื่องจากการใช้การจัดการข้อผิดพลาดที่ "ไม่เหมาะสม" แต่ฉันคิดว่าถือว่าเป็นที่ยอมรับใน VBA ... อีกทางเลือกหนึ่งคือการวนซ้ำแผ่นงานทั้งหมดจนกว่าคุณจะพบรายการที่ตรงกัน

Function WorksheetExists(shtName As String, Optional wb As Workbook) As Boolean
    Dim sht As Worksheet

    If wb Is Nothing Then Set wb = ThisWorkbook
    On Error Resume Next
    Set sht = wb.Sheets(shtName)
    On Error GoTo 0
    WorksheetExists = Not sht Is Nothing
End Function

หากคุณสนใจเฉพาะในเวิร์กชีตเท่านั้นคุณสามารถใช้การเรียกใช้ Evaluate ง่ายๆ

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Evaluate("ISREF('" & sName & "'!A1)")
End Function

คุณไม่จำเป็นต้องจัดการข้อผิดพลาดเพื่อที่จะทำสิ่งนี้ให้สำเร็จ สิ่งที่คุณต้องทำคือทำซ้ำบนแผ่นงานทั้งหมดและตรวจสอบว่ามีชื่อที่ระบุอยู่หรือไม่:

For i = 1 To Worksheets.Count
    If Worksheets(i).Name = "MySheet" Then
        exists = True
    End If
Next i

If Not exists Then
    Worksheets.Add.Name = "MySheet"
End If

เนื่องจากการตรวจสอบสมาชิกของคอลเล็กชันเป็นปัญหาทั่วไปนี่คือคำตอบของ Tim ที่เป็นนามธรรม:

ฟังก์ชันประกอบด้วย (objCollection As Object, strName as String) เป็น Boolean
    Dim o เป็นวัตถุ
    ใน Error Resume Next
    ตั้งค่า o = objCollection (strName)
    ประกอบด้วย = (Err.Number = 0)
    สิ้นสุด Err.Clear
 สิ้นสุดฟังก์ชัน

ฟังก์ชั่นนี้สามารถใช้กับคอลเลกชันใด ๆ เช่นวัตถุ ( Shapes, Range, Names, Workbooksฯลฯ )

ในการตรวจสอบการมีอยู่ของแผ่นงานให้ใช้ If Contains(Sheets, "SheetName") ...

แก้ไข: ไม่มีการจัดการข้อผิดพลาด:

Function CheckIfSheetExists(SheetName As String) As Boolean
      CheckIfSheetExists = False
      For Each WS In Worksheets
        If SheetName = WS.name Then
          CheckIfSheetExists = True
          Exit Function
        End If
      Next WS
End Function

ในกรณีที่ใครก็ตามต้องการหลีกเลี่ยง VBA และทดสอบว่าเวิร์กชีตมีอยู่ในสูตรของเซลล์หรือไม่สามารถทำได้โดยใช้ฟังก์ชันISREFand INDIRECT:

=ISREF(INDIRECT("SheetName!A1"))

สิ่งนี้จะส่งคืนTRUEหากสมุดงานมีแผ่นงานที่เรียกSheetNameและFALSEอื่น ๆ

ฉันเขียนสิ่งนี้:

Function sheetExist(sSheet As String) As Boolean
On Error Resume Next
sheetExist = (ActiveWorkbook.Sheets(sSheet).Index > 0)
End Function

โซลูชันของฉันดูเหมือน Tims มาก แต่ก็ใช้ได้ในกรณีที่ไม่ใช่แผ่นงาน - แผนภูมิ

Public Function SheetExists(strSheetName As String, Optional wbWorkbook As Workbook) As Boolean
    If wbWorkbook Is Nothing Then Set wbWorkbook = ActiveWorkbook 'or ThisWorkbook - whichever appropriate
    Dim obj As Object
    On Error GoTo HandleError
    Set obj = wbWorkbook.Sheets(strSheetName)
    SheetExists = True
    Exit Function
HandleError:
    SheetExists = False
End Function

.

ทดสอบในฟังก์ชันและคุณจะสามารถใช้ซ้ำได้และคุณจะอ่านโค้ดได้ดีขึ้น

อย่าใช้ "On Error Resume Next" เนื่องจากอาจขัดแย้งกับส่วนอื่น ๆ ของรหัสของคุณ

Sub DoesTheSheetExists()
    If SheetExist("SheetName") Then
        Debug.Print "The Sheet Exists"
    Else
        Debug.Print "The Sheet Does NOT Exists"
    End If
End Sub

Function SheetExist(strSheetName As String) As Boolean
    Dim i As Integer

    For i = 1 To Worksheets.Count
        If Worksheets(i).Name = strSheetName Then
            SheetExist = True
            Exit Function
        End If
    Next i
End Function

หลายปีที่ผ่านมา แต่ฉันต้องทำสิ่งนี้และไม่ชอบวิธีแก้ปัญหาใด ๆ ที่โพสต์ไว้ ... ดังนั้นฉันจึงสร้างขึ้นมาทั้งหมดนี้ต้องขอบคุณความมหัศจรรย์ของ (ท่าทางมือสายรุ้ง SpongeBob) "Evaluate ()"!

Evaluate("IsError(" & vSheetName & "!1:1)")

ส่งคืนค่า TRUE หากไม่มีแผ่นงาน FALSE หากมีแผ่นงานอยู่ คุณสามารถแทนที่ช่วงใดก็ได้ที่คุณต้องการสำหรับ "1: 1" แต่ฉันไม่แนะนำให้ใช้เซลล์เดียวเพราะหากมีข้อผิดพลาด (เช่น # N / A) มันจะส่งคืน True

wsExistsฟังก์ชันกะทัดรัด_{^{( โดยไม่ต้องพึ่งพาการจัดการข้อผิดพลาด!)}}

นี่คือฟังก์ชั่นสั้น ๆ และเรียบง่ายที่ไม่ต้องพึ่งพาการจัดการข้อผิดพลาดเพื่อตรวจสอบว่ามีแผ่นงานอยู่หรือไม่ ( และได้รับการประกาศอย่างเหมาะสมว่าใช้งานได้ในทุกสถานการณ์!)

Function wsExists(wsName As String) As Boolean
    Dim ws: For Each ws In Sheets
    wsExists = (wsName = ws.Name): If wsExists Then Exit Function
    Next ws
End Function

ตัวอย่างการใช้งาน:

ตัวอย่างต่อไปนี้จะเพิ่มเวิร์กชีตใหม่ที่ชื่อmyNewSheetหากยังไม่มี:

If Not wsExists("myNewSheet") Then Sheets.Add.Name = "myNewSheet"

ข้อมูลมากกว่านี้:

• MSDN: For Each… Nextคำชี้แจง (VBA)
• MSDN: Exitคำชี้แจง (VBA)
• MSDN: ตัวดำเนินการเปรียบเทียบ (VBA)

ทำไมไม่ใช้ลูปเล็ก ๆ เพื่อตรวจสอบว่ามีเวิร์กชีตที่ตั้งชื่ออยู่หรือไม่ สมมติว่าคุณกำลังมองหาแผ่นงานชื่อ "Sheet1" ในสมุดงานที่เปิดอยู่

Dim wb as Workbook
Dim ws as Worksheet

Set wb = ActiveWorkbook

For Each ws in wb.Worksheets

    if ws.Name = "Sheet1" then
        'Do something here
    End if

Next

หากคุณเป็นแฟนตัวยงWorksheetFunction.หรือทำงานจากประเทศที่ไม่ใช่ภาษาอังกฤษโดยใช้ Excel ที่ไม่ใช่ภาษาอังกฤษนี่เป็นทางออกที่ดีซึ่งใช้ได้ผล:

WorksheetFunction.IsErr(Evaluate("'" & wsName & "'!A1"))

หรือในฟังก์ชันเช่นนี้:

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Not WorksheetFunction.IsErr(Evaluate("'" & sName & "'!A1"))
End Function

Public Function WorkSheetExists(ByVal strName As String) As Boolean
   On Error Resume Next
   WorkSheetExists = Not Worksheets(strName) Is Nothing
End Function

sub test_sheet()

 If Not WorkSheetExists("SheetName") Then
 MsgBox "Not available"
Else MsgBox "Available"
End If

End Sub

    For Each Sheet In Worksheets
    If UCase(Sheet.Name) = "TEMP" Then
    'Your Code when the match is True
        Application.DisplayAlerts = False
        Sheet.Delete
        Application.DisplayAlerts = True
    '-----------------------------------
    End If
Next Sheet

เปลี่ยน "ข้อมูล" เป็นชื่อแผ่นงานที่คุณกำลังทดสอบ ...

On Error Resume Next 

Set DataSheet = Sheets("Data")

If DataSheet Is Nothing Then

     Sheets.Add(after:=ActiveSheet).Name = "Data"
     ''or whatever alternate code you want to execute''
End If

On Error GoTo 0

ไม่ต้องสงสัยเลยว่าฟังก์ชันข้างต้นสามารถใช้งานได้ฉันเพิ่งลงเอยด้วยรหัสต่อไปนี้ซึ่งใช้งานได้ดี:

Sub Sheet_exist ()
On Error Resume Next
If Sheets("" & Range("Sheet_Name") & "") Is Nothing Then
    MsgBox "doesnt exist"
Else
    MsgBox "exist"
End if
End sub

หมายเหตุ: Sheets_Nameเป็นที่ที่ฉันขอให้ผู้ใช้ป้อนชื่อดังนั้นสิ่งนี้อาจไม่เหมือนกันสำหรับคุณ

ฉันทำอย่างอื่น: ลบแผ่นงานเฉพาะเมื่อมีอยู่ - ไม่ได้รับข้อผิดพลาดหากไม่มี:

Excel.DisplayAlerts = False 
Dim WS
For Each WS In Excel.Worksheets
    If WS.name = "Sheet2" Then
        Excel.sheets("Sheet2").Delete
        Exit For
    End If
Next
Excel.DisplayAlerts = True

ฉันคิดวิธีง่ายๆในการทำ แต่ฉันไม่ได้สร้างย่อยใหม่สำหรับมัน แต่ฉันเพียงแค่ "ดำเนินการตรวจสอบ" ในส่วนย่อยที่ฉันกำลังดำเนินการอยู่ สมมติว่าชื่อแผ่นงานที่เรากำลังมองหาคือ "Sheet_Exist" และเราต้องการเปิดใช้งานหากพบ:

Dim SheetCounter As Integer

SheetCounter = 1

Do Until Sheets(SheetCounter).Name = "Sheet_Exist" Or SheetCounter = Sheets.Count + 1
 SheetCounter = SheetCounter +1
Loop
If SheetCounter < Sheets.Count + 1 Then
 Sheets("Sheet_Exist").Activate
Else
 MsgBox("Worksheet ""Sheet_Exist"" was NOT found")
End If

ฉันยังเพิ่มป๊อปอัปเมื่อไม่มีแผ่นงาน

ฉันรู้ว่ามันเป็นโพสต์เก่า แต่นี่เป็นอีกวิธีง่ายๆที่รวดเร็ว

Public Function worksheetExists(ByVal wb As Workbook, ByVal sheetNameStr As String) As Boolean

On Error Resume Next
worksheetExists = (wb.Worksheets(sheetNameStr).Name <> "")
Err.Clear: On Error GoTo 0

End Function

สั้นและสะอาด:

Function IsSheet(n$) As Boolean
    IsSheet = Not IsError(Evaluate(n & "!a1"))
End Function

ฉันมีวิธีง่ายๆในการตรวจสอบว่ามีแผ่นงานอยู่หรือไม่จากนั้นดำเนินการตามคำสั่ง:

ในกรณีของฉันฉันต้องการลบแผ่นงานและสร้างแผ่นงานเดิมขึ้นมาใหม่โดยใช้ชื่อเดียวกัน แต่รหัสถูกขัดจังหวะหากโปรแกรมไม่สามารถลบแผ่นงานได้เนื่องจากถูกลบไปแล้ว

Sub Foo ()

    Application.DisplayAlerts = False

    On Error GoTo instructions
    Sheets("NAME OF THE SHEET").Delete

    instructions:

    Sheets.Add After:=Sheets(Sheets.Count)
    ActiveSheet.Name = "NAME OF THE SHEET"

End Sub