ใน Clojure 1.3 วิธีการอ่านและเขียนไฟล์

ฉันต้องการทราบวิธีการ "แนะนำ" ในการอ่านและเขียนไฟล์ใน Clojure 1.3

1. วิธีอ่านไฟล์ทั้งหมด
2. วิธีอ่านไฟล์ทีละบรรทัด
3. วิธีเขียนไฟล์ใหม่
4. วิธีเพิ่มบรรทัดลงในไฟล์ที่มีอยู่

สมมติว่าเราทำไฟล์ข้อความที่นี่เท่านั้น

หมายเลข 1: วิธีอ่านไฟล์ทั้งหมดในหน่วยความจำ

(slurp "/tmp/test.txt")

ไม่แนะนำเมื่อเป็นไฟล์ขนาดใหญ่จริงๆ

หมายเลข 2: วิธีอ่านไฟล์ทีละบรรทัด

(use 'clojure.java.io)
(with-open [rdr (reader "/tmp/test.txt")]
  (doseq [line (line-seq rdr)]
    (println line)))

with-openแมโครจะดูแลว่าผู้อ่านจะปิดท้ายของร่างกาย ฟังก์ชั่นอ่าน coerces สตริง (มันยังสามารถทำ URL ที่ ฯลฯ ) BufferedReaderเป็นline-seqส่ง seq ขี้เกียจ เรียกร้ององค์ประกอบถัดไปของผลลัพธ์ที่ขี้เกียจเป็นบรรทัดที่อ่านจากเครื่องอ่าน

โปรดทราบว่าจาก Clojure 1.7 เป็นต้นไปคุณสามารถใช้ทรานสดิวเซอร์สำหรับอ่านไฟล์ข้อความได้

หมายเลข 3: วิธีการเขียนไปยังไฟล์ใหม่

(use 'clojure.java.io)
(with-open [wrtr (writer "/tmp/test.txt")]
  (.write wrtr "Line to be written"))

with-openดูแลอีกครั้งว่าBufferedWriterปิดในตอนท้ายของร่างกาย Writer บีบอัดสตริงลงในBufferedWriter, ซึ่งคุณใช้ผ่านทาง java interop:(.write wrtr "something").

คุณสามารถใช้งานได้spitตรงกันข้ามslurp:

(spit "/tmp/test.txt" "Line to be written")

หมายเลข 4: ต่อท้ายบรรทัดไปยังไฟล์ที่มีอยู่

(use 'clojure.java.io)
(with-open [wrtr (writer "/tmp/test.txt" :append true)]
  (.write wrtr "Line to be appended"))

เหมือนข้างต้น แต่ตอนนี้มีตัวเลือกผนวก

หรืออีกครั้งกับspitตรงข้ามของslurp:

(spit "/tmp/test.txt" "Line to be written" :append true)

PS:เพื่อให้ชัดเจนยิ่งขึ้นเกี่ยวกับความจริงที่ว่าคุณกำลังอ่านและเขียนลงในไฟล์และไม่ใช่อย่างอื่นคุณสามารถสร้างวัตถุไฟล์ก่อนแล้วจึงบีบบังคับให้เป็นBufferedReaderหรือนักเขียน:

(reader (file "/tmp/test.txt"))
;; or
(writer (file "tmp/test.txt"))

ฟังก์ชั่นไฟล์ยังอยู่ใน clojure.java.io

PS2:บางครั้งมันเป็นประโยชน์ที่จะสามารถดูว่าไดเรกทอรีปัจจุบัน (ดังนั้น ".") คืออะไร คุณสามารถหาพา ธ สัมบูรณ์ได้สองวิธี:

(System/getProperty "user.dir") 

หรือ

(-> (java.io.File. ".") .getAbsolutePath)

หากไฟล์พอดีกับหน่วยความจำคุณสามารถอ่านและเขียนด้วย slurp และ spit:

(def s (slurp "filename.txt"))

(s ตอนนี้มีเนื้อหาของไฟล์เป็นสตริง)

(spit "newfile.txt" s)

สิ่งนี้จะสร้าง newfile.txt หากไม่ออกและเขียนเนื้อหาไฟล์ หากคุณต้องการผนวกไฟล์ที่คุณสามารถทำได้

(spit "filename.txt" s :append true)

หากต้องการอ่านหรือเขียนไฟล์ linewise คุณจะต้องใช้ตัวอ่านและตัวเขียนของ Java พวกเขาถูกห่อใน namespace clojure.java.io:

(ns file.test
  (:require [clojure.java.io :as io]))

(let [wrtr (io/writer "test.txt")]
  (.write wrtr "hello, world!\n")
  (.close wrtr))

(let [wrtr (io/writer "test.txt" :append true)]
  (.write wrtr "hello again!")
  (.close wrtr))

(let [rdr (io/reader "test.txt")]
  (println (.readLine rdr))
  (println (.readLine rdr)))
; "hello, world!"
; "hello again!"

โปรดทราบว่าความแตกต่างระหว่าง slurp / spit และตัวอย่าง reader / writer คือไฟล์ยังคงเปิดอยู่ (ในคำสั่ง let) ในภายหลังและการอ่านและการเขียนจะถูกบัฟเฟอร์ดังนั้นจึงมีประสิทธิภาพมากขึ้นเมื่ออ่านจาก / เขียนไปยังไฟล์ซ้ำ ๆ

นี่คือข้อมูลเพิ่มเติม: slurp spit clojure.java.io Java's BufferedReader Java's Writer

เกี่ยวกับคำถามที่ 2 บางครั้งต้องการให้กระแสข้อมูลของเส้นคืนเป็นวัตถุชั้นหนึ่ง เพื่อให้เป็นลำดับที่ขี้เกียจและยังคงปิดไฟล์โดยอัตโนมัติใน EOF ฉันใช้ฟังก์ชั่นนี้:

(use 'clojure.java.io)

(defn read-lines [filename]
  (let [rdr (reader filename)]
    (defn read-next-line []
      (if-let [line (.readLine rdr)]
       (cons line (lazy-seq (read-next-line)))
       (.close rdr)))
    (lazy-seq (read-next-line)))
)

(defn echo-file []
  (doseq [line (read-lines "myfile.txt")]
    (println line)))

นี่คือวิธีการอ่านไฟล์ทั้งหมด

หากไฟล์อยู่ในไดเรกทอรีทรัพยากรคุณสามารถทำได้:

(let [file-content-str (slurp (clojure.java.io/resource "public/myfile.txt")])

clojure.java.ioอย่าลืมที่จะต้องใช้ /

(require '[clojure.java.io :as io])
(io/copy (io/file "/etc/passwd") \*out*\)

หากต้องการอ่านไฟล์ทีละบรรทัดคุณไม่จำเป็นต้องหันมาใช้ interop อีกต่อไป:

(->> "data.csv"
      io/resource
      io/reader
      line-seq
      (drop 1))

นี่ถือว่าไฟล์ข้อมูลของคุณถูกเก็บไว้ในไดเรกทอรีทรัพยากรและบรรทัดแรกคือข้อมูลส่วนหัวที่สามารถละทิ้งได้