แสดงคำสั่งของ Windows พร้อมท์เอาต์พุตและเปลี่ยนเส้นทางไปยังไฟล์

ฉันจะรันแอพพลิเคชั่นบรรทัดคำสั่งในพรอมต์คำสั่งของ Windows ได้อย่างไรและให้แสดงผลลัพธ์และเปลี่ยนเส้นทางไปยังไฟล์ในเวลาเดียวกันได้อย่างไร

ตัวอย่างเช่นถ้าฉันจะเรียกใช้คำสั่งdir > test.txtนี้จะเปลี่ยนเส้นทางการส่งออกไปยังไฟล์ที่เรียกว่าtest.txtโดยไม่แสดงผลลัพธ์

ฉันจะเขียนคำสั่งเพื่อแสดงเอาต์พุตและเปลี่ยนเส้นทางเอาต์พุตไปยังไฟล์ในพรอมต์คำสั่ง Windows ได้เช่นเดียวกับteeคำสั่งบน Unix ได้อย่างไร

เพื่อขยายคำตอบของ davorคุณสามารถใช้ PowerShell ดังนี้:

powershell "dir | tee test.txt"

หากคุณพยายามเปลี่ยนเส้นทางเอาต์พุตของ exe ในไดเรกทอรีปัจจุบันคุณต้องใช้.\ชื่อไฟล์เช่น:

powershell ".\something.exe | tee test.txt"

ฉันสามารถค้นหาวิธีแก้ปัญหา / วิธีแก้ปัญหาของการเปลี่ยนเส้นทางเอาต์พุตไปยังไฟล์จากนั้นไปที่คอนโซล:

dir > a.txt | type a.txt

โดยที่dirเป็นคำสั่งที่เอาต์พุตต้องถูกเปลี่ยนเส้นทางa.txtไฟล์ที่เก็บเอาต์พุต

มีพอร์ต Win32 ของteeคำสั่งUnix ที่ทำเช่นนั้น ดูhttp://unxutils.sourceforge.net/หรือhttp://getgnuwin32.sourceforge.net/

ลองดูสิ: wintee

ไม่จำเป็นต้องมี cygwin

ฉันพบและรายงานปัญหาบางอย่างแล้ว

นอกจากนี้คุณอาจตรวจสอบunxutilsเพราะมันมี tee (และไม่จำเป็นต้อง cygwin) แต่ระวังว่า output EOL นั้นเป็น UNIX เหมือนที่นี่

สุดท้าย แต่ไม่ท้ายสุดคือถ้าคุณมี PowerShell คุณสามารถลองใช้ Tee-Object พิมพ์get-help tee-objectใน PowerShell console สำหรับข้อมูลเพิ่มเติม

@ tori3852

ฉันพบว่า

dir > a.txt | type a.txt

ไม่ทำงาน (ไม่กี่บรรทัดแรกของรายการ dir เท่านั้น - สงสัยว่ากระบวนการฟอร์กกิ้งบางประเภทและส่วนที่สองคำสั่ง 'type' ถูกยกเลิกก่อนที่รายการไดเร็คต์จะเสร็จสมบูรณ์?) ดังนั้นฉันจึงใช้:

dir > z.txt && type z.txt

ซึ่งทำ - คำสั่งต่อเนื่องหนึ่งเสร็จสมบูรณ์ก่อนที่สองเริ่ม

น่าเสียดายที่ไม่มีสิ่งนั้น

แอปพลิเคชันคอนโซล Windows มีหมายเลขอ้างอิงผลลัพธ์เดียวเท่านั้น (ดีมีสองSTDOUT, STDERRแต่มันไม่ได้เรื่องที่นี่) ด้วย>การเปลี่ยนเส้นทางการส่งออกที่เขียนตามปกติในการจับคอนโซลเพื่อจัดการไฟล์

หากคุณต้องการมัลติเพล็กซ์บางประเภทคุณต้องใช้แอปพลิเคชันภายนอกซึ่งคุณสามารถเบี่ยงเบนความสนใจไปที่เอาต์พุต แอปพลิเคชันนี้สามารถเขียนไปยังไฟล์และคอนโซลอีกครั้ง

แอปพลิเคชันคอนโซล C # แบบง่ายจะทำการหลอกลวง:

using System;
using System.Collections.Generic;
using System.IO;

namespace CopyToFiles
{
    class Program
    {
        static void Main(string[] args)
        {
            var buffer = new char[100];
            var outputs = new List<TextWriter>();

            foreach (var file in args)
                outputs.Add(new StreamWriter(file));

            outputs.Add(Console.Out);

            int bytesRead;
            do
            {
                bytesRead = Console.In.ReadBlock(buffer, 0, buffer.Length);
                outputs.ForEach(o => o.Write(buffer, 0, bytesRead));
            } while (bytesRead == buffer.Length);

            outputs.ForEach(o => o.Close());
        }
    }
}

ในการใช้สิ่งนี้คุณเพียงแค่ไพพ์คำสั่ง source ลงในโปรแกรมและจัดเตรียมพา ธ ของไฟล์ใด ๆ ที่คุณต้องการทำซ้ำเอาต์พุต ตัวอย่างเช่น:

dir | CopyToFiles files1.txt files2.txt 

จะแสดงผลลัพธ์ของ dir รวมถึงเก็บผลลัพธ์ไว้ในทั้ง files1.txt และ files2.txt

โปรดทราบว่าการจัดการข้อผิดพลาดมีไม่มาก (อะไร!) ด้านบนและอาจไม่จำเป็นต้องรองรับไฟล์หลายไฟล์

ใช้งานได้แม้ว่ามันจะน่าเกลียดสักหน่อย:

dir >_ && type _ && type _ > a.txt

มีความยืดหยุ่นมากกว่าโซลูชันอื่น ๆ เล็กน้อยเนื่องจากสามารถใช้คำสั่งต่อคำสั่งเพื่อให้คุณสามารถใช้ผนวกเข้าด้วยกัน ฉันใช้สิ่งนี้ในไฟล์แบตช์เล็กน้อยเพื่อบันทึกและแสดงข้อความ:

ECHO Print line to screen and log to file.  >_ && type _ && type _ >> logfile.txt

ใช่คุณสามารถทำซ้ำคำสั่ง ECHO (หนึ่งครั้งสำหรับหน้าจอและครั้งที่สองที่เปลี่ยนเส้นทางไปยังไฟล์บันทึก) แต่นั่นดูเหมือนจะไม่ดีและเป็นปัญหาการบำรุงรักษาเล็กน้อย อย่างน้อยคุณก็ไม่ต้องทำการเปลี่ยนแปลงข้อความในสองที่นี้

โปรดทราบว่า _ เป็นเพียงชื่อไฟล์สั้น ๆ ดังนั้นคุณจะต้องตรวจสอบให้แน่ใจว่าได้ลบที่ท้ายแบทช์ไฟล์ (ถ้าคุณใช้แบตช์ไฟล์)

mtee เป็นเครื่องมือขนาดเล็กที่ทำงานได้ดีมากสำหรับวัตถุประสงค์นี้ แหล่งที่มาเปิดฟรีและใช้งานได้ฟรี

คุณสามารถค้นหาได้ที่ http://www.commandline.co.uk

ใช้ในไฟล์แบตช์เพื่อแสดงเอาต์พุตและสร้างล็อกไฟล์พร้อมกันไวยากรณ์มีลักษณะดังนี้:

    someprocess | mtee /+ mylogfile.txt

โดยที่ / + หมายถึงการผนวกเอาต์พุต

นี่ถือว่าคุณได้คัดลอก mtee ไปไว้ในโฟลเดอร์ที่อยู่ใน PATH แน่นอน

ฉันต้องการที่จะขยายบิตแซกซอน Druce ของคำตอบที่ดี

ตามที่ระบุไว้คุณสามารถเปลี่ยนทิศทางเอาต์พุตของไฟล์เรียกทำงานในไดเร็กทอรีปัจจุบันดังนี้:

powershell ".\something.exe | tee test.txt"

แต่นี้เข้าสู่ระบบเพื่อstdout มันไม่ได้นอกจากนี้ยังเข้าสู่ระบบtest.txtstderr

ทางออกที่ชัดเจนคือการใช้สิ่งนี้:

powershell ".\something.exe 2>&1 | tee test.txt"

แต่นี้จะไม่ทำงานสำหรับทุกsomething.exes บางคนsomething.exeจะตีความ2>&1ว่าเป็นข้อโต้แย้งและล้มเหลว วิธีแก้ไขที่ถูกต้องคือแทนที่จะมีเครื่องหมายอัญประกาศเดี่ยวรอบ ๆsomething.exeและสวิตช์และอาร์กิวเมนต์ของมันเท่านั้นเช่น:

powershell ".\something.exe --switch1 --switch2 … arg1 arg2 …" 2>&1 | tee test.txt

ฉันเห็นด้วยกับ Brian Rasmussen พอร์ต unxutils เป็นวิธีที่ง่ายที่สุดในการทำเช่นนี้ ในส่วนBatch Filesของหน้าสคริปต์ของเขาRob van der Woude ให้ข้อมูลมากมายเกี่ยวกับการใช้คำสั่ง MS-DOS และ CMD ฉันคิดว่าเขาอาจมีทางแก้ปัญหาของคุณและหลังจากขุดไปที่นั่นฉันพบTEE.BATซึ่งดูเหมือนจะเป็นเช่นนั้นการใช้ภาษาชุดแบ็ตช์ของ MS-DOS มันเป็นไฟล์แบทช์ที่ดูค่อนข้างซับซ้อนและความชอบของฉันจะยังคงใช้พอร์ต unxutils

หากคุณมี cygwin ในเส้นทางสภาพแวดล้อมของ windows คุณสามารถใช้:

 dir > a.txt | tail -f a.txt

dir 1>a.txt 2>&1 | type a.txt

สิ่งนี้จะช่วยในการเปลี่ยนเส้นทางทั้ง STDOUT และ STDERR

ฉันรู้ว่านี่เป็นหัวข้อที่เก่ามาก แต่ในคำตอบก่อนหน้านี้ไม่มีการนำ Tee แบบเรียลไทม์มาเขียนในแบทช์ โซลูชันด้านล่างของฉันคือสคริปต์ไฮบริด Batch-JScript ที่ใช้ส่วน JScript เพียงเพื่อรับเอาต์พุตจากคำสั่ง piped แต่การประมวลผลข้อมูลจะทำในส่วน Batch วิธีการนี้มีข้อได้เปรียบที่โปรแกรมเมอร์ Batch ใด ๆ อาจแก้ไขโปรแกรมนี้ให้เหมาะสมกับความต้องการเฉพาะ โปรแกรมนี้ยังประมวลผลเอาต์พุตของคำสั่ง CLS ที่สร้างโดยไฟล์ Batch อื่นอย่างถูกต้องนั่นคือจะล้างหน้าจอเมื่อตรวจพบเอาต์พุตคำสั่ง CLS

@if (@CodeSection == @Batch) @then


@echo off
setlocal EnableDelayedExpansion

rem APATee.bat: Asynchronous (real time) Tee program, Batch-JScript hybrid version
rem Antonio Perez Ayala

rem The advantage of this program is that the data management is written in Batch code,
rem so any Batch programmer may modify it to fit their own needs.
rem As an example of this feature, CLS command is correctly managed

if "%~1" equ "" (
   echo Duplicate the Stdout output of a command in the screen and a disk file
   echo/
   echo anyCommand ^| APATee teeFile.txt [/A]
   echo/
   echo If /A switch is given, anyCommand output is *appended* to teeFile.txt
   goto :EOF
)

if "%2" equ ":TeeProcess" goto TeeProcess

rem Get the output of CLS command
for /F %%a in ('cls') do set "cls=%%a"

rem If /A switch is not provided, delete the file that receives Tee output
if /I "%~2" neq "/A" if exist %1 del %1

rem Create the semaphore-signal file and start the asynchronous Tee process
echo X > Flag.out
if exist Flag.in del Flag.in
Cscript //nologo //E:JScript "%~F0" | "%~F0" %1 :TeeProcess
del Flag.out
goto :EOF

:TeeProcess
   rem Wait for "Data Available" signal
   if not exist Flag.in goto TeeProcess
   rem Read the line sent by JScript section
   set line=
   set /P line=
   rem Set "Data Read" acknowledgement
   ren Flag.in Flag.out
   rem Check for the standard "End Of piped File" mark
   if "!line!" equ ":_EOF_:" exit /B
   rem Correctly manage CLS command
   if "!line:~0,1!" equ "!cls!" (
      cls
      set "line=!line:~1!"
   )
   rem Duplicate the line in Stdout and the Tee output file
   echo(!line!
   echo(!line!>> %1
goto TeeProcess


@end


// JScript section

var fso = new ActiveXObject("Scripting.FileSystemObject");
// Process all lines of Stdin
while ( ! WScript.Stdin.AtEndOfStream ) {
   // Read the next line from Stdin
   var line = WScript.Stdin.ReadLine();
   // Wait for "Data Read" acknowledgement
   while ( ! fso.FileExists("Flag.out") ) {
      WScript.Sleep(10);
   }
   // Send the line to Batch section
   WScript.Stdout.WriteLine(line);
   // Set "Data Available" signal
   fso.MoveFile("Flag.out", "Flag.in");
}
// Wait for last "Data Read" acknowledgement
while ( ! fso.FileExists("Flag.out") ) {
      WScript.Sleep(10);
}
// Send the standard "End Of piped File" mark
WScript.Stdout.WriteLine(":_EOF_:");
fso.MoveFile("Flag.out", "Flag.in");

ฉันยังมองหาวิธีการแก้ปัญหาเดียวกันหลังจากลองเล็ก ๆ น้อย ๆ ฉันก็สามารถประสบความสำเร็จได้ใน Command Prompt นี่คือทางออกของฉัน:

@Echo off
for /f "Delims=" %%a IN (xyz.bat) do (
%%a > _ && type _ && type _ >> log.txt
)
@Echo on

มันยังจับคำสั่งหยุดชั่วคราวใด ๆ เช่นกัน

นี่คือตัวอย่างของสิ่งที่ฉันใช้ตามคำตอบอย่างอื่น

@echo off
REM SOME CODE
set __ERROR_LOG=c:\errors.txt
REM set __IPADDRESS=x.x.x.x

REM Test a variable
if not defined __IPADDRESS (
     REM Call function with some data and terminate
     call :TEE %DATE%,%TIME%,IP ADDRESS IS NOT DEFINED
     goto :EOF
)

REM If test happens to be successful, TEE out a message and end script.
call :TEE Script Ended Successful
goto :EOF


REM THE TEE FUNCTION
:TEE
for /f "tokens=*" %%Z in ("%*") do (
     >  CON ECHO.%%Z
     >> "%__ERROR_LOG%" ECHO.%%Z
     goto :EOF
)

สิ่งนี้ควรทำในสิ่งที่คุณต้องการ?

%DATE%_%TIME% > c:\a.txt & type c:\a.txt
ipconfig >> c:\a.txt & type c:\a.txt
ping localhost >> c:\a.txt & type c:\a.txt
pause

ส่งออกไปยังคอนโซลผนวกกับบันทึกคอนโซลลบออกจากคำสั่งปัจจุบัน

dir  >> usb-create.1 && type usb-create.1 >> usb-create.log | type usb-create.1 && del usb-create.1

นี่เป็นรูปแบบของคำตอบก่อนหน้าโดย MTS อย่างไรก็ตามมันเพิ่มฟังก์ชันการทำงานบางอย่างที่อาจเป็นประโยชน์กับผู้อื่น นี่คือวิธีการที่ฉันใช้:

• คำสั่งถูกตั้งค่าเป็นตัวแปรที่สามารถใช้ได้ในภายหลังตลอดทั้งรหัสเพื่อส่งออกไปยังหน้าต่างคำสั่งและผนวกเข้ากับไฟล์บันทึกโดยใช้ set _Temp_Msg_Cmd=
  • คำสั่งหนีการเปลี่ยนเส้นทางโดยใช้^ตัวอักษรแครอทเพื่อไม่ให้ประเมินคำสั่งในตอนแรก
• ไฟล์ชั่วคราวถูกสร้างด้วยชื่อไฟล์ที่คล้ายกับไฟล์แบตช์ที่กำลังเรียก%~n0_temp.txtใช้ซึ่งใช้ไวยากรณ์ส่วนขยายพารามิเตอร์บรรทัดคำสั่ง %~n0เพื่อรับชื่อของไฟล์แบตช์
• ผลลัพธ์จะถูกผนวกเข้ากับไฟล์บันทึกแยกต่างหาก %~n0_log.txt

นี่คือลำดับของคำสั่ง:

1. เอาต์พุตและข้อความแสดงความผิดพลาดถูกส่งไปยังไฟล์ชั่วคราว ^> %~n0_temp.txt 2^>^&1
2. เนื้อหาของไฟล์ชั่วคราวนั้นทั้งคู่:
   • ผนวกเข้ากับล็อกไฟล์ ^& type %~n0_temp.txt ^>^> %~n0_log.txt
   • ส่งออกไปยังหน้าต่างคำสั่ง ^& type %~n0_temp.txt
3. ไฟล์ชั่วคราวพร้อมข้อความถูกลบ ^& del /Q /F %~n0_temp.txt

นี่คือตัวอย่าง:

set _Temp_Msg_Cmd= ^> %~n0_temp.txt 2^>^&1 ^& type %~n0_temp.txt ^>^> %~n0_log.txt ^& type %~n0_temp.txt ^& del /Q /F %~n0_temp.txt

ด้วยวิธีนี้แล้วคำสั่งสามารถต่อท้ายหลังจากคำสั่งในภายหลังในไฟล์แบทช์ที่ดูสะอาดกว่ามาก:

echo test message %_Temp_Msg_Cmd%

สิ่งนี้สามารถเพิ่มลงในส่วนท้ายของคำสั่งอื่นเช่นกัน เท่าที่ฉันสามารถบอกได้ว่ามันจะทำงานเมื่อข้อความมีหลายบรรทัด ตัวอย่างเช่นคำสั่งต่อไปนี้จะออกสองบรรทัดหากมีข้อผิดพลาด:

net use M: /D /Y %_Temp_Msg_Cmd%

@echo on

set startDate=%date%
set startTime=%time%

set /a sth=%startTime:~0,2%
set /a stm=1%startTime:~3,2% - 100
set /a sts=1%startTime:~6,2% - 100


fullprocess.bat > C:\LOGS\%startDate%_%sth%.%stm%.%sts%.LOG | fullprocess.bat

สิ่งนี้จะสร้างไฟล์บันทึกที่มีวันที่และเวลาปัจจุบันและคุณสามารถบรรทัดคอนโซลในระหว่างกระบวนการ

ฉันใช้รูทีนย่อยชุดคำสั่ง "for" เพื่อรับเอาต์พุตคำสั่งทีละบรรทัดและทั้งคู่เขียนบรรทัดนั้นไปยังไฟล์และส่งออกไปยังคอนโซล

@echo off
set logfile=test.log

call :ExecuteAndTee dir C:\Program Files

Exit /B 0

:ExecuteAndTee
setlocal enabledelayedexpansion
echo Executing '%*'
  for /f "delims=" %%a in ('%* 2^>^&1') do (echo.%%a & echo.%%a>>%logfile%)
endlocal
Exit /B 0

หากคุณอยู่ใน CLI ทำไมไม่ใช้ FOR loop เพื่อ "DO" สิ่งที่คุณต้องการ:

for /F "delims=" %a in ('dir') do @echo %a && echo %a >> output.txt

ทรัพยากรที่ยอดเยี่ยมสำหรับ Windows CMD สำหรับลูป: https://ss64.com/nt/for_cmd.html กุญแจสำคัญในที่นี้คือการตั้งค่าตัวคั่น (delims) ที่จะแยกเอาท์พุทแต่ละบรรทัดออกเป็นไม่มีอะไร วิธีนี้จะไม่ทำให้ค่าเริ่มต้นของ white-space แตก % a เป็นตัวอักษรตามอำเภอใจ แต่มันถูกใช้ในส่วน "do" ถึงดี ... ทำบางสิ่งบางอย่างกับตัวอักษรที่แยกวิเคราะห์ในแต่ละบรรทัด ในกรณีนี้เราสามารถใช้เครื่องหมายแอมเปอร์แซนด์ (&&) เพื่อรันคำสั่ง echo ลำดับที่ 2 เพื่อสร้างหรือต่อท้าย (>>) ไปยังไฟล์ที่เราเลือก ปลอดภัยกว่าเพื่อรักษาคำสั่ง DO นี้ในกรณีที่มีปัญหาในการเขียนไฟล์อย่างน้อยเราจะนำเสียงก้องไปยังคอนโซลก่อน เครื่องหมาย at (@) ที่อยู่ด้านหน้าของ echo แรกช่วยไม่ให้คอนโซลแสดงคำสั่ง echo เองและเพียงแสดงผลลัพธ์ของคำสั่งที่จะแสดงอักขระใน% a มิฉะนั้นคุณจะเห็น:

echo Volume ในไดรฟ์ [x] คือ Windows
Volume ในไดรฟ์ [x] คือ Windows

UPDATE: / F ข้ามบรรทัดว่างเปล่าและแก้ไขเพียงอย่างเดียวคือกรองเอาท์พุทล่วงหน้าที่เพิ่มอักขระให้กับทุกบรรทัด (อาจมีหมายเลขบรรทัดผ่านการค้นหาคำสั่ง) การแก้ปัญหานี้ใน CLI นั้นไม่รวดเร็วหรือสวย นอกจากนี้ฉันไม่ได้รวม STDERR ดังนั้นนี่คือข้อผิดพลาดในการจับภาพเช่นกัน:

for /F "delims=" %a in ('dir 2^>^&1') do @echo %a & echo %a >> output.txt

การเปลี่ยนเส้นทางข้อความผิดพลาด

เครื่องหมายคาร์เร็ต (^) อยู่ที่นั่นเพื่อหนีสัญลักษณ์หลังจากพวกมันเนื่องจากคำสั่งเป็นสตริงที่ถูกตีความซึ่งต่างจากการพูดให้ป้อนมันโดยตรงบนบรรทัดคำสั่ง

เหมือนยูนิกซ์

dir | tee a.txt

ทำงานบน windows XP ต้องmksntติดตั้ง

มันจะแสดงขึ้นบนพรอมต์เช่นเดียวกับผนวกเข้ากับไฟล์

การติดตามช่วยหากคุณต้องการสิ่งที่เห็นบนหน้าจอจริงๆ - แม้ว่าไฟล์แบตช์จะถูกเปลี่ยนเส้นทางไปยังไฟล์ อุปกรณ์ CON อาจใช้หากเปลี่ยนเส้นทางไปยังไฟล์

ตัวอย่าง:

ECHO first line on normal stdout. maybe redirected
ECHO second line on normal stdout again. maybe redirected
ECHO third line is to ask the user. not redirected  >CON
ECHO fourth line on normal stdout again. maybe redirected

ดูคำอธิบายการเปลี่ยนเส้นทางที่ดี: http://www.p-dd.com/chapter7-page14.html

ฉันจะแสดงและเปลี่ยนเส้นทางผลลัพธ์ไปยังไฟล์ได้อย่างไร สมมติว่าถ้าฉันใช้คำสั่ง dos, dir> test.txt คำสั่งนี้จะเปลี่ยนเส้นทางผลลัพธ์ไปยังไฟล์ test.txt โดยไม่แสดงผลลัพธ์ วิธีการเขียนคำสั่งเพื่อแสดงผลลัพธ์และเปลี่ยนเส้นทางไปยังไฟล์โดยใช้ DOS เช่นคำสั่ง windows command ไม่ใช่ใน UNIX / LINUX

คุณอาจพบคำสั่งเหล่านี้ใน biterscripting ( http://www.biterscripting.com ) มีประโยชน์

var str output
lf > $output
echo $output                            # Will show output on screen.
echo $output > "test.txt"               # Will write output to file test.txt.
system start "test.txt"                 # Will open file test.txt for viewing/editing.

ใช้งานได้ในเวลาจริง แต่ก็น่าเกลียดและประสิทธิภาพก็ช้า ไม่ผ่านการทดสอบอย่างดี:

@echo off
cls
SET MYCOMMAND=dir /B
ECHO File called 'test.bat' > out.txt
for /f "usebackq delims=" %%I in (`%MYCOMMAND%`) do (
  ECHO %%I
  ECHO %%I >> out.txt
) 
pause

อีกทางเลือกหนึ่งคือการที stdout ไปยัง stderr ภายในโปรแกรมของคุณ:

ใน java:

System.setOut(new PrintStream(new TeeOutputStream(System.out, System.err)));

จากนั้นในไฟล์ batch batch ของคุณ: java program > log.txt

stdout จะไปที่ logfile และ stderr (ข้อมูลเดียวกัน) จะแสดงบนคอนโซล

ฉันติดตั้ง Perl ในเครื่องส่วนใหญ่ของฉันดังนั้นคำตอบโดยใช้ Perl: tee.pl

my $file = shift || "tee.dat";
open $output, ">", $file or die "unable to open $file as output: $!";
while(<STDIN>)
{
    print $_;
    print $output $_;
}
close $output;

ผบ perl tee.pl หรือ dir | perl tee.pl dir.bat

น้ำมันดิบและยังไม่ทดลอง

อีกรูปแบบหนึ่งคือแยกท่อจากนั้นกำหนดทิศทางเอาต์พุตตามที่คุณต้องการอีกครั้ง

    @echo off
    for /f "tokens=1,* delims=:" %%P in ('findstr /n "^"') do (
      echo(%%Q
      echo(%%Q>&3
    )
    @exit/b %errorlevel%

บันทึกด้านบนเป็นไฟล์. bat มันแยกเอาท์พุทข้อความบน filestream 1 ถึง filestream 3 ด้วยซึ่งคุณสามารถเปลี่ยนเส้นทางได้ตามต้องการ ในตัวอย่างด้านล่างของฉันฉันเรียกสคริปต์ข้างต้น splitPipe.bat ...

    dir | splitPipe.bat  1>con  2>&1  3>my_stdout.log

    splitPipe.bat 2>nul < somefile.txt

1. https://cygwin.com/install
2. คลิกลิงก์สำหรับ "setup-x86_.exe"
3. เรียกใช้โปรแกรมติดตั้ง
4. ในหน้า ~ 2nd เลือก "mirror" เพื่อดาวน์โหลดจาก (ฉันค้นหาโดเมน. edu)
5. ฉันบอกว่าโอเคกับตัวเลือกมาตรฐาน
6. Cygwin เสร็จสิ้นการติดตั้งอย่างรวดเร็ว
7. เปิด cmd
8. พิมพ์c:\cygwin64\bin\script.exeและป้อน
9. พิมพ์cmdและป้อน
10. เรียกใช้โปรแกรมของคุณ
11. พิมพ์exitและป้อน (ออกจาก Cygwin's cmd.exe)
12. พิมพ์exitและป้อน (ออกจาก script.exe ของ Cygwin)
13. ดูผลลัพธ์หน้าจอของโปรแกรมของคุณในไฟล์ข้อความชื่อ "typescript"