ฉันใช้ฟังก์ชันต่อไปนี้

=DAYS360(A2, A35)

เพื่อคำนวณความแตกต่างระหว่างวันที่สองวันในคอลัมน์ของฉัน อย่างไรก็ตามคอลัมน์นี้กำลังขยายออกไปเรื่อย ๆ และตอนนี้ฉันต้องเปลี่ยน "A35" ด้วยตนเองเมื่อฉันอัปเดตสเปรดชีต

มีวิธี (ใน Google ชีต) ในการค้นหาเซลล์สุดท้ายที่ไม่ว่างเปล่าในคอลัมน์นี้แล้วตั้งค่าพารามิเตอร์นั้นแบบไดนามิกในฟังก์ชันด้านบนหรือไม่

อาจมีวิธีที่คมชัดกว่านี้ แต่นี่คือวิธีที่ฉันคิดขึ้น:

ฟังก์ชันในการค้นหาเซลล์ที่เติมสุดท้ายในคอลัมน์คือ:

=INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) )

ดังนั้นหากคุณรวมเข้ากับฟังก์ชันปัจจุบันของคุณจะมีลักษณะดังนี้:

=DAYS360(A2,INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) ))

หากต้องการค้นหาเซลล์สุดท้ายที่ไม่ว่างคุณสามารถใช้INDEXและMATCHทำหน้าที่ดังนี้:

=DAYS360(A2; INDEX(A:A; MATCH(99^99;A:A; 1)))

ฉันคิดว่านี่เร็วและง่ายกว่าเล็กน้อย

ถ้า A2: A มีวันที่ติดกัน INDEX (A2: A, COUNT (A2: A)) จะส่งกลับวันที่สุดท้าย สูตรสุดท้ายคือ

=DAYS360(A2,INDEX(A2:A,COUNT(A2:A)))

สิ่งที่ฉันชอบคือ:

=INDEX(A2:A,COUNTA(A2:A),1)

ดังนั้นสำหรับความต้องการของ OP:

=DAYS360(A2,INDEX(A2:A,COUNTA(A2:A),1))

หากคอลัมน์ขยายตามวันที่ที่เพิ่มต่อเนื่องกันในกรณีของฉัน - ฉันใช้เพียงฟังก์ชัน MAX เพื่อรับวันที่สุดท้าย

สูตรสุดท้ายจะเป็น:

=DAYS360(A2; MAX(A2:A)) 

แม้ว่าคำถามจะได้รับคำตอบแล้ว แต่ก็มีวิธีที่ดีในการทำเช่นนั้น

Use just the column name to denote last non-empty row of that column.

ตัวอย่างเช่น:

หากข้อมูลของคุณอยู่ในA1:A100และคุณต้องการที่จะสามารถเพิ่มข้อมูลเพิ่มเติมในคอลัมน์ A กล่าวว่าอาจเป็นA1:A105หรือในA1:A1234ภายหลังคุณสามารถใช้ช่วงนี้:

A1:A

ดังนั้นเพื่อให้ได้ค่าสุดท้ายที่ไม่ว่างเปล่าในช่วงเราจะใช้ 2 ฟังก์ชัน:

• COUNTA
• ดัชนี

คำตอบคือ=INDEX(B3:B,COUNTA(B3:B)).

นี่คือคำอธิบาย:

COUNTA(range) ส่งคืนจำนวนค่าในช่วงเราสามารถใช้สิ่งนี้เพื่อรับจำนวนแถว

INDEX(range, row, col)ส่งคืนค่าในช่วงที่ตำแหน่งrowและcol( col=1หากไม่ระบุ)

ตัวอย่าง:

INDEX(A1:C5,1,1) = A1
INDEX(A1:C5,1) = A1 # implicitly states that col = 1
INDEX(A1:C5,1,2) = A2
INDEX(A1:C5,2,1) = B1
INDEX(A1:C5,2,2) = B2
INDEX(A1:C5,3,1) = C1
INDEX(A1:C5,3,2) = C2

B3:Bสำหรับภาพข้างบนช่วงของเราจะได้รับ ดังนั้นเราจะนับจำนวนค่าจะมีในช่วงB3:BโดยCOUNTA(B3:B)ครั้งแรก ทางด้านซ้ายจะผลิต8เนื่องจากมี 8 ค่าในขณะที่จะผลิต9ในด้านขวา เรายังไม่ทราบว่าค่าสุดท้ายที่อยู่ในคอลัมน์ที่ 1 ของช่วงB3:Bดังนั้นcolพารามิเตอร์ของINDEXต้องเป็น 1 และพารามิเตอร์ที่ควรจะเป็นrowCOUNTA(B3:B)

PS : โปรดโหวตคำตอบของ @ bloodymurderlive ตั้งแต่เขาเขียนครั้งแรกฉันแค่อธิบายที่นี่

นี่คืออีกหนึ่ง:

=indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),""))))

ด้วยสมการสุดท้ายคือ:

=DAYS360(A2,indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),"")))))

สมการอื่น ๆ ในที่นี่ใช้ได้ แต่ฉันชอบอันนี้เพราะมันทำให้การหาหมายเลขแถวง่ายขึ้นซึ่งฉันพบว่าฉันต้องทำบ่อยขึ้น หมายเลขแถวจะเป็นดังนี้:

=max(arrayformula(if(A:A<>"",row(A:A),"")))

ตอนแรกฉันพยายามค้นหาสิ่งนี้เพื่อแก้ปัญหาสเปรดชีต แต่ไม่พบสิ่งที่เป็นประโยชน์ที่ให้หมายเลขแถวของรายการสุดท้ายดังนั้นหวังว่านี่จะเป็นประโยชน์สำหรับใครบางคน

นอกจากนี้ยังมีข้อได้เปรียบเพิ่มเติมที่สามารถใช้ได้กับข้อมูลประเภทใดก็ได้ในลำดับใดก็ได้และคุณสามารถมีแถวว่างระหว่างแถวที่มีเนื้อหาได้และจะไม่นับเซลล์ที่มีสูตรที่ประเมินเป็น "" นอกจากนี้ยังสามารถจัดการกับค่าซ้ำ ๆ สรุปแล้วมันคล้ายกับสมการที่ใช้ max ((G: G <> "") * row (G: G)) ตรงนี้ แต่จะทำให้การดึงหมายเลขแถวออกมาง่ายขึ้นเล็กน้อยหากนั่นคือสิ่งที่คุณต้องการ .

หรือหากคุณต้องการใส่สคริปต์ลงในแผ่นงานของคุณคุณสามารถทำให้มันง่ายขึ้นด้วยตัวคุณเองหากคุณวางแผนที่จะทำสิ่งนี้เป็นจำนวนมาก นี่คือสิ่งที่ scirpt:

function lastRow(sheet,column) {
  var ss = SpreadsheetApp.getActiveSpreadsheet();
  if (column == null) {
    if (sheet != null) {
       var sheet = ss.getSheetByName(sheet);
    } else {
      var sheet = ss.getActiveSheet();
    }
    return sheet.getLastRow();
  } else {
    var sheet = ss.getSheetByName(sheet);
    var lastRow = sheet.getLastRow();
    var array = sheet.getRange(column + 1 + ':' + column + lastRow).getValues();
    for (i=0;i<array.length;i++) {
      if (array[i] != '') {       
        var final = i + 1;
      }
    }
    if (final != null) {
      return final;
    } else {
      return 0;
    }
  }
}

ที่นี่คุณสามารถพิมพ์ข้อความต่อไปนี้หากคุณต้องการให้แถวสุดท้ายในแผ่นเดียวกันกับที่คุณกำลังแก้ไขอยู่:

=LASTROW()

หรือถ้าคุณต้องการให้แถวสุดท้ายของคอลัมน์ใดคอลัมน์หนึ่งจากแผ่นงานนั้นหรือของคอลัมน์ใดคอลัมน์หนึ่งจากแผ่นงานอื่นคุณสามารถทำสิ่งต่อไปนี้:

=LASTROW("Sheet1","A")

และสำหรับแถวสุดท้ายของแผ่นงานโดยทั่วไป:

=LASTROW("Sheet1")

จากนั้นเพื่อให้ได้ข้อมูลจริงคุณสามารถใช้ทางอ้อม:

=INDIRECT("A"&LASTROW())

หรือคุณสามารถแก้ไขสคริปต์ด้านบนที่สองบรรทัดสุดท้าย (สองบรรทัดสุดท้ายเนื่องจากคุณจะต้องใส่ทั้งชีตและคอลัมน์เพื่อรับค่าจริงจากคอลัมน์จริง) และแทนที่ตัวแปรด้วยสิ่งต่อไปนี้:

return sheet.getRange(column + final).getValue();

และ

return sheet.getRange(column + lastRow).getValue();

ข้อดีอย่างหนึ่งของสคริปต์นี้คือคุณสามารถเลือกได้ว่าคุณต้องการรวมสมการที่ประเมินเป็น "" หรือไม่ หากไม่มีการเพิ่มข้อโต้แย้งสมการที่ประเมินเป็น "" จะถูกนับ แต่ถ้าคุณระบุแผ่นงานและคอลัมน์จะถูกนับ นอกจากนี้ยังมีความยืดหยุ่นมากหากคุณต้องการใช้สคริปต์ในรูปแบบต่างๆ

อาจจะมากเกินไป แต่เป็นไปได้ทั้งหมด

แล้วสูตรนี้สำหรับการรับค่าสุดท้าย:

=index(G:G;max((G:G<>"")*row(G:G)))

และนี่จะเป็นสูตรสุดท้ายสำหรับงานเดิมของคุณ:

=DAYS360(G10;index(G:G;max((G:G<>"")*row(G:G))))

สมมติว่าวันที่เริ่มต้นของคุณอยู่ใน G10

ฉันไปคนละเส้นทาง เนื่องจากฉันรู้ว่าฉันจะเพิ่มบางสิ่งลงในแถว / คอลัมน์ทีละรายการฉันจึงค้นหาแถวสุดท้ายโดยการนับช่องที่มีข้อมูลก่อน ฉันจะสาธิตสิ่งนี้ด้วยคอลัมน์:

=COUNT(A5:A34)

สมมุติว่าส่งกลับ 21 A5 คือ 4 แถวลงไปดังนั้นผมต้องได้ตำแหน่งที่ 21 จากแถวที่ 4 ลงไป ฉันสามารถทำได้โดยใช้ inderect ดังนี้:

=INDIRECT("A"&COUNT(A5:A34)+4)

เป็นการหาจำนวนแถวที่มีข้อมูลและส่งคืนตัวเลขที่ฉันใช้เป็นตัวปรับดัชนี

สำหรับแถว:

=ARRAYFORMULA(INDIRECT("A"&MAX(IF(A:A<>"", ROW(A:A), ))))

สำหรับคอลัมน์:

=ARRAYFORMULA(INDIRECT(ADDRESS(1, MAX(IF(1:1<>"", COLUMN(1:1), )), 4)))

นี่ดูเหมือนจะเป็นวิธีที่ง่ายที่สุดที่ฉันพบในการดึงค่าสุดท้ายในคอลัมน์ที่ขยายตลอดเวลา:

=INDEX(A:A,COUNTA(A:A),1)

สิ่งนี้ใช้ได้กับฉัน รับค่าสุดท้ายของคอลัมน์ A ใน Google แผ่นงาน:

=index(A:A,max(row(A:A)*(A:A<>"")))

(นอกจากนี้ยังข้ามแถวว่างระหว่างถ้ามี)

คำนวณความแตกต่างระหว่างวันที่ล่าสุดในคอลัมน์ A กับวันที่ในเซลล์ A2

=MAX(A2:A)-A2

สิ่งนี้จะให้เนื้อหาของเซลล์สุดท้าย:

=indirect("A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>""))))

สิ่งนี้จะให้ที่อยู่ของเซลล์สุดท้าย:

="A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

สิ่งนี้จะให้แถวของเซลล์สุดท้าย:

=max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

บางทีคุณอาจต้องการสคริปต์ สคริปต์นี้สั้นกว่าสคริปต์ขนาดใหญ่ที่คนอื่นโพสต์ไว้ด้านบน:

ไปที่โปรแกรมแก้ไขสคริปต์และบันทึกสคริปต์นี้:

function getLastRow(range){
  while(range.length>0 && range[range.length-1][0]=='') range.pop();
  return range.length;
}

สิ่งหนึ่งที่เสร็จแล้วคุณเพียงแค่ป้อนสิ่งนี้ในเซลล์:

=getLastRow(A:A)

วิธีที่มือสมัครเล่นทำคือ "= CONCATENATE (" A ", COUNTUNIQUE (A1: A9999))" โดยที่ A1 เป็นเซลล์แรกในคอลัมน์และ A9999 จะอยู่ห่างจากคอลัมน์นั้นมากกว่าที่ฉันคาดไว้ว่าจะมีรายการใด ๆ ผลลัพธ์ A # นี้สามารถใช้กับฟังก์ชัน INDIRECT ได้ตามต้องการ

เพื่อหาจำนวน nonempty แถวสุดท้าย (ให้ช่องว่างระหว่างพวกเขา) Aผมใช้ด้านล่างเพื่อค้นหาคอลัมน์

=ArrayFormula(IFNA(match(2,1/(A:A<>""))))