ฉันเป็นมือใหม่กับ CMAKE ด้านล่างนี้เป็นไฟล์ cmake แบบธรรมดาซึ่งทำงานได้ดีในหน้าต่างสภาพแวดล้อม mingw ปัญหาชัดเจนกับtarget_link_libraries()ฟังก์ชันของ CMAKE ที่ฉันเชื่อมโยง libwsock32.a ใน windows สิ่งนี้ใช้งานได้และฉันได้รับผลลัพธ์

อย่างไรก็ตามตามที่คาดไว้ใน Linux /usr/bin/ldจะมองหา-lwsock32สิ่งที่ไม่มีใน Linux OS

ปัญหาของฉันคือ: ฉันจะสั่งให้ CMAKE หลีกเลี่ยงการเชื่อมโยงไลบรารี wsock32 ใน Linux OS ได้อย่างไร ???

ความช่วยเหลือใด ๆ จะได้รับการชื่นชมอย่างมาก

ไฟล์ Simple CMake ของฉัน:

 PROJECT(biourl)
 set (${PROJECT_NAME}_headers ./BioSocketAddress.h  ./BioSocketBase.h ./BioSocketBuffer.h ./BioSocketCommon.h  ./BioSocketListener.h  ./BioSocketPrivate.h  ./BioSocketStream.h ./BioUrl.h BioDatabase.h )

set (${PROJECT_NAME}_sources BioSocketAddress.C  BioSocketBase.C  BioSocketCommon.C BioSocketStream.C  BioUrl.C BioDatabase.C )

add_library(${PROJECT_NAME} STATIC ${${PROJECT_NAME}_headers} ${${PROJECT_NAME}_sources} )

# linkers
#find_library(ws NAMES wsock32 PATHS ${PROJECT_SOURCE_DIR} NO_SYSTEM_ENVIRONMENT_PATH NO_DEFAULT_PATH)

target_link_libraries(${PROJECT_NAME} bioutils wsock32)

install (TARGETS ${PROJECT_NAME}
       RUNTIME DESTINATION bin
       LIBRARY DESTINATION lib
       ARCHIVE DESTINATION lib/archive )

ใช้

if (WIN32)
    #do something
endif (WIN32)

หรือ

if (UNIX)
    #do something
endif (UNIX)

หรือ

if (MSVC)
    #do something
endif (MSVC)

หรือคล้ายกัน

ดูตัวแปรที่เป็นประโยชน์ของCMake และแพลตฟอร์มการตรวจสอบ CMake

เนื่องจากนี่เป็นปัญหาทั่วไปการโพสต์บนเว็บไซต์:

    if(UNIX AND NOT APPLE)
        set(LINUX TRUE)
    endif()

    # if(NOT LINUX) should work, too, if you need that
    if(LINUX) 
        message(STATUS ">>> Linux")
        # linux stuff here
    else()
        message(STATUS ">>> Not Linux")
        # stuff that should happen not on Linux 
    endif()

CMake เอกสารตรรกะบูลีน

ชื่อแพลตฟอร์ม CMake ฯลฯ

โดยทั่วไป

คุณสามารถตรวจจับและระบุตัวแปรสำหรับระบบปฏิบัติการต่างๆเช่น:

ตรวจหา Microsoft Windows

if(WIN32)
    # for Windows operating system in general
endif()

หรือ:

if(MSVC OR MSYS OR MINGW)
    # for detecting Windows compilers
endif()

ตรวจหา Apple MacOS

if(APPLE)
    # for MacOS X or iOS, watchOS, tvOS (since 3.10.3)
endif()

ตรวจหา Unix และ Linux

if(UNIX AND NOT APPLE)
    # for Linux, BSD, Solaris, Minix
endif()

ปัญหาตัวเชื่อมโยงเฉพาะของคุณ

ในการแก้ปัญหาของคุณเกี่ยวกับwsock32ไลบรารีเฉพาะ Windows ให้ลบออกจากระบบอื่นเช่น:

if(WIN32)
    target_link_libraries(${PROJECT_NAME} bioutils wsock32)
else
    target_link_libraries(${PROJECT_NAME} bioutils)
endif()

คุณมีคำพิเศษจาก CMAKE โปรดดู:

if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
    // do something for Linux
else
    // do something for other OS

นอกจากนี้ยังมีนิพจน์เครื่องกำเนิดไฟฟ้า:

target_link_libraries(
    target_name
    PUBLIC
        libA
        $<$<PLATFORM_ID:Windows>:wsock32>
    PRIVATE
        $<$<PLATFORM_ID:Linux>:libB>
        libC
)

สิ่งนี้จะเชื่อมโยง libA, wsock32 & libC บน Windows และเชื่อมโยง libA, libB & libC บน Linux

นิพจน์ CMake Generator

ลองดู:

if(WIN32)
    set(ADDITIONAL_LIBRARIES wsock32)
else()
    set(ADDITIONAL_LIBRARIES "")
endif()

target_link_libraries(${PROJECT_NAME} bioutils ${ADDITIONAL_LIBRARIES})

คุณสามารถค้นหาตัวแปรที่มีประโยชน์อื่น ๆที่นี่

ฉันต้องการออกจากที่นี่เพราะฉันประสบปัญหานี้เมื่อรวบรวมสำหรับ Android ใน Windows ด้วย Android SDK

CMake แยกความแตกต่างระหว่างแพลตฟอร์ม TARGET และ HOST

TARGET ของฉันคือ Android ดังนั้นตัวแปรเช่น CMAKE_SYSTEM_NAME จึงมีค่า "Android" และตัวแปร WIN32 จากคำตอบอื่น ๆ ที่นี่จึงไม่ได้กำหนดไว้ แต่ฉันต้องการทราบว่าระบบ HOST ของฉันเป็น Windows หรือไม่เพราะฉันต้องทำบางสิ่งที่แตกต่างออกไปเมื่อคอมไพล์บน Windows หรือ Linux หรือ IO ในการทำเช่นนั้นฉันใช้ CMAKE_HOST_SYSTEM_NAME ซึ่งฉันพบว่าแทบไม่มีใครรู้จักหรือพูดถึงเลยเพราะสำหรับคนส่วนใหญ่ TARGEt และ HOST นั้นเหมือนกันหรือไม่สนใจ

หวังว่านี่จะช่วยใครสักคน ...

ใช้มาโครตัวประมวลผลล่วงหน้าเพื่อตรวจสอบว่าอยู่ใน windows หรือ linux หรือไม่ ตัวอย่างเช่น

#ifdef WIN32
LIB= 
#elif __GNUC__
LIB=wsock32
#endif

รวม -l $ (LIB) ในคำสั่ง build ของคุณ

คุณยังสามารถระบุอาร์กิวเมนต์บรรทัดคำสั่งเพื่อแยกความแตกต่างทั้งสองได้