ฉันจะค้นหาฐานข้อมูล SQL Server สำหรับสตริงได้อย่างไร

ฉันรู้ว่ามันเป็นไปได้ แต่ฉันไม่รู้วิธี

ฉันต้องการค้นหาฐานข้อมูล SQL Server สำหรับการกล่าวถึงสตริงเฉพาะทั้งหมด

ตัวอย่างเช่นฉันต้องการค้นหาตารางมุมมองฟังก์ชันกระบวนงานที่จัดเก็บไว้ทั้งหมด ... สำหรับสตริง "tblEmployes" (ไม่ใช่ข้อมูลภายในตาราง)

หนึ่งในเหตุผลที่ฉันต้องการสิ่งนี้คือฉันต้องการลบตารางข้อมูลพิเศษบางตารางที่สร้างขึ้น แต่ฉันกลัวว่าอาจจะถูกใช้ในขั้นตอนหรือฟังก์ชันที่ใดที่หนึ่ง

สิ่งนี้จะค้นหาทุกคอลัมน์ของทุกตารางในฐานข้อมูลเฉพาะ สร้างกระบวนงานที่เก็บไว้บนฐานข้อมูลที่คุณต้องการค้นหา

คำถามเกี่ยวกับเซิร์ฟเวอร์ SQL ที่ถูกถามมากที่สุดสิบคำถามและคำตอบของพวกเขา :

CREATE PROCEDURE FindMyData_String
    @DataToFind NVARCHAR(4000),
    @ExactMatch BIT = 0
AS
SET NOCOUNT ON

DECLARE @Temp TABLE(RowId INT IDENTITY(1,1), SchemaName sysname, TableName sysname, ColumnName SysName, DataType VARCHAR(100), DataFound BIT)

    INSERT  INTO @Temp(TableName,SchemaName, ColumnName, DataType)
    SELECT  C.Table_Name,C.TABLE_SCHEMA, C.Column_Name, C.Data_Type
    FROM    Information_Schema.Columns AS C
            INNER Join Information_Schema.Tables AS T
                ON C.Table_Name = T.Table_Name
        AND C.TABLE_SCHEMA = T.TABLE_SCHEMA
    WHERE   Table_Type = 'Base Table'
            And Data_Type In ('ntext','text','nvarchar','nchar','varchar','char')


DECLARE @i INT
DECLARE @MAX INT
DECLARE @TableName sysname
DECLARE @ColumnName sysname
DECLARE @SchemaName sysname
DECLARE @SQL NVARCHAR(4000)
DECLARE @PARAMETERS NVARCHAR(4000)
DECLARE @DataExists BIT
DECLARE @SQLTemplate NVARCHAR(4000)

SELECT  @SQLTemplate = CASE WHEN @ExactMatch = 1
                            THEN 'If Exists(Select *
                                          From   ReplaceTableName
                                          Where  Convert(nVarChar(4000), [ReplaceColumnName])
                                                       = ''' + @DataToFind + '''
                                          )
                                     Set @DataExists = 1
                                 Else
                                     Set @DataExists = 0'
                            ELSE 'If Exists(Select *
                                          From   ReplaceTableName
                                          Where  Convert(nVarChar(4000), [ReplaceColumnName])
                                                       Like ''%' + @DataToFind + '%''
                                          )
                                     Set @DataExists = 1
                                 Else
                                     Set @DataExists = 0'
                            END,
        @PARAMETERS = '@DataExists Bit OUTPUT',
        @i = 1

SELECT @i = 1, @MAX = MAX(RowId)
FROM   @Temp

WHILE @i <= @MAX
    BEGIN
        SELECT  @SQL = REPLACE(REPLACE(@SQLTemplate, 'ReplaceTableName', QUOTENAME(SchemaName) + '.' + QUOTENAME(TableName)), 'ReplaceColumnName', ColumnName)
        FROM    @Temp
        WHERE   RowId = @i


        PRINT @SQL
        EXEC SP_EXECUTESQL @SQL, @PARAMETERS, @DataExists = @DataExists OUTPUT

        IF @DataExists =1
            UPDATE @Temp SET DataFound = 1 WHERE RowId = @i

        SET @i = @i + 1
    END

SELECT  SchemaName,TableName, ColumnName
FROM    @Temp
WHERE   DataFound = 1
GO

ในการเรียกใช้ให้ทำสิ่งนี้:

exec FindMyData_string 'google', 0

ได้ผลดีอย่างน่าอัศจรรย์ !!!

หากคุณต้องการค้นหาวัตถุฐานข้อมูล (เช่นตารางคอลัมน์และทริกเกอร์) ตามชื่อลองดูที่เครื่องมือ Redgate Software ฟรีที่เรียกว่าSQL Searchซึ่งทำสิ่งนี้ - จะค้นหาฐานข้อมูลทั้งหมดของคุณเพื่อหาสตริงประเภทใดก็ได้

เป็นเครื่องมือที่ยอดเยี่ยมที่ต้องมีสำหรับ DBA หรือผู้พัฒนาฐานข้อมูล - ฉันเคยพูดถึงไปแล้วว่ามันใช้งานได้ฟรีทุกประเภทหรือไม่?

นอกจากนี้คุณยังสามารถลองApexSQL ค้นหา - มันเป็นฟรีSSMS add-in ที่คล้ายกับSQL ค้นหา

หากคุณต้องการใช้เฉพาะ SQL เท่านั้นคุณอาจต้องการลองใช้สคริปต์นี้:

select
S.name as [Schema],
o.name as [Object],
o.type_desc as [Object_Type],
C.text as [Object_Definition]
from sys.all_objects O inner join sys.schemas S on O.schema_id = S.schema_id
inner join sys.syscomments C on O.object_id = C.id
where S.schema_id not in (3,4) -- avoid searching in sys and INFORMATION_SCHEMA schemas
and C.text like '%ICE_%'
order by [Schema]

คุณสามารถส่งออกฐานข้อมูลของคุณ (ถ้ามีขนาดเล็ก) ไปยังฮาร์ดไดรฟ์ / เดสก์ท็อปของคุณจากนั้นทำการค้นหาสตริงผ่านโปรแกรมค้นหาข้อความหรือโปรแกรมแก้ไขข้อความ

สำหรับการรับตารางตามชื่อใน SQL Server:

SELECT *
FROM sys.Tables
WHERE name LIKE '%Employees%'

สำหรับการค้นหาโพรซีเดอร์ที่จัดเก็บตามชื่อ:

SELECT name
FROM sys.objects
WHERE name = 'spName'

ในการรับโพรซีเดอร์ที่จัดเก็บทั้งหมดที่เกี่ยวข้องกับตาราง:

----Option 1
SELECT DISTINCT so.name
FROM syscomments sc
INNER JOIN sysobjects so ON sc.id=so.id
WHERE sc.TEXT LIKE '%tablename%'
----Option 2
SELECT DISTINCT o.name, o.xtype
FROM syscomments c
INNER JOIN sysobjects o ON c.id=o.id
WHERE c.TEXT LIKE '%tablename%'

ขั้นตอนและฟังก์ชันการค้นหาโค้ดนี้ แต่ไม่ค้นหาในตาราง :)

SELECT name 
FROM   sys.all_objects 
WHERE  Object_definition(object_id) 
LIKE '%text%' 
ORDER BY name

คุณสามารถ;

1. เขียนสคริปต์ฐานข้อมูลเป็นไฟล์เดียวและค้นหาไฟล์สำหรับ tblEmployees โดยใช้โปรแกรมแก้ไขข้อความ ในSQL เซิร์ฟเวอร์การจัดการสตูดิโอ (SSMS) ให้คลิกขวามากกว่าฐานข้อมูลและเลือกสร้างสคริป
2. ใช้ SSMS 'View Dependencies' โดยคลิกขวาที่ tblEmployees เพื่อดูว่าวัตถุอื่น ๆ ขึ้นอยู่กับวัตถุใด
3. ใช้เครื่องมือของบุคคลที่สามฟรีเช่นการค้นหา SQL ของ Redgate Softwareเพื่อค้นหาวัตถุฐานข้อมูลทั้งหมดตามชื่อและเนื้อหาตามคำสำคัญ

สิ่งนี้จะค้นหาสตริงในทุกฐานข้อมูล:

declare @search_term varchar(max)
set @search_term = 'something'

select @search_term = 'use ? SET QUOTED_IDENTIFIER ON
select
    ''[''+db_name()+''].[''+c.name+''].[''+b.name+'']'' as [object],
    b.type_desc as [type],
    d.obj_def.value(''.'',''varchar(max)'') as [definition]
from (
    select distinct
        a.id
    from sys.syscomments a
    where a.[text] like ''%'+@search_term+'%''
) a
inner join sys.all_objects b
    on b.[object_id] = a.id
inner join sys.schemas c
    on c.[schema_id] = b.[schema_id]
cross apply (
    select
        [text()] = a1.[text]
    from sys.syscomments a1
    where a1.id = a.id
    order by a1.colid
    for xml path(''''), type
) d(obj_def)
where c.schema_id not in (3,4) -- avoid searching in sys and INFORMATION_SCHEMA schemas
    and db_id() not in (1,2,3,4) -- avoid sys databases'

if object_id('tempdb..#textsearch') is not null drop table #textsearch
create table #textsearch
(
    [object] varchar(300),
    [type] varchar(300),
    [definition] varchar(max)
)

insert #textsearch
exec sp_MSforeachdb @search_term

select *
from #textsearch
order by [object]

เวอร์ชั่นของฉัน ...

ฉันตั้งชื่อมันว่า "เข็มในกองหญ้า" ด้วยเหตุผลที่ชัดเจน

ค้นหาค่าเฉพาะในแต่ละแถวและแต่ละคอลัมน์ไม่ใช่สำหรับชื่อคอลัมน์เป็นต้น

ดำเนินการค้นหา (แทนที่ค่าสำหรับตัวแปรสองตัวแรกแน่นอน):

DECLARE @SEARCH_DB VARCHAR(100)='REPLACE_WITH_YOUR_DB_NAME'
DECLARE @SEARCH_VALUE_LIKE NVARCHAR(100)=N'%REPLACE_WITH_SEARCH_STRING%'

SET NOCOUNT ON;
DECLARE col_cur CURSOR FOR
SELECT TABLE_CATALOG, TABLE_SCHEMA, TABLE_NAME, COLUMN_NAME, DATA_TYPE
FROM information_schema.columns WHERE TABLE_CATALOG=@SEARCH_DB AND DATA_TYPE NOT IN ('timestamp', 'datetime');

DECLARE @TOTAL int = (SELECT COUNT(*)
FROM information_schema.columns WHERE TABLE_CATALOG=@SEARCH_DB AND DATA_TYPE NOT IN ('timestamp', 'datetime'));


DECLARE @TABLE_CATALOG nvarchar(500), @TABLE_SCHEMA nvarchar(500), @TABLE_NAME nvarchar(500), @COLUMN_NAME nvarchar(500), @DATA_TYPE nvarchar(500);
DECLARE @SQL nvarchar(4000)='';

PRINT '-------- BEGIN SEARCH --------';
OPEN col_cur;

FETCH NEXT FROM col_cur INTO @TABLE_CATALOG, @TABLE_SCHEMA, @TABLE_NAME, @COLUMN_NAME, @DATA_TYPE;

BEGIN TRY DROP TABLE ##RESULTS; END TRY BEGIN CATCH END CATCH
CREATE TABLE ##RESULTS( TABLE_CATALOG nvarchar(500), TABLE_SCHEMA nvarchar(500), TABLE_NAME nvarchar(500), COLUMN_NAME nvarchar(500), DATA_TYPE nvarchar(500), RECORDS int)
DECLARE @SHOULD_CAST bit=0
DECLARE @i int =0
DECLARE @progress_sum bigint=0

WHILE @@FETCH_STATUS = 0
BEGIN
    -- PRINT '' + CAST(@i as varchar(100)) +' of ' + CAST(@TOTAL as varchar(100)) + '  ' + @TABLE_CATALOG+'.'+@TABLE_SCHEMA+'.'+@TABLE_NAME+': '+@COLUMN_NAME+' ('+@DATA_TYPE+')';

    SET @SHOULD_CAST = (SELECT CASE @DATA_TYPE
                                WHEN 'varchar' THEN 0
                                WHEN 'nvarchar' THEN 0
                                WHEN 'char' THEN 0
                                ELSE 1 END)

    SET @SQL='SELECT '''+@TABLE_CATALOG+''' catalog_name, '''+@TABLE_SCHEMA+''' schema_name, '''+@TABLE_NAME+''' table_name, '''+@COLUMN_NAME+''' column_name, '''+@DATA_TYPE+''' data_type, ' +
            +' COUNT(['+@COLUMN_NAME+']) records '+
            +' FROM '+@TABLE_CATALOG+'.'+@TABLE_SCHEMA+'.'+@TABLE_NAME +
            +' WHERE ' + CASE WHEN @SHOULD_CAST=1 THEN 'CAST(['+@COLUMN_NAME + '] as NVARCHAR(max)) ' ELSE ' ['+@COLUMN_NAME + '] ' END
            +' LIKE '''+ @SEARCH_VALUE_LIKE + ''' '

    -- PRINT @SQL;

    IF @i % 100 = 0
        BEGIN
            SET @progress_sum = (SELECT SUM(RECORDS) FROM ##RESULTS)
            PRINT CAST (@i as varchar(100)) +' of ' + CAST(@TOTAL as varchar(100)) +': '+ CAST (@progress_sum as varchar(100))
        END

    INSERT INTO ##RESULTS (TABLE_CATALOG, TABLE_SCHEMA, TABLE_NAME, COLUMN_NAME, DATA_TYPE, RECORDS)
    EXEC(@SQL)

    FETCH NEXT FROM col_cur INTO @TABLE_CATALOG, @TABLE_SCHEMA, @TABLE_NAME, @COLUMN_NAME, @DATA_TYPE;
    SET @i=@i+1
    -- IF @i > 1000
    --     BREAK
END
CLOSE col_cur;
DEALLOCATE col_cur;

SELECT * FROM ##RESULTS WHERE RECORDS>0;

จากนั้นหากต้องการดูผลลัพธ์แม้ในขณะดำเนินการจากหน้าต่างอื่นให้ดำเนินการ:

DECLARE @SEARCH_VALUE_LIKE NVARCHAR(100)=N'%@FLEX@%'
SELECT * FROM ##RESULTS WHERE RECORDS>0;

SET NOCOUNT ON;
DECLARE col_cur CURSOR FOR
SELECT TABLE_CATALOG, TABLE_SCHEMA, TABLE_NAME, COLUMN_NAME, DATA_TYPE
FROM ##RESULTS WHERE RECORDS>0;

DECLARE @TABLE_CATALOG nvarchar(500), @TABLE_SCHEMA nvarchar(500), @TABLE_NAME nvarchar(500), @COLUMN_NAME nvarchar(500), @DATA_TYPE nvarchar(500);
DECLARE @SQL nvarchar(4000)='';

OPEN col_cur;

FETCH NEXT FROM col_cur INTO @TABLE_CATALOG, @TABLE_SCHEMA, @TABLE_NAME, @COLUMN_NAME, @DATA_TYPE;
DECLARE @i int =0
DECLARE @SHOULD_CAST bit=0

WHILE @@FETCH_STATUS = 0
BEGIN
    SET @SHOULD_CAST = (SELECT CASE @DATA_TYPE
                                WHEN 'varchar' THEN 0
                                WHEN 'nvarchar' THEN 0
                                WHEN 'char' THEN 0
                                ELSE 1 END)

    SET @SQL='SELECT '''+@TABLE_CATALOG+''' catalog_name, '''+@TABLE_SCHEMA+''' schema_name, '''+@TABLE_NAME+''' table_name, '''+@COLUMN_NAME+''' column_name, '''+@DATA_TYPE+''' data_type, ' +
            +' ['+@COLUMN_NAME+']'+
            +', * '
            +' FROM '+@TABLE_CATALOG+'.'+@TABLE_SCHEMA+'.'+@TABLE_NAME +
            +' WHERE ' + CASE WHEN @SHOULD_CAST=1 THEN 'CAST(['+@COLUMN_NAME + '] as NVARCHAR(max)) ' ELSE ' ['+@COLUMN_NAME + '] ' END
            +' LIKE '''+ @SEARCH_VALUE_LIKE + ''' '

    PRINT @SQL;

    EXEC(@SQL)

    FETCH NEXT FROM col_cur INTO @TABLE_CATALOG, @TABLE_SCHEMA, @TABLE_NAME, @COLUMN_NAME, @DATA_TYPE;
    SET @i=@i+1
    -- IF @i > 10
    --    BREAK
END
CLOSE col_cur;
DEALLOCATE col_cur;

มีบางคนกล่าวถึงเรื่องนี้:

• มันใช้เคอร์เซอร์แทนการบล็อกในขณะที่วนซ้ำ
• สามารถพิมพ์ความคืบหน้า (ไม่แสดงความคิดเห็นหากจำเป็น)
• มันสามารถออกได้หลังจากพยายามสองสามครั้ง (ไม่ใส่เครื่องหมาย IF ในตอนท้าย)
• จะแสดงบันทึกทั้งหมด
• คุณสามารถปรับแต่งได้ตามต้องการ

ความรับผิดชอบ:

• อย่าใช้งานในสภาพแวดล้อมการผลิต!
• มันเป็นช้า หากบริการ / ผู้ใช้อื่นเข้าถึงฐานข้อมูลได้โปรดเพิ่ม "ด้วย (NOLOCK)" หลังทุกชื่อตารางในการเลือกทั้งหมดโดยเฉพาะอย่างยิ่งรายการเลือกแบบไดนามิก
• ไม่ตรวจสอบ / ป้องกันตัวเลือกการฉีด SQL ทุกประเภท
• หากฐานข้อมูลของคุณมีขนาดใหญ่ให้เตรียมตัวสำหรับการนอนหลับตรวจสอบให้แน่ใจว่าแบบสอบถามจะไม่ถูกฆ่าหลังจากผ่านไปสักครู่
• มันร่ายค่าบางอย่างให้กับสตริงรวมถึง ints / bigints / smallints / tinyints หากคุณไม่ต้องการสิ่งเหล่านี้ให้วางไว้ในรายการยกเว้นเดียวกันโดยมีการประทับเวลาที่ด้านบนของสคริปต์

ฉันได้รับสิทธิ์เข้าถึงฐานข้อมูล แต่ไม่ใช่ตารางที่เก็บแบบสอบถามของฉัน

แรงบันดาลใจจาก@marc_s answe r ฉันได้ดูHeidiSQLซึ่งเป็นโปรแกรม Windows ที่สามารถจัดการกับ MySQL, SQL Server และ PostgreSQL

ฉันพบว่ามันสามารถค้นหาฐานข้อมูลสำหรับสตริงได้ด้วย

มันจะค้นหาแต่ละตารางและให้คุณพบสตริงต่อตารางกี่ครั้ง!

เนื้อหาวิธีการจัดเก็บทุกมุมมองและฟังก์ชั่นจะถูกเก็บไว้ในด้านข้อความของตารางsysComments ชื่อของวัตถุทั้งหมดจะถูกเก็บไว้ในตารางsysobjectsและคอลัมน์อยู่ในsyscolumns

เมื่อมีข้อมูลนี้คุณสามารถใช้รหัสนี้เพื่อค้นหาเนื้อหาของมุมมองโพรซีเดอร์ที่จัดเก็บและฟังก์ชันสำหรับคำที่ระบุ:

Select b.name from syscomments a
inner join sysobjects b on a.id = b.id
where text like '%tblEmployes%'

แบบสอบถามนี้จะให้วัตถุที่มีคำว่า "tblEmployes"

ในการค้นหาโดยใช้ชื่อ Objects คุณสามารถใช้รหัสนี้:

Select name from sysobjects
where name like  '%tblEmployes%'

และในที่สุดเพื่อค้นหาวัตถุที่มีอย่างน้อยหนึ่งคอลัมน์ที่มีคำว่า "tblEmployes" คุณสามารถใช้รหัสนี้:

Select b.name from syscolumns a inner join sysobjects b on a.id = b.id
where a.name like  '%tblEmployes%'

คุณสามารถรวมสามแบบสอบถามนี้เข้ากับสหภาพ:

Select distinct b.name from syscomments a
inner join sysobjects b on a.id = b.id
where text like '%tblEmployes%'
union
Select distinct name from sysobjects
where name like  '%tblEmployes%'
union
Select distinct b.name from syscolumns a inner join sysobjects b on a.id = b.id
where a.name like  '%tblEmployes%'

ด้วยแบบสอบถามนี้คุณมีวัตถุทั้งหมดที่มีคำว่า "tblEmployes" ในเนื้อหาหรือชื่อหรือเป็นคอลัมน์

นี่คือสคริปต์เดียวกับที่ส่งโดยผู้ใช้ l --''''''--------- '' '' '' '' ''แต่ได้รับการแก้ไขให้ทำงานบน SQL ที่คำนึงถึงตัวพิมพ์เล็กและใหญ่ อินสแตนซ์และการปรับปรุงเล็กน้อยอื่น ๆ

DROP PROCEDURE IF EXISTS dbo.spFind_Text_In_Database
GO

CREATE PROCEDURE dbo.spFind_Text_In_Database
    @strText_To_Find NVARCHAR(4000),
    @bitExact_Match BIT = 0
AS
SET NOCOUNT ON

DECLARE @Temp TABLE(RowId INT IDENTITY(1,1), SchemaName sysname, TableName sysname, ColumnName SysName, DataType VARCHAR(100), DataFound BIT)

    INSERT  INTO @Temp(TableName,SchemaName, ColumnName, DataType)
    SELECT  C.TABLE_NAME, C.TABLE_SCHEMA, C.COLUMN_NAME, C.DATA_TYPE
    FROM    INFORMATION_SCHEMA.COLUMNS AS C
            INNER Join INFORMATION_SCHEMA.TABLES AS T
                ON C.TABLE_NAME = T.TABLE_NAME
        AND C.TABLE_SCHEMA = T.TABLE_SCHEMA
    WHERE   TABLE_TYPE = 'BASE TABLE'
            And DATA_TYPE In ('ntext','text','nvarchar','nchar','varchar','char')


DECLARE @i INT
DECLARE @MAX INT
DECLARE @TableName sysname
DECLARE @ColumnName sysname
DECLARE @SchemaName sysname
DECLARE @SQL NVARCHAR(4000)
DECLARE @PARAMETERS NVARCHAR(4000)
DECLARE @DataExists BIT
DECLARE @SQLTemplate NVARCHAR(4000)

SELECT  @SQLTemplate = CASE WHEN @bitExact_Match = 1
                            THEN 'If Exists(Select *
                                          From   ReplaceTableName
                                          Where  Convert(nVarChar(4000), [ReplaceColumnName])
                                                       = ''' + @strText_To_Find + '''
                                          )
                                     Set @DataExists = 1
                                 Else
                                     Set @DataExists = 0'
                            ELSE 'If Exists(Select *
                                          From   ReplaceTableName
                                          Where  Convert(nVarChar(4000), [ReplaceColumnName])
                                                       Like ''%' + @strText_To_Find + '%''
                                          )
                                     Set @DataExists = 1
                                 Else
                                     Set @DataExists = 0'
                            END,
        @PARAMETERS = '@DataExists Bit OUTPUT',
        @i = 1

SELECT @i = 1, @MAX = MAX(RowId)
FROM   @Temp

WHILE @i <= @MAX
    BEGIN
        SELECT  @SQL = REPLACE(REPLACE(@SQLTemplate, 'ReplaceTableName', QUOTENAME(SchemaName) + '.' + QUOTENAME(TableName)), 'ReplaceColumnName', ColumnName)
        FROM    @Temp
        WHERE   RowId = @i


        PRINT @SQL
        EXEC sp_executesql @SQL, @PARAMETERS, @DataExists = @DataExists OUTPUT

        IF @DataExists =1
            UPDATE @Temp SET DataFound = 1 WHERE RowId = @i

        SET @i = @i + 1
    END

SELECT  SchemaName,TableName, ColumnName
FROM    @Temp
WHERE   DataFound = 1
GO

การค้นหาอ็อบเจ็กต์ฐานข้อมูล SQL เป็นไปได้ด้วยSQL Server Management Studio (SSMS) ด้วยวิธีการต่อไปนี้โดยใช้ SSMS Object Search: รายละเอียด object explorer หรือสคริปต์T-SQLตามที่อธิบายต่อไปนี้:

• วิธีต่างๆในการค้นหาวัตถุฐานข้อมูล SQL Server
• SQL Server ค้นหาทุกสิ่งใน Object Explorer ใน SSMS
• ค้นหาข้อความด้วยสัญลักษณ์แทน

นี่คือวิธีค้นหาฐานข้อมูลใน Swift โดยใช้ไลบรารี FMDB

แรกไปที่ลิงก์นี้และเพิ่มนี้กับโครงการของคุณ: FMDB เมื่อคุณทำเสร็จแล้วนี่คือวิธีที่คุณทำ ตัวอย่างเช่นคุณมีตารางชื่อบุคคลและคุณมี firstName และ secondName และคุณต้องการค้นหาข้อมูลโดยใช้ชื่อนี่คือรหัสสำหรับสิ่งนั้น:

    func loadDataByfirstName(firstName : String, completion: @escaping CompletionHandler){
    if isDatabaseOpened {
        let query = "select * from Person where firstName like '\(firstName)'"
        do {
            let results = try database.executeQuery(query, values: [firstName])
            while results.next() {
                let firstName = results.string(forColumn: "firstName") ?? ""
                let lastName = results.string(forColumn: "lastName") ?? ""
                let newPerson = Person(firstName: firstName, lastName: lastName)
                self.persons.append(newPerson)
            }
            completion(true)
        }catch let err {
            completion(false)
            print(err.localizedDescription)
        }
        database.close()
    }
}

จากนั้นใน ViewController ของคุณคุณจะเขียนสิ่งนี้เพื่อค้นหารายละเอียดบุคคลที่คุณต้องการ:

  override func viewWillAppear(_ animated: Bool) {
     super.viewWillAppear(animated)
      SQLManager.instance.openDatabase { (success) in
        if success {
            SQLManager.instance.loadDataByfirstName(firstName: "Hardi") { (success) in
                if success {
                    // You have your data Here
                }
            }
        }
    }
}

หากฉันต้องการค้นหาสิ่งที่ฉันต้องการค้นหาฉันใช้สิ่งนี้:

DECLARE @search_string    varchar(200)
    SET @search_string = '%myString%'

    SELECT DISTINCT
           o.name AS Object_Name,
           o.type_desc,
           m.definition
      FROM sys.sql_modules m
           INNER JOIN
           sys.objects o
             ON m.object_id = o.object_id
     WHERE m.definition Like @search_string;