คำสั่งเพื่อค้นหาอินเตอร์เฟสเครือข่ายสำหรับ IP

ด้วยipconfigฉันสามารถแสดงรายการของอะแดปเตอร์เครือข่ายและการตั้งค่าของพวกเขาเช่นที่อยู่ IP

ฉันกำลังมองหาคำสั่งย้อนกลับที่แสดงชื่อของอะแดปเตอร์เครือข่ายสำหรับที่อยู่ IP ที่กำหนด

ฉันได้ลองกรองผลลัพธ์ipconfigด้วยคำสั่งที่ชอบipconfig | find "192.168.2.4"แต่แล้วชื่ออะแดปเตอร์หายไป

ผลลัพธ์ของฉันipconfigคือ (ส่วนที่ยุ่งยากดูเหมือนว่าฉันมีที่อยู่หลายแห่งในหนึ่งอะแดปเตอร์ที่นี่):

Windows IP Configuration


Ethernet adapter Local Area Connection:

   Connection-specific DNS Suffix  . :
   Link-local IPv6 Address . . . . . : fe80::xxxx:xxxx:xxxx:xxxx%11
   IPv4 Address. . . . . . . . . . . : 192.168.2.4
   Subnet Mask . . . . . . . . . . . : 255.255.255.0
   IPv4 Address. . . . . . . . . . . : 192.168.178.20
   Subnet Mask . . . . . . . . . . . : 255.255.255.0
   Default Gateway . . . . . . . . . : 192.168.178.1
                                       192.168.2.1

Ethernet adapter VMware Network Adapter VMnet1:
...

ฉันจะแสดงชื่อของอะแดปเตอร์เครือข่ายสำหรับที่อยู่ IP ที่กำหนดได้อย่างไร

การแก้ปัญหานี้ไม่ไม่จำเป็นต้องมีคำสั่งภายนอกใด ๆ ( pcre2grep, sedฯลฯ )

ใช้แบตช์ไฟล์ต่อไปนี้ (getname.cmd):

@echo off
setlocal
setlocal enabledelayedexpansion
set "_adapter="
set "_ip="
for /f "tokens=1* delims=:" %%g in ('ipconfig /all') do (
  set "_tmp=%%~g"
  if "!_tmp:adapter=!"=="!_tmp!" (
    if not "!_tmp:IPv4 Address=!"=="!_tmp!" (
      for %%i in (%%~h) do (
      if not "%%~i"=="" set "_ip=%%~i"
      )
    set "_ip=!_ip:(Preferred)=!"
    if "!_ip!"=="%1" (
        @echo !_adapter!
      )
    )
  ) else (
    set "_ip="
    set "_adapter=!_tmp:*adapter =!"
  )
)
endlocal

การใช้งาน:

getname ipaddress

ตัวอย่าง:

F:\test>getname 192.168.42.78
Local Area Connection 2
F:\test>

อ่านเพิ่มเติม

• ดัชนี AZ ของบรรทัดคำสั่ง Windows CMD - การอ้างอิงที่ยอดเยี่ยมสำหรับทุกสิ่งที่เกี่ยวข้องกับบรรทัด Windows cmd
• for / f - คำสั่งวนซ้ำกับผลลัพธ์ของคำสั่งอื่น
• ipconfig - กำหนดค่า IP (การกำหนดค่าอินเทอร์เน็ตโปรโตคอล)

คุณสามารถใช้ PS หนึ่งซับนี้:

$addr='192.168.2.4'; get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr} |select Description |% {$_.Description}

วิธีใช้โดยตรงจากบรรทัดคำสั่ง:

powershell "$addr='192.168.2.4'; get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr} |select Description |% {$_.Description}"

หรือถ้าคุณต้องการที่จะนำมันกลับมาใช้ใหม่ในสคริปต์และทำให้ที่อยู่พารามิเตอร์

แก้ไข: เพื่อรับชื่อตามที่แสดงใน Win / Ipconfig:

$addr='192.168.2.4'; 
$netconf = get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr};
$netconf |% {$_.GetRelated("win32_NetworkAdapter")} | select NetConnectionID |%{$_.NetConnectionID}

(การกำหนดให้กับตัวแปรตัวกลางเป็นเพียงเพื่อให้อ่านได้ง่ายขึ้น)

ฉันกำลังมองหาคำสั่งย้อนกลับที่แสดงชื่อของอะแดปเตอร์เครือข่ายสำหรับที่อยู่ IP ที่กำหนด

จากทุกสิ่งที่ฉันพยายามมันน่าจะทำงานได้ดีถ้าคุณบอกว่าคุณต้องได้รับข้อมูลนี้จากที่อยู่ IP ที่คุณระบุไว้ในตัวอย่างเท่านั้น

PROMPT แบบโต้ตอบสำหรับที่อยู่ IP เพื่อรับชื่อการเชื่อมต่อเครือข่าย

(ใช้WMICและบางชุดFORวนtokenและการdelimแยกเพื่อรับชื่อการเชื่อมต่อเครือข่ายสำหรับที่อยู่ IP ที่ระบุ)

(ค่าผลลัพธ์จะสะท้อนไปที่หน้าต่างคำสั่งและหน้าต่างกล่องข้อความมันเป็นสคริปต์ชุดงานทั้งหมด แต่สร้างฟังก์ชัน VBS script แบบไดนามิกเพื่อให้กระบวนการสำหรับผู้ที่ต้องการง่ายขึ้น)

@ECHO ON

:SetTempFiles
SET tmpIPaddr=%tmp%\~tmpipaddress.vbs
SET tmpNetConName1=%tmp%\~tmpNetConName1.txt
SET tmpNetConName2=%tmp%\~tmpNetConName2.txt
SET tmpBatFile=%tmp%\~tmpBatch.cmd
SET tmpVBNetCon=%tmp%\~tmpVBNetCon.vbs

IF EXIST "%tmpIPaddr%" DEL /F /Q "%tmpIPaddr%"
IF EXIST "%tmpNetConName1%" DEL /Q /F "%tmpNetConName1%"
IF EXIST "%tmpNetConName2%" DEL /Q /F "%tmpNetConName2%"
IF EXIST "%tmpBatFile%" DEL /Q /F "%tmpBatFile%"
IF EXIST "%tmpVBNetCon%" DEL /Q /F "%tmpVBNetCon%"

:InputBox
SET msgboxTitle=IP ADDRESS
SET msgboxLine1=Enter the IP address to get its Windows connection name
>"%tmpIPaddr%" ECHO wsh.echo inputbox("%msgboxLine1%","%msgboxTitle%")
FOR /F "tokens=*" %%N IN ('cscript //nologo "%tmpIPaddr%"') DO CALL :setvariables %%N
GOTO EOF

:setvariables
SET IPAddress=%~1
FOR /F "USEBACKQ TOKENS=3 DELIMS=," %%A IN (`"WMIC NICCONFIG GET IPADDRESS,MACADDRESS /FORMAT:CSV | FIND /I "%IPAddress%""`) DO (SET MACAddress=%%~A)
FOR /F "USEBACKQ TOKENS=3 DELIMS=," %%B IN (`"WMIC NIC GET MACADDRESS,NETCONNECTIONID /FORMAT:CSV | FIND /I "%MACAddress%""`) DO ECHO(%%~B>>"%tmpNetConName1%"

::: Parse Empty Lines
FINDSTR "." "%tmpNetConName1%">"%tmpNetConName2%"

::: Build Dynamic Batch with ECHO'd Network Connection Value
FOR /F "tokens=*" %%C IN (%tmpNetConName2%) DO ECHO ECHO %%~C>>"%tmpBatFile%"
IF NOT EXIST "%tmpBatFile%" GOTO :NullExit
START "" "%tmpBatFile%"

::: Build Dynamic VBS with Message Box Network Connection Value
FOR /F "tokens=*" %%C IN (%tmpNetConName2%) DO (SET vbNetconName=%%~C)
ECHO msgbox "%vbNetconName%",0,"%vbNetconName%">"%tmpVBNetCon%"
START /B "" "%tmpVBNetCon%"
EXIT /B

:NullExit
ECHO msgbox "Cannot find MAC Address, check to confirm IP Address was correct.",0,"Invalid IP">"%tmpVBNetCon%"
START /B "" "%tmpVBNetCon%"
EXIT /B

ทุกสายการบิน

WINDOWS ดั้งเดิมเฉพาะกับ NETSH ทั้งหมด (ที่อยู่ IPv4 ทั้งหมด)

NETSH INT IP SHOW CONFIG | FINDSTR /R "Configuration for interface.* Address.*[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"

Windows พื้นเมืองเท่านั้นกับ IPCONFIG การเชื่อมต่อทั้งหมด (ที่อยู่ IPv4 ทั้งหมด)

IPCONFIG | FINDSTR /R "Ethernet* Address.*[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"

การใช้ PCRE2GREP (ต่อ @SalvoF)

ระบุที่อยู่ IP เดียว

netsh interface ipv4 show address | pcre2grep -B2 "192\.168\.2\.4" | FIND /V "DHCP"

ค้นหาที่อยู่ IP ทั้งหมด

netsh interface ip show config | pcre2grep -B2 ^(?:[0-9]{1,3}\.){3}[0-9]{1,3}$ | FIND /V "DHCP" | FIND /V "Gate" | FIND /V "Metric" | FIND /V "Subnet"

ค้นหาที่อยู่ IP ทั้งหมด (ล้าง Regex (ต่อ @SalvoF))

netsh interface ip show config | pcre2grep "^[A-Z]|IP.*([0-9]{1,3}(\.|)){4}"

โปรดทราบว่าpcre2grepฉันพยายามต่อ @SalvoF [+1]ตามที่เขาแนะนำ แต่ใช้ .... FIND /Vเพื่อลบบรรทัดด้านบนที่มีอยู่DHCPดูเหมือนว่าจะได้รับผลลัพธ์ที่ต้องการตามที่คุณอธิบาย ฉันใช้NETSHมากกว่าIPCONFIGเช่นกัน

เพื่อความแม่นยำมากขึ้นตามตัวอย่างของ OP ฉันจะใช้sedซึ่งสามารถพบได้ภายใต้\usr\local\wbinโฟลเดอร์ของไฟล์ซิปนี้ (โครงการ UnxUtils)

ipconfig | sed -rn "/^[A-Z]/h;/192.168.2.4/{g;s/.* adapter (.*):/\1/p;}"

-nไม่แสดงบรรทัดที่ไม่ตรงกัน รูปแบบแรกพบบรรทัดใด ๆ ที่ขึ้นต้นด้วยตัวอักษรพิมพ์ใหญ่แล้วhวางไว้บนพื้นที่พัก การจับคู่ที่สองคือหมายเลข IP ที่ต้องการ: ณ จุดนี้ชื่อส่วนต่อประสานสายจะถูกเรียกคืน ( g), ข้อความนำหน้าพิเศษที่ถูกตัด ( s) และพิมพ์ ( p)

สำหรับระเบียนนี่เป็นอีกโซลูชันหนึ่งของชุดข้อมูลซึ่งใช้ประโยชน์จากการขยายตัวแบบล่าช้าของ%ERRORLEVEL%ตัวแปรระบบ:

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%L in ('ipconfig') do (
    echo %%L | findstr /r "^[A-Z]" 1>NUL
    if !errorlevel! == 0 set "_int=%%L"
    echo %%L | findstr /c:%1 1>NUL
    if !errorlevel! == 0 (
       set "_int=!_int::=!"
       echo !_int:* adapter =!
       goto:eof
    )
)

สามารถเรียกใช้วิธีนี้ได้: find_int.cmd 192.168.1.100

ขอบคุณสำหรับความพยายามทุกคน ดูเหมือนว่ามีอุปสรรคหลายอย่าง:

• จำนวนที่อยู่ IP ที่กำหนดให้กับอะแดปเตอร์
• ภาษาของระบบปฏิบัติการ

ทุกสิ่ง-Bxและ Regex ดูเหมือนจะแตกง่ายดังนั้นฉันจึงไปหาสิ่งที่ฉันสามารถนำไปใช้เองและมากับโปรแกรม C # ต่อไปนี้ซึ่งใช้ที่อยู่ IP เป็นพารามิเตอร์ ( IP2Adapter <IP>):

using System;
using System.Net.NetworkInformation;
using System.Net.Sockets;

namespace IP2Adapter
{
    class Program
    {
        static void Main(string[] args)
        {
            var adapters = NetworkInterface.GetAllNetworkInterfaces();
            foreach (var adapter in adapters)
            {
                var ipProps = adapter.GetIPProperties();
                foreach (var ip in ipProps.UnicastAddresses)
                {
                    if ((adapter.OperationalStatus == OperationalStatus.Up)
                        && (ip.Address.AddressFamily == AddressFamily.InterNetwork))
                    {
                        if (ip.Address.ToString() == args[0])
                        Console.Out.WriteLine(adapter.Name);
                    }
                }
            }
        }
    }
}

บน Windows 10 Powershell สามารถทำได้ดังนี้:

Get-NetIPAddress -IPAddress '192.168.2.4' | %{$_.InterfaceAlias};

Wi-Fiนี้จะให้ผลเช่น

โดยที่คุณสามารถทดแทนInterfaceAliasคุณสมบัติวัตถุอื่นได้

Get-NetIPAddress -IPAddress '192.168.2.4'ที่จะได้รับคุณสมบัติทั้งหมดเพียงแค่ละเว้นท่อและเรียกใช้:

คุณสมบัติที่เกี่ยวข้องกับอะแดปเตอร์เครือข่ายอื่น ๆ (เช่นคำอธิบาย) สามารถสอบถามได้โดยขึ้นอยู่กับInterfaceAliasหรือInterfaceIndexเช่น:

Get-NetAdapter -InterfaceAlias Wi-Fi | %{$_.InterfaceDescription};

ซึ่งจะให้สิ่งที่ต้องการ: Intel(R) Dual Band Wireless-AC 8265.

อ่านเพิ่มเติมเกี่ยวกับเอกสาร: https://docs.microsoft.com/en-us/powershell/module/nettcpip/get-netipaddress?view=win10-ps