ยูทิลิตี้ของ Windows เพื่อแสดงว่าฉันกำลังกดแป้นใดบนหน้าจอ [ปิด]

ฉันกำลังฝึกอบรมให้กับคนกลุ่มใหญ่จากระยะไกลและจะครอบคลุมปุ่มลัดของแอปพลิเคชันจำนวนมาก

ฉันเคยเห็นการกดปุ่มบนหน้าจอของMousePose ; มีผลิตภัณฑ์ที่คล้ายกันสำหรับ Windows หรือไม่

คุณสมบัติอื่น ๆ ของ MousePose (ตัวชี้เมาส์แฟนซี ฯลฯ ) ไม่ได้มีประโยชน์สำหรับฉันจริงๆเพียงแค่ OSD ของการกดปุ่ม

KeyPoséเป็นทางเลือกฟรีสำหรับMousePoséสำหรับ Windows คุณสามารถดูได้ในการดำเนินการในscreencast

นี่คือภาพตัวอย่าง:

ผมขอแนะนำให้คาร์นัค เป็นโครงการฟรีที่โฮสต์ใน GitHub

ยูทิลิตี้การบันทึกแป้นพิมพ์และงานนำเสนอสำหรับการนำเสนอหน้าจอและเพื่อช่วยให้คุณเป็นผู้ใช้คีย์บอร์ดที่ดีขึ้น

ก็ดำเนินการอย่างได้รับการออกแบบอย่างสวยงามและยังเปิดมาบน GitHub

ค้นหาการวางจำหน่ายทางแยกพร้อมการแก้ไขและการแสดงภาพของอินพุตเมาส์ที่นี่: https://github.com/bfritscher/carnac/releases/tag/v3-beta

ฉันต้องการแชร์เครื่องมือ - keycastow

https://brookhong.github.io/2014/04/28/keycast-on-windows.html

ฉันเขียนสคริปต์ AutoHotkey_L เพื่อจุดประสงค์นี้

หากต้องการเรียกใช้ใช้AutoHotkey_L ( direct dl ) คือ FOSS นอกจากนี้ด้วย AutoHotkey คุณสามารถรวบรวมสคริปต์เพื่อ EXE (เพียง)Ahk2Exe.exe /inDisplayPressedKeyOnScreen.ahk/outDisplayPressedKeyOnScreen.exe

มันสามารถแสดงปุ่มกดคล้าย OSD หรือ Tool-tip มาตรฐานใกล้เคอร์เซอร์ของเมาส์ นอกจากนี้ยังแสดงการคลิกปุ่มเมาส์และการเลื่อนด้วยล้อ

(โปรดทราบว่าเฟรมและการเบลอของภาพนั้นทำขึ้นเพื่อจุดประสงค์ในการแสดงเท่านั้นสคริปต์จะแสดงเฉพาะข้อความที่ไม่มีการรบกวนใด ๆ )

นี่คือสคริปต์ (คัดลอกและวางไปยัง Notepad บันทึกเป็น DisplayPressedKeysOnScreen.ahk):

#NoEnv
#SingleInstance force
#InstallKeybdHook

Global KeyStates, MouseState, ClickCount, IdleDelay, LargeDisplay

IdleDelay=3000

LargeDisplay=1
; 0 = Tooltip near mouse pointer
; 1 = Big pane at screen bottom

If LargeDisplay
{
;Initializing GUI
;modded func originated from http://www.autohotkey.com/board/topic/8190-osd-function/

SysGet Monitor, Monitor

GUIx := MonitorLeft
GUIw := MonitorRight - MonitorLeft
GUIh := (MonitorBottom - MonitorTop) * GUIw * 0.00003
If (GUIh > ((MonitorBottom - MonitorTop) * 0.3))
    GUIh := (MonitorBottom - MonitorTop) * 0.3

opacity=230
fname="Tahoma"
fsize:=GUIh * 0.65 ; really, pixel = 0.75 point, but with 0.75 lowercase letter with lower part (like "g") get cut
fcolor=cccccc
bcolor=222222
fformat="600"

Gui +LastFound +AlwaysOnTop +ToolWindow -Caption
Gui Margin, 0, 0 ;pixels of space to leave at the left/right and top/bottom sides of the window when auto-positioning.
Gui Color, ffffff ;changes background color
Gui Font, s%fsize% w%fformat%, %fname%

;    0x80 = SS_NOPREFIX -> Ampersand (&) is shown instead of underline one letter for Alt+letter navigation
Gui Add, Text, c%bcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName, tesT test test
Gui Add, Text, c%fcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName2 xp-3 yp-3 , tesT test test

WinSet ExStyle, +0x20 ; WS_EX_TRANSPARENT -> mouse klickthrough
WinSet TransColor, ffffff %opacity%
}


TrayTip %A_ScriptName%, To Exit`, press the Right Windows logo key.

Loop
{
Input SingleKey, L1 V M I B, {LControl}{RControl}{LAlt}{RAlt}{LShift}{RShift}{LWin}{AppsKey}{F1}{F2}{F3}{F4}{F5}{F6}{F7}{F8}{F9}{F10}{F11}{F12}{Left}{Right}{Up}{Down}{Home}{End}{PgUp}{PgDn}{Del}{Ins}{BS}{Capslock}{Numlock}{PrintScreen}{Pause}
GetKeyStates()

;    IfInString ErrorLevel, EndKey
;   CollectedText .= (CollectedText =="" ? "" : " + " ) . SubStr(ErrorLevel, 8)
If SingleKey
{
    SingleKeyText=
    If (SingleKey==Chr(27))
    SingleKeyText=Esc
    Else If (SingleKey==Chr(32))
    SingleKeyText=Space

    If (GetKeyState("LControl", "P") || GetKeyState("RControl", "P"))
    {
    If (SingleKey==Chr(10) && EnterPressed)
        SingleKeyText=Enter
    Else If (SingleKey >= Chr(1) && SingleKey <= Chr(26)) ; With "M" in Input, Ctrl-A through Ctrl-Z correspond to Chr(1) through Chr(26)
        SingleKeyText := Chr(Asc("A")-1+Asc(SingleKey))
    } Else {
    If (SingleKey==Chr(10))
        SingleKeyText=Enter
    }

    If Not SingleKeyText
    SingleKeyText:=SingleKey
    ShowKeys(KeyStates . SingleKeyText)
;    . (MouseState ? "`n" . MouseState : "")
    EnterPressed=0
    GoSub ClearMouseState
} Else {
    ShowKeys(SubStr(KeyStates, 1, -3) . (MouseState ? " + " . MouseState : ""))
}
SetTimer TooltipOff, % -IdleDelay
}

RWin::
ExitApp

~*Enter::
EnterPressed=1
return

~*LButton::
~*RButton::
~*MButton::
~*XButton1::
~*XButton2::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3) . " Pressed"
MouseTooltip()
return

~*WheelDown::
~*WheelUp::
~*WheelLeft::
~*WheelRight::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3)
MouseTooltip()
return

~*LButton Up::
~*RButton Up::
~*MButton Up::
~*XButton1 Up::
~*XButton2 Up::
;    MsgBox %A_PriorHotkey%`n%A_ThisHotkey%
If (A_PriorHotkey == SubStr(A_ThisHotkey, 1, -3) && A_TimeSincePriorHotkey < 200)
{
    ClickCount++
    Suffix := " Clicked " . ClickCount . "x"
} Else {
    ClickCount:=0
    Suffix := " Released"
}
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3, -3) . Suffix
MouseTooltip()
return

MouseTooltip(){
GetKeyStates()
ShowKeys(KeyStates . MouseState)
SetTimer ClearMouseState,  % -IdleDelay
SetTimer TooltipOff, % -IdleDelay
}

ClearMouseState:
MouseState=
ClickCount=0
return
TooltipOff:
If LargeDisplay
    Gui Hide
Else
    Tooltip
return

GetKeyStates() {
KeyStates := ""
    . ( GetKeyState("LControl", "P") ? "LControl + " : "" )
    . ( GetKeyState("RControl", "P") ? "RControl + " : "" )
    . ( GetKeyState("LAlt", "P") ? "LAlt + " : "" )
    . ( GetKeyState("RAlt", "P") ? "RAlt + " : "" )
    . ( GetKeyState("LShift", "P") ? "LShift + " : "" )
    . ( GetKeyState("RShift", "P") ? "RShift + " : "" )
    . ( GetKeyState("LWin", "P") ? "LWin + " : "" )
    . ( GetKeyState("AppsKey", "P") ? "AppsKey + " : "" )
    . ( GetKeyState("F1", "P") ? "F1 + " : "" )
    . ( GetKeyState("F2", "P") ? "F2 + " : "" )
    . ( GetKeyState("F3", "P") ? "F3 + " : "" )
    . ( GetKeyState("F4", "P") ? "F4 + " : "" )
    . ( GetKeyState("F5", "P") ? "F5 + " : "" )
    . ( GetKeyState("F6", "P") ? "F6 + " : "" )
    . ( GetKeyState("F7", "P") ? "F7 + " : "" )
    . ( GetKeyState("F8", "P") ? "F8 + " : "" )
    . ( GetKeyState("F9", "P") ? "F9 + " : "" )
    . ( GetKeyState("F10", "P") ? "F10 + " : "" )
    . ( GetKeyState("F11", "P") ? "F11 + " : "" )
    . ( GetKeyState("F12", "P") ? "F12 + " : "" )
    . ( GetKeyState("Left", "P") ? "Left + " : "" )
    . ( GetKeyState("Right", "P") ? "Right + " : "" )
    . ( GetKeyState("Up", "P") ? "Up + " : "" )
    . ( GetKeyState("Down", "P") ? "Down + " : "" )
    . ( GetKeyState("Home", "P") ? "Home + " : "" )
    . ( GetKeyState("End", "P") ? "End + " : "" )x
    . ( GetKeyState("PgUp", "P") ? "PgUp + " : "" )
    . ( GetKeyState("PgDn", "P") ? "PgDn + " : "" )
    . ( GetKeyState("Del", "P") ? "Del + " : "" )
    . ( GetKeyState("Ins", "P") ? "Ins + " : "" )
    . ( GetKeyState("BS", "P") ? "BS + " : "" )
    . ( GetKeyState("Capslock", "P") ? "Capslock + " : "" )
    . ( GetKeyState("Numlock", "P") ? "Numlock + " : "" )
    . ( GetKeyState("PrintScreen", "P") ? "PrintScreen + " : "" )
    . ( GetKeyState("Pause", "P") ? "Pause + " : "" )
}

ShowKeys(text) {
If LargeDisplay
{
    Global blkOsdCtrlName, blkOsdCtrlName2, MonitorLeft, MonitorRight, MonitorBottom, MonitorTop, GUIx, GUIy, GUIh

    CoordMode Mouse, Screen
    MouseGetPos MouseX, MouseY

    If ((!GUIy) || (MouseX >= MonitorLeft && MouseX <= MonitorRight && MouseY >= GUIy && MouseY <= (GUIy+GUIh)) ) {
    If (MouseY < (MonitorTop + (MonitorBottom - MonitorTop) / 2) )
        GUIy := MonitorBottom - (MonitorBottom - MonitorTop) * 0.2
    Else
        GUIy := MonitorTop + (MonitorBottom - MonitorTop) * 0.2
    }

    GuiControl Text, blkOsdCtrlName, %text%
    GuiControl Text, blkOsdCtrlName2, %text%

    Gui, Show, x%GUIx% y%GUIy% NoActivate
} Else {
    Tooltip % text
}
}

คุณสามารถใช้แป้นพิมพ์บนหน้าจอเพื่อแสดงการกดปุ่มที่มาพร้อมกับ Windows เมื่อคุณพิมพ์แป้นพิมพ์ทางกายภาพของคุณบนหน้าจอหนึ่งไฮไลท์กล่าวว่าคีย์

Presentation Pointerเป็นทางเลือกที่ดีที่สุดสำหรับMousePoséสำหรับ Windows มันมีพอยน์เตอร์เอฟเฟกต์, เม้าส์คลิกเอฟเฟกต์, Keystrokes และแม้กระทั่งให้คุณวาดภาพบนหน้าจอได้อย่างอิสระ แต่ไม่ล็อคหน้าจอ นั่นเป็นข้อได้เปรียบของโปรแกรมจริงๆ

PointerFocusสามารถแสดงการกดแป้นของคุณ

ฉันได้เขียนแอป Windows เล็ก ๆ ที่เรียกQiPress มีการควบคุมการเปลี่ยน look-n-feel แสดงหรือละเว้นกลุ่มคีย์บางอย่างแม้แต่เพิ่มข้อความแบบคงที่ (เช่นชื่อหรือชื่อ บริษัท ของคุณเอง) การจัดตำแหน่งเป็นไปได้โดยการปิดการคลิกผ่านและคลิกแล้วลากป๊อปอัป มีคุณสมบัติอื่น ๆ ที่คุณอาจไม่ต้องการ แต่ครอบคลุมส่วนใหญ่สิ่งที่คุณต้องการ

คุณสามารถใช้PassMark KeyboardTest (ประเมินผลฟรี 30 วันจากนั้น US $ 24.00 ในการซื้อ)

FYI:

• คำถามที่คล้ายกันถูกถามใน SO: วิธีการแสดงทางลัดแป้นพิมพ์กดบนหน้าจอในระหว่างการนำเสนอหรือ screencasts
• คำถามที่คล้ายกันถูกถามสำหรับ OS X: https://apple.stackexchange.com/q/62168/20338
• มีการถามคำถามที่เกี่ยวข้องกับคำแนะนำซอฟต์แวร์ (OP ขอให้โปรแกรมแสดงปุ่มที่ผู้ใช้กำลังกดในขณะที่ใช้โปรแกรมอื่น ๆ มันควรจะแสดงปุ่มทั้งหมดที่กดและทันทีที่ผู้ใช้ปลดกุญแจ - มันควรจะหายไป ): ยูทิลิตี้เพื่อแสดงบนหน้าจอปุ่มกดในปัจจุบัน