รวมถึงชื่อเรื่องสไลด์ในเอกสารบันทึกย่อโดยอัตโนมัติ (PowerPoint 2016)

ฉันต้องการสร้างคู่มือจากงานนำเสนอ PowerPoint ซึ่งข้อมูลในส่วน Notes เป็นส่วนหนึ่งของงานพิมพ์ เพื่อให้ฉันสามารถจัดรูปแบบชื่อสไลด์ให้เป็นส่วนหนึ่งของสารบัญฉันต้องการให้ชื่อสไลด์เป็นข้อความไม่ใช่แค่ส่วนหนึ่งของภาพสไลด์

ในฐานะตัวเลือกการส่งออกฉันสามารถเลือกบันทึกย่อด้านล่างสไลด์ (แต่ชื่อสไลด์ไม่ได้อยู่ในรูปแบบข้อความ) หรือฉันสามารถพิมพ์เค้าร่างเท่านั้น (แต่ไม่รวมบันทึกสไลด์)

ใน Notes Master ฉันเห็นกล่องส่วนหัวและพยายามใส่หัวเรื่องสไลด์ที่นั่น แต่ดูเหมือนจะไม่มีวิธีระบุชื่อสไลด์สำหรับแต่ละสไลด์โดยอัตโนมัติ นั่นคือฉันไม่สามารถรวมตัวแปรสำหรับชื่อเรื่องในกล่องส่วนหัว

ถ้าฉันดูในมุมมองเค้าร่างฉันไม่เห็นข้อความบันทึกย่อ

มีวิธีการสร้างเอกสารประกอบคำบรรยายที่มีทั้งข้อมูลโครงร่างและข้อความบันทึกโดยอัตโนมัติหรือไม่?

การดำเนินการนี้จะรับข้อความไตเติ้ลของแต่ละสไลด์และเพิ่มไปยังหน้าโน้ต แก้ไขตามต้องการเพื่อเปลี่ยนการจัดรูปแบบข้อความ / ตำแหน่ง

Sub AddTitlesToNotesPages()

    Dim oSld As Slide
    Dim oShp As Shape
    Dim sTitleText As String

    For Each oSld In ActivePresentation.Slides

        ' get the slide's title text
        sTitleText = GetTitleText(oSld)

        ' add a text shape with the text to notes page
        ' placement is totally arbitrary; edit to suit
        Set oShp = oSld.NotesPage.Shapes.AddTextbox(msoTextOrientationHorizontal, _
                   0, 0, 500, 100)
        With oShp.TextFrame.TextRange
            .Text = sTitleText
            ' modify other stuff as needed
            .Font.Name = "Arial"
            .Font.Color.RGB = RGB(0, 0, 0)  ' black
            ' and so on
        End With
    Next     ' Slide

End Sub

Function GetTitleText(oSld As Slide) As String
' Returns the title text for oSld if any, or "Slide xxx" if not
    Dim oShp As Shape
    Dim sTemp As String
    For Each oShp In oSld.Shapes
        If oShp.Type = msoPlaceholder Then
            If oShp.PlaceholderFormat.Type = ppPlaceholderCenterTitle Or oShp.PlaceholderFormat.Type = ppPlaceholderTitle Then
                sTemp = oShp.TextFrame.TextRange.Text
            End If
        End If
    Next

    ' if we got this far and didn't find a slide title:
    If Len(sTemp) = 0 Then
        ' return the slide index number
        GetTitleText = "Slide " & CStr(oSld.SlideIndex)
    Else
        ' return the title
        GetTitleText = sTemp
    End If

End Function