การคัดลอกช่วงโดยใช้เกณฑ์ Combo Box

ฉันพยายามที่จะคัดลอกช่วงที่ตรงกับสองเกณฑ์จากสองกล่องคำสั่งผสมบนแบบฟอร์มผู้ใช้

ComboBox1 มีเกณฑ์ 1 สาขา
ComboBox2 มีเกณฑ์ 2 ไตรมาส

คอลัมน์Aต้องตรงกับเกณฑ์สาขาและแถว1ต้องตรงกับเกณฑ์ไตรมาส

ฉันไม่สามารถใช้รหัสได้อย่างถูกต้อง เพียงคัดลอกข้อมูลจากคอลัมน์2และไม่ได้ตรวจสอบทั้งแถวสำหรับเกณฑ์ไตรมาส

ตัวอย่างเช่นถ้าฉันเลือกสาขาเพิร์ลและไตรมาสที่ 1 รหัสควรคัดลอก "แอปเปิ้ล" และ "8"

นี่คือรหัส:

Private Sub CommandButton1_Click()

Dim LastRow As Long, i As Long, ws2 As Worksheet

With Worksheets("Sheet1")
    LastRow = .Range("A" & .Rows.Count).End(xlUp).Row

    For i = 2 To LastRow

        If .Cells(i, 1) = ComboBox1 And .Cells(1, 2) = ComboBox2 Then
            With Worksheets("Sheet4")
                .Cells(.Rows.Count, "A").End(xlUp).Offset(1, 0) = _
                     Worksheets("Sheet1").Cells(i, 2).Value
            End With
        End If

    Next i
End With
Unload Me

End Sub

ปัญหาหลักของโค้ดคือแม้ว่าคุณจะวนลูปไปตามแถวอย่างถูกต้อง แต่คุณไม่ได้วนลูปผ่านคอลัมน์

การเพิ่มวงในจะแก้ปัญหานี้ อย่างไรก็ตามทางออกที่ดีกว่าคือการใช้ฟังก์ชั่นแผ่นงานMATCH()เพื่อค้นหาแถวที่ตรงกันและวนซ้ำผ่านคอลัมน์แทน:

Private Sub CommandButton1_Click()

Dim LastColumn As Long
Dim i As Long

With Worksheets("Sheet1")
    LastColumn = .Cells(1, Columns.Count).End(xlToLeft).Column
    Dim lngMatchingRow As Long
    lngMatchingRow = Excel.WorksheetFunction.Match(ComboBox1.Value, .Range("A:A"), 0)

    For i = 2 To LastColumn

        If .Cells(1, i).Value2 = ComboBox2.Value Then
            With Worksheets("Sheet4")
                .Cells(.Rows.Count, "A").End(xlUp).Offset(1, 0) = _
                     Worksheets("Sheet1").Cells(lngMatchingRow, i).Value2
            End With
        End If

    Next i
End With
Unload Me

End Sub

โปรดทราบว่าฉันมีเสรีภาพในการแก้ไขส่วนอื่น ๆ ของรหัสเพื่อปฏิบัติตามแนวทางปฏิบัติที่ดีที่สุด:

• ตัวแปรควรถูกประกาศหนึ่งรายการต่อบรรทัด
• ตัวแปรควรถูกประกาศว่าใกล้เคียงกับการใช้งานครั้งแรกเท่าที่จะเป็นไปได้
• .Value2การแสดงจะถูกนำมาใช้เสมอ.Valueเมื่อต้องการดึงข้อมูลจากสเปรดชีต
• แทนที่จะต้องพึ่งพาคุณสมบัติเริ่มต้นควรระบุไว้อย่างชัดเจนเช่นComboBox1.Valueแทนที่จะเป็นComboBox1

ตอนนี้ถ้าฉันกำลังเขียนโค้ดตั้งแต่เริ่มต้นและหาก Quarters รับประกันว่าจะถูกจัดกลุ่มเข้าด้วยกันฉันจะแจกจ่ายให้กับการวนซ้ำคอลัมน์เช่นกัน

แต่ฉันจะใช้MATCH()และCOUNTIF()ค้นหาการ จำกัด คอลัมน์และคัดลอกข้อมูลทั้งหมดในครั้งเดียว:

Private Sub CommandButton1_Click()
        Dim ƒ As Excel.WorksheetFunction: Set ƒ = Excel.WorksheetFunction

  With Worksheets("Sheet1")
    Dim lngMatchingRow As Long
    lngMatchingRow = ƒ.Match(ComboBox1.Value, .Range("A:A"), 0)
    Dim lngStartCol As Long
    lngStartCol = ƒ.Match(ComboBox2.Value, .Range("1:1"), 0)
    Dim lngColCount As Long
    lngColCount = ƒ.CountIf(.Range("1:1"), "Q1")

    Worksheets("Sheet4").Cells(Rows.Count, "A").End(xlUp).Offset(1).Resize(lngColCount) _
    = ƒ.Transpose(.Cells(lngMatchingRow, lngStartCol).Resize(1, lngColCount).Value2)

  End With
  Unload Me

End Sub