ฉันจะควบคุมระดับเสียงของระบบบน OS X ด้วยคีย์บอร์ดโดยไม่มีการควบคุมสื่อได้อย่างไร

ฉันใช้แป้นพิมพ์ PC บน Mac OS ฉันสามารถใช้แถบเมนูเพื่อควบคุมระดับเสียง แต่มีแป้นพิมพ์ลัดใด ๆ ที่ฉันสามารถใช้เพื่อเปลี่ยนระดับเสียงของระบบได้หรือไม่

หรืออาจเป็นสคริปต์หรือวิธีแก้ปัญหาง่ายๆที่ฉันสามารถติดตั้งเพื่อให้สามารถตั้งค่าระดับเสียงโดยใช้แป้นพิมพ์

คุณสามารถซื้อSizzling Keysรุ่น pro ได้ มันเป็นตัวpreference paneที่ช่วยให้คุณสามารถกำหนดแป้นพิมพ์ลัดที่กำหนดเองสำหรับการปรับเปลี่ยนระดับเสียงของระบบและอื่น ๆ อีกมากมาย

หรือคุณสามารถปรับเปลี่ยนระดับเสียงของระบบโดยใช้ AppleScript

เปิด AppleScript Editor และป้อน

set volume output volume 100

ปริมาณอยู่ในระดับ 0 ถึง 100 คุณสามารถตั้งค่าสัมบูรณ์ (เช่น 100 สำหรับปริมาณเต็ม) หรือสร้างสคริปต์ที่เพิ่ม / ลดเช่นต่อไปนี้:

set vol to output volume of (get volume settings)
if vol > 90 then # 100 max
    set volume output volume 100
else
    set volume output volume (vol + 10)
end if

สำหรับ Volume Down:

set vol to output volume of (get volume settings)
if vol < 10 then # 0 is min
    set volume output volume 0
else
    set volume output volume (vol - 10)
end if

หากคุณต้องการจำลองเสียงความคิดเห็นที่เกิดขึ้นตามปกติเมื่อคุณเปลี่ยนระดับเสียงคุณสามารถเพิ่มสิ่งต่อไปนี้ในสคริปต์:

    do shell script "afplay /System/Library/Sounds/Pop.aiff"

คุณสามารถบันทึกสคริปต์เช่นเดียวกับแอปพลิเคชันหรือรวมไว้ในเมนูบริการโดยใช้ Automator เป็นบริการแบบไม่ต้องป้อนข้อมูล คุณสามารถกำหนดแป้นพิมพ์ลัดสำหรับบริการในการตั้งค่าระบบ»คีย์บอร์ด»แป้นพิมพ์ลัด»บริการ

Karabiner (เดิมชื่อ KeyRemap4MacBook) สามารถทำการแมปปุ่มฟังก์ชั่นใหม่เพื่อควบคุมระดับเสียงและทำงานได้อย่างราบรื่นสำหรับฉันจนถึงตอนนี้ ในแผงควบคุมให้ค้นหา "F9 เพื่อปิดเสียง" ฯลฯ

ฉันได้จัดทำชุดบริการ AppleScript และคำแนะนำที่ให้คุณควบคุมระบบและระดับเสียงของ iTunes รวมถึง play / pause & next / prev บนคีย์บอร์ดใด ๆ ใน Lion

http://gskinner.com/blog/archives/2011/10/media-keys-in-osx-for-any-keyboard.html

เธรดเก่า แต่วิธีที่ฉันแก้ไขมันผ่าน applescript บรรทัดเดียวตามคำตอบอื่น ๆ

เพิ่มปริมาณได้ 10%

osascript -e 'set volume output volume ((output volume of (get volume settings)) + 10)'

ลดปริมาณลง 10%

osascript -e 'set volume output volume ((output volume of (get volume settings)) - 10)'

จบลงด้วยการเขียนโพสต์บล็อกเกี่ยวกับการใช้มันด้วยแอป Alfred: http://arif.im/system-volume-control-using-alfred/

ปุ่ม F1 ถึง F12 บนแป้นพิมพ์ PC ควรทำสิ่งเดียวกัน ฉันคิดว่าคุณไม่มีปัญหากับการแทนที่คีย์ "Windows" สำหรับคีย์⌘ หากปุ่ม F1 ถึง F12 ไม่ทำงานให้ไปที่การตั้งค่าระบบแป้นพิมพ์และเมาส์แป้นพิมพ์และทำการเลือกจากที่นั่นไม่ว่าจะใช้ปุ่ม F โดยตรงหรือด้วยตัวระบุคีย์ fn ขอแสดงความนับถือ Paul

นี่คือโซลูชันที่สมบูรณ์แบบของฉันสำหรับทางลัดสำหรับการเพิ่มระดับเสียงขึ้นลงและปิดเสียง ฉันใช้แอปพลิเคชัน Spark เพื่อเชื่อมโยงคีย์เข้ากับสคริปต์เหล่านี้ ( http://www.macupdate.com/app/mac/14352/spark ) สคริปต์ตรวจสอบสถานะปิดเสียงปัจจุบันและจัดการเพื่อหลีกเลี่ยงปัญหาแปลก ๆ ที่อาจเกิดขึ้นหากคุณไม่ได้ควบคุมอย่างถูกต้อง

ปรับระดับเสียงขึ้น:

set vol to output muted of (get volume settings)
if (vol = true) then
    set volume without output muted
end if
set vol to output volume of (get volume settings)
if vol > 95 then
    set volume output volume 100
else
    set volume output volume (vol + 5)
end if

do shell script "afplay /System/Library/Sounds/Pop.aiff"

ลดเสียงลง:

set vol to output muted of (get volume settings)
if (vol = true) then
    error number -128
else
    set vol to output volume of (get volume settings)
    if vol < 5 then # 0 is min
        set volume with output muted
    else
        set volume output volume (vol - 5)
    end if

    do shell script "afplay /System/Library/Sounds/Pop.aiff"

end if

ปิด / เปิดเสียง:

set vol to output muted of (get volume settings)
if (vol = true) then
    set volume without output muted
else
    set volume with output muted
end if