TextWrangler: ปุ่มลัดเพื่อเลื่อนบรรทัดขึ้น / ลง

ใน Eclipse คุณสามารถกด ALT- (ลูกศร) เพื่อย้ายบรรทัดขึ้นหรือลง

มีใครค้นพบคุณสมบัติปุ่มลัดเหล่านี้ใน TextWrangler?

สำหรับ Mac OS X มันเป็นctrl+ ↑หรือ+ctrl↓

คุณอาจต้องเปลี่ยนการตั้งค่าคีย์ลัดของ Mission Control (ใน System Preferences) เนื่องจากการกดสองครั้งบนคีย์บอร์ดนั้น

ไม่มีการพูดถึงในคู่มือ (เฉพาะอักขระExchangeและคำแลกเปลี่ยน )

หาก TextWrangler รองรับระบบข้อความ Cocoa (ซึ่งฉันสงสัยว่ามันไม่ได้ แต่ก็ยัง) คุณสามารถสร้างไฟล์~/Library/Keybindings/DefaultKeyBinding.dictและป้อนข้อมูลต่อไปนี้:

{
    "~\UF701" = (
        "moveToBeginningOfLine:",
        "deleteToEndOfLine:",
        "deleteForward:",
        "moveDown:",
        "yank:",
        "insertNewline:",
        "moveUp:"
    );
}

สิ่งนี้จะเพิ่มทางลัดOpt-DownArrowสำหรับคำสั่ง line-swap (พร้อมบรรทัดด้านล่าง) ให้กับทุกแอปพลิเคชันที่รองรับระบบข้อความ Cocoa

ฉันไม่คิดว่า TextWrangler มีสิ่งนี้ในตัว

คุณสามารถเรียกใช้ applescripts ใน TextWrangler ได้ดังนั้นคุณสามารถใช้งานได้ ฉันยังพบแอปพลิเคชันบางตัวที่จะทำเช่นนี้

คุณจะต้องแทนที่ BBEdit ด้วย TextWrangler ใน applescripts วางสคริปต์ใน "~ / Library / Application Support / TextWrangler / Scripts /" และพวกเขาจะปรากฏขึ้นบนเมนูสคริปต์ใน TextWrangler คลิกหน้าต่าง -> จาน -> สคริปต์เพื่อดูจานสีสคริปต์ซึ่งคุณสามารถตั้งค่าแป้นพิมพ์ลัดที่กำหนดเอง

วิธีการแก้ปัญหา nathangs ทำงานได้ดีทีเดียว แต่ลิงก์ที่ให้มาใช้ไม่ได้อีกต่อไป ดังนั้นนี่คือสคริปต์เป็นข้อความธรรมดา เพียงวางลงใน "AppleScript Editor" และบันทึกลงใน ~ / Library / Application Support / TextWrangler / Scripts /

ทำงานได้ดีบน Mountain Lion และด้วย TextWrangler 4

MoveLineDown.scpt:

tell application "TextWrangler"
    set x to startLine of selection
    tell text 1 of window 1
        if x = (count of lines) then return
        set myline to contents of line x
        delete line x
        if length of line x = 0 then
            make line at line x with data "
"
            make line at line (x + 1) with data myline
        else
            make line at line x with data myline

        end if
        select insertion point before line (x + 1)
    end tell
end tell

MoveLineUp.scpt:

tell application "TextWrangler"
    set x to startLine of selection
    if x = 1 then
        beep
        return
    end if
    tell text 1 of window 1
        set oldCount to count of lines
        set myline to contents of line x
        delete line x
        if x = 2 then
            if length of line 1 = 0 then
                make line at beginning with data "
"
            end if
            make line at beginning with data myline
        else
            if length of line (x - 2) = 0 then
                make line at line (x - 2) with data "
"
                make line at line (x - 1) with data myline
            else
                make line at line (x - 2) with data myline
            end if
        end if
        select insertion point before line (x - 1)
    end tell
end tell