เป็นไปได้หรือไม่ที่จะตั้งค่า Internet Explorer เป็นเบราว์เซอร์เริ่มต้นเพื่อเรียกใช้จากบรรทัดคำสั่ง?

ฉันมีเว็บแอปพลิเคชั่นที่ทำงานภายใต้ Internet Explorer เท่านั้น แต่ถ้าเกิดว่า Firefox เป็นเบราว์เซอร์เริ่มต้นมันจะไม่ทำงาน ผู้ใช้อยู่ในสภาพแวดล้อมของโดเมนและแม้ว่าฉันพยายามเปิดแอปพลิเคชันของเราจากชุดด้วยวิธีนี้:

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

แอปพลิเคชันไม่เริ่มทำงานเว้นแต่ฉันจะเปลี่ยนเบราว์เซอร์ด้วยตนเอง

คำสั่งนี้จะตั้งค่า IE เป็นเบราว์เซอร์เริ่มต้น:

shmgrate.exe OcinstallreinstallIE

นโยบายนี้ควรหยุดคนกำหนดเบราว์เซอร์เริ่มต้น

คุณสามารถลองสิ่งนี้มันจะทำงาน

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

ข้อผิดพลาดในคำสั่งของคุณคือstartคาดว่าสตริงที่ยกมาก่อนจะเป็นชื่อของแอปพลิเคชันซึ่งในกรณีนี้คุณสามารถปล่อยว่าง

สำหรับการตั้งค่าiexplorer.exeเป็นเว็บเบราว์เซอร์เริ่มต้นของระบบคุณสามารถใช้assocและftypeคำสั่งซึ่งเชื่อมโยงส่วนขยายกับประเภทไฟล์และประเภทไฟล์กับไฟล์ที่เรียกใช้งานได้ดังนี้:

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1 เป็นอาร์กิวเมนต์ที่นี่ - นั่นคือ URL หรือไฟล์ที่คุณสามารถส่งไปยังโปรแกรมเป็นอินพุต

Windows Vista และใหม่กว่า IE 7+

ชุดสคริปต์ต่อไปนี้จำลองการคลิกตั้งค่าโปรแกรมนี้เป็นค่าเริ่มต้นจากแอปเพล็ตแผงควบคุมโปรแกรมเริ่มต้น ทดสอบกับ Vista / 7 และ IE 7 / IE 11

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)

pause
exit /b

หมายเหตุ

แอปพลิเคชันเว็บเบราว์เซอร์ใด ๆ สามารถลงทะเบียนเพื่อให้ปรากฏเป็นไคลเอนต์อินเทอร์เน็ตบนเมนูเริ่ม การมองเห็นนี้ควบคู่ไปกับการลงทะเบียนที่เหมาะสมสำหรับไฟล์และประเภทโปรโตคอลของแอปพลิเคชันให้สถานะเบราว์เซอร์เริ่มต้นของแอปพลิเคชัน เว็บเบราว์เซอร์เริ่มต้นใช้สำหรับเรียกใช้ URL ที่กำหนดเองจากที่ใดก็ได้ในระบบ

หมายเหตุการลงทะเบียน [ลิงค์เมนูเริ่ม] ที่มีอยู่จะถูกละเว้นใน Windows 7 และใหม่กว่า การลงทะเบียนนี้เลิกใช้แล้วใน Windows 7

_{ที่มา: วิธีลงทะเบียนเบราว์เซอร์อินเทอร์เน็ตหรือไคลเอนต์อีเมลด้วยเมนูเริ่มของ Windows}

­­

โครงสร้างรีจิสทรีแบบลำดับชั้นสำหรับการเชื่อมโยงไฟล์และโปรโตคอลให้ความสำคัญกับค่าเริ่มต้นต่อผู้ใช้มากกว่าค่าเริ่มต้นระดับเครื่อง

_{ที่มา: โปรแกรมเริ่มต้น}

คุณสามารถเพิ่มด้านล่างสองบรรทัดในไฟล์ค้างคาว

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

หลังจากเรียกใช้ bat, reboot / log off และ log back ตั้งแต่ข้างบนบรรทัดคำสั่งสองบรรทัดนั้นหมายถึงการเปลี่ยนค่ารีจิสตรี

รายละเอียดเกี่ยวกับ Aditinal สามารถดูได้ที่นี่

(คงที่) - ตั้งค่า Internet Explorer เป็นเบราว์เซอร์เริ่มต้น! http://www.windowstechinfo.com/2016/03/fixed-cant-set-internet-explorer-as-the-default-browser.html

ฉันไม่รู้เกี่ยวกับการตั้งค่าเบราว์เซอร์เริ่มต้นจากบรรทัดคำสั่ง แต่คุณสามารถตั้งค่าและบังคับใช้สำหรับโดเมนผ่านนโยบายกลุ่ม

นี่คือสิ่งที่จะช่วยให้คุณเริ่มต้นได้:

http://technet.microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

เพียงแค่ปล่อยstartเพื่อรับคำสั่งหรือไฟล์แบทช์ให้ทำงาน

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

สำหรับ Windows 8 (IE 10+) สคริปต์ VBS ง่าย ๆ :

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

มันจะเริ่มหน้า IE สำหรับการเปลี่ยน IE เป็นค่าเริ่มต้นและจำลองคลิกที่ปุ่มเพื่อยอมรับ