แก้ไขสำหรับแทร็กบอลล้อเลื่อนไม่ได้?

ฉันกำลังคิดที่จะซื้อแทร็กบอลและตัวเลือกของฉันคือหินอ่อนของ Logitech trackman แต่ฉันก็พบว่าไม่มีล้อเลื่อน คุณจะรับมือกับสิ่งนั้นได้อย่างไร ฉันต้องการซื้อแทร็กบอลด้วยล้อเลื่อนหรือไม่? ฉันเลื่อนดูมากโดยใช้ Facebook

ฉันไม่ต้องการคลิกด้วยนิ้วชี้และนิ้วกลางของฉันดังนั้นแทร็กบอลบางอันจะไม่เหมาะกับฉันเช่น Trackman Wheel

หากคุณใช้ Windows ฉันขอแนะนำให้ลองใช้ AutoHotKey ผู้ใช้รายอื่นได้เลื่อนการเลื่อนด้วย Marble Mouse แล้ว (ฉันใช้สคริปต์ด้านล่าง):

http://www.autohotkey.com/board/topic/4677-wheel-button-emulation-script/

โซลูชันของ Logitech ที่มาพร้อมกับไดรเวอร์นั้นแปลก: คุณคลิกหนึ่งครั้งเพื่อเปิดใช้งานการเลื่อน 4 ทิศทางและคลิกอีกครั้งเพื่อปิดการใช้งาน คุณไม่สามารถถือและเลื่อนซึ่งเป็นสิ่งที่ฉันเป็นหลังจากนั้น ฉันถอนการติดตั้งซอฟต์แวร์

ฉันมี trackball เหมือนกันและวิธีแก้ปัญหานั้นสวยงามมากเมื่อคุณคลิกที่ปุ่มที่เลือกลูกบอลจะกลายเป็นล้อเลื่อน ฉันเลือกปุ่มขวาขนาดใหญ่ที่ฉันกดด้วยนิ้วก้อย

นี้เป็นมากสะดวกและใช้เวลาเพียงไม่กี่วันจะได้รับใช้

คุณจะพิจารณาอย่างรวดเร็วว่าการเลื่อนใด ๆ (บนเมาส์หรือแทร็กบอล) เป็นสิ่งที่ใช้ไม่ได้ เชื่อใจฉันมันคุ้มค่า ;-)

ข้อดี:

• เลื่อนแบบ 2D แทน 1D
• เลื่อนเร็วกว่าและแม่นยำกว่าล้อ
• สะดวกสบายยิ่งขึ้นสำหรับการเลื่อนที่ยาวนาน (ขอบคุณความเฉื่อยของลูกบอล) เหมาะสำหรับตัวอย่าง Facebook ของคุณ

ฉันไม่สามารถอยู่ได้โดยปราศจากมันอีกต่อไป

การกำหนดค่าภายใต้ Linux OS ใด ๆ ก็ไม่ยาก มันต้องการให้คุณสร้างไฟล์ /etc/X11/xorg.conf เท่านั้น (ดูที่ config ของฉันที่นี่: กำหนดค่า trackball ภายใต้ Linux โดยไม่ต้องแก้ไข Xorg.conf )

รายละเอียดเพิ่มเติมสามารถดูได้ที่นี่: https://help.ubuntu.com/community/Logitech_Marblemouse_USB

ใน Windows ฉันไม่มีประสบการณ์ แต่ฉันคิดว่าเครื่องมือกำหนดค่านั้นมาพร้อมกับแทร็กบอล

คุณสามารถลองใช้ Wheel Mouse Scroll Wheel ที่พัฒนาขึ้นมาโดยเฉพาะสำหรับเมาส์นั้น:

Marble Mouse Scroll Wheel หรือเพียงแค่ Marble Scroll เป็นโปรแกรมขนาดเล็กที่ออกแบบมาเพื่อจำลองล้อเลื่อนของแทร็กบอลหรือเมาส์โดยที่ไม่มี มันถูกออกแบบมาโดยเฉพาะสำหรับ Logitech Marble Mouse แต่สามารถทำงานกับเมาส์หรือแทร็กบอลมาตรฐาน มันถูกออกแบบมาสำหรับ Windows 2000 ขึ้นไป

Marble Scroll ใช้แทนฟังก์ชัน Autoscroll และ Universal Scroll ของ Logitech ไม่เลียนแบบล้อเลื่อนของจริงอย่างถูกต้องและทั้งคู่มีข้อ จำกัด และข้อบกพร่อง

Marble Scroll ใช้งานได้กับเมาส์หรือแทร็กบอลและไม่จำเป็นต้องติดตั้งไดรเวอร์ SetPoint หรือ MouseWare ของ Logitech

คุณสมบัติ

• เพิ่มล้อเลื่อนของเมาส์ใด ๆ ที่มีมากกว่าสองปุ่ม
• ความเข้ากันได้กับแอพพลิเคชั่นส่วนใหญ่ที่รองรับล้อเลื่อน (สำหรับอินพุตทุกประเภท)
• ปรับความเร่งได้
• ระยะเลื่อนที่ปรับได้ (ต่อ "ขั้นตอน" - ดูด้านล่าง)
• การเลื่อนแบบก้าวเพื่อจำลองล้อเมาส์จริง
• สลับโหมดซ้าย / ขวาด่วน
• เปิดใช้งาน / ปิดใช้งานด่วนโดยคลิกที่ไอคอนถาด
• ขนาดเล็กและเบากับทรัพยากรระบบ

เว็บไซต์ของผลิตภัณฑ์ที่ดูเหมือนว่าขณะนี้ลง แต่นี่เป็นสำเนาของข้อความของเว็บไซต์บนArchive.org

ลิงค์ดาวน์โหลดอยู่ที่นี่

มีทางเลือกง่าย ๆ 100 บรรทัด C ++ ซึ่งค่อนข้างคล้ายกับโซลูชัน AutoHotKey นั่นคือ

• ส่งเหตุการณ์ล้อเลื่อนแนวตั้ง / แนวนอนโดยเลื่อนแทร็กบอลในขณะที่ถือหนึ่งในปุ่ม X และ
• คลิกกลางเมื่อกดและปล่อยปุ่ม X โดยไม่ย้ายแทร็คบอล

https://github.com/Seelge/TrackballScroll

แก้ไข: เวอร์ชันที่ใหม่กว่าจะมีไอคอน systray-icon ทำงานบน Windows 10 และใช้ C #

นี่คือสคริปต์ AutoHotKey ที่ฉันใช้ คุณเลื่อนโดยการกดปุ่มเล็ก ๆ ที่เหลือค้างไว้แล้วกลิ้งลูกบอลขึ้น / ลง อย่างไรก็ตามการคลิกปุ่มเล็ก ๆ ด้านซ้ายยังคงเป็น BACK มันยังสามารถเลื่อนไปทางซ้าย / ขวา แต่มันไวเกินไปสำหรับฉันดังนั้นมันจึงคอมเม้นท์ที่นี่ (บล็อกที่ขึ้นต้นด้วย;timesX := Abs(movedx) / 4)

ผมพบว่ารุ่นเดิมที่ http://www.autohotkey.com/board/topic/30816-simulate-scroll-wheel-using-right-mouse-button/ ฉันโพสต์เวอร์ชันของฉันที่นั่นในฐานะคนอื่น 8923

$*XButton1::
Hotkey, $*XButton1 Up, XButton1up, off
;KeyWait, XButton1, T0.4
;If ErrorLevel = 1
;{
   Hotkey, $*XButton1 Up, XButton1up, on
   MouseGetPos, ox, oy
   SetTimer, WatchTheMouse, 5
   movedx := 0
   movedy := 0
   pixelsMoved := 0
;   TrayTip, Scrolling started, Emulating scroll wheel
;}
;Else
;   Send {XButton1}
return

XButton1up:
Hotkey, $*XButton1 Up, XButton1up, off
SetTimer, WatchTheMouse, off
;TrayTip
If (pixelsMoved = 0)
{
    ;The mouse was not moved, send the click event
    ; (May want to make it PGUP or something)
    Send {XButton1}
    Send {XButton1Up}
}
return

WatchTheMouse:
MouseGetPos, nx, ny
movedx := movedx+nx-ox
movedy := movedy+ny-oy

pixelsMoved := pixelsMoved + Abs(nx-ox) + Abs(ny-oy)

;timesX := Abs(movedx) / 4
;ControlGetFocus, control, A
;Loop, %timesX%
;{
;    If (movedx > 0)
;    {
;        SendMessage, 0x114, 1, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx - 4
;    }
;    Else
;    {
;        SendMessage, 0x114, 0, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx + 4
;    }
;}

timesY := Abs(movedy) / 4
Loop, %timesY%
{
    If (movedy > 0)
    {
        Click WheelDown
        movedy := movedy - 4
    }
    Else
    {
        Click WheelUp
        movedy := movedy + 4
    }
}   

MouseMove ox, oy
return

มันเป็นความอัปยศอย่างมาก Logitech ไม่ได้ใช้การจำลองล้อเลื่อน ไดรเวอร์ของพวกเขาสัญญาว่าจะใช้คุณสมบัติดังกล่าว แต่ไม่สามารถใช้งานได้กับทุกแอปพลิเคชัน พวกเขาเกือบจะสร้างเม้าส์ที่สมบูรณ์แบบแล้ว : s

วิธีแก้ปัญหาเดียวที่ฉันพบคือใช้สคริปต์AutoHotkey ด้วยคุณสามารถทำให้ปุ่มซ้าย / ขวาเล็ก ๆ เลื่อนขึ้นและลง มันทำงานได้อย่างสมบูรณ์แบบ แต่มันเป็นความยุ่งยากที่แท้จริงในการกำหนดค่า: คุณจะต้องเรียนรู้พื้นฐาน AutoHotkey ก่อน หากคุณตัดสินใจที่จะทำนี่คือสคริปต์ AutoHotkey ของฉัน มันคือการปรับตัวของสคริปต์เดิม Jerbo ของ การคลิกครั้งเดียวจะเริ่มเลื่อนอย่างรวดเร็ว แต่การคลิกสองครั้งหรือสามครั้งจะเริ่มเลื่อนเร็วขึ้น

; This script remaps the two small buttons on a Logitech Trackman® Marble® Mouse
; to act as scroll up and scroll down

global lastXButton1ClickTime := 0
global nrSubsequentXButton1Clicks := 0

ScrollTheWheel(direction, scrollKey)
{
    now := A_TickCount
    timeSinceLastClick := now - lastXButton1ClickTime 
    lastXButton1ClickTime := now
    if (timeSinceLastClick < 300)
    {
        nrSubsequentXButton1Clicks := nrSubsequentXButton1Clicks + 1
    }
    else
    {
        nrSubsequentXButton1Clicks := 1
    }        

    sleepingFraction := 5

    if (nrSubsequentXButton1Clicks <= 1)
        scrollSpeed := 30
    if (nrSubsequentXButton1Clicks == 2)
        scrollSpeed := 15
    if (nrSubsequentXButton1Clicks >= 3)
        scrollSpeed := 5

    timeSlept := scrollSpeed

    loop 
    {
        if (direction == 1) ; Scroll down
        {
            static downKeyState
            if (scrollKey == 0) 
                GetKeyState, downKeyState, XButton1, P
            else
                GetKeyState, downKeyState, PgDn, P

            if downKeyState = U ; The key has been released, so break out of the loop
               break

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelDown}
                timeSlept = 0                
            }
        }
        else ; Scroll up
        {
            static upKeyState
            if (scrollKey == 0)
                GetKeyState, upKeyState, XButton2, P
            else
                GetKeyState, upKeyState, PgUp, P

            if upKeyState = U ; The key has been released, so break out of the loop
               break            

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelUp}
                timeSlept = 0                
            }
        }   

        Sleep, sleepingFraction
        timeSlept := timeSlept + sleepingFraction
    }    
}

XButton2::
    ScrollTheWheel(0, 0)
    return
XButton1::
    ScrollTheWheel(1, 0)
    return
!PgUp::
    ScrollTheWheel(0, 1)
    return
!PgDn::
    ScrollTheWheel(1, 1)
    return

ฉันเพิ่งได้เมาส์ Logitech Marble และยังมีปัญหาในการเลื่อน ดังนั้นฉันจึงทำสคริปต์นี้ใน AutoHotKey Xbutton ด้านซ้ายเปิดใช้งานการเลื่อนซึ่งหมายความว่าในขณะที่ลงคุณสามารถเลื่อนในแนวตั้งและแนวนอนกับลูกและเลื่อนไปข้างหน้าและข้างหลังในเบราว์เซอร์ด้วยปุ่มซ้ายและขวา Xbutton ด้านขวามีการทำงานเหมือนกับปุ่มกลาง

ฉันอยู่บน windows 7

#SINGLEINSTANCE FORCE  
GLOBAL status := "basic"
GLOBAL cnt_x
GLOBAL cnt_y

XButton2::MButton

$*XButton1::
    status := "scroll"
    cnt_x := 0
    cnt_y := 0
    MOUSEGETPOS, st_x, st_y
    SETTIMER, _scroll, 30
RETURN

$*XButton1 UP::
    status := "basic"
    SETTIMER, _scroll, OFF
RETURN

_scroll:
    MOUSEGETPOS, cur_x, cur_y
    MOUSEMOVE, st_x, st_y

IF(abs(cur_x-st_x) > abs(cur_y-st_y)) {
    cnt_x := cnt_x + (cur_x-st_x)
    ControlGetFocus, control, A 
    IF (cnt_x > 7) {
        cnt := floor(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 0, 0, %control%, A
        }
        cnt_x := cnt_x - 8*floor(cnt_x / 8)
    } ELSE IF (cnt_x < -7) {
        cnt := -ceil(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 1, 0, %control%, A
        }
        cnt_x := cnt_x - 8*ceil(cnt_x / 8)
    }
} ELSE {
    IF (cur_y >= st_y) {
        cnt_y := cnt_y + (cur_y-st_y)**1.2
    } ELSE {
        cnt_y := cnt_y -(st_y-cur_y)**1.2
    }   
    IF (cnt_y > 7) {
        cnt := floor(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelUp
        }
        cnt_y := cnt_y - 8*floor(cnt_y / 8)
    } ELSE IF (cnt_y < -7) {
        cnt := -ceil(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelDown
        }
        cnt_y := cnt_y - 8*ceil(cnt_y / 8)
    }
}   
RETURN

$*LButton::
    IF (status = "basic") {
        CLICK DOWN Left
    } ELSE IF (status = "scroll") {
        SEND {Browser_Back}
    }
RETURN

$*LButton UP::
    IF (status = "basic") {
        CLICK UP Left
    }
RETURN

$*RButton::
    IF (status = "basic") {
        CLICK DOWN Right
    } ELSE IF (status = "scroll") {
        SEND {Browser_Forward}
    }
RETURN

$*RButton UP::
    IF (status = "basic") {
        CLICK UP Right
    }
RETURN

คุณอาจกำหนดค่าปุ่มใดปุ่มหนึ่งเพื่อเปิดใช้งานการเลื่อนผ่านการเลื่อนตัวชี้เมื่อถือ เช่นสคริปต์ต่อไปนี้เปิดใช้งานสิ่งนี้บนปุ่ม 10 ของเมาส์ของฉัน (ปุ่ม "top middle" ของ Logitech MX310):

#!/bin/sh
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 290 10
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 286 1
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 287 6 7 4 5

มีเมาส์หินอ่อน (เม้าส์) ที่มีล้อเลื่อนอยู่ด้วย มิฉะนั้นดูเหมือนว่าจะต้องมีแอปหรือสคริปต์บางอย่างสำหรับเมาส์ที่ไม่มีล้อพร้อมกับการใช้ปุ่มใดปุ่มหนึ่งเพื่อใช้งานฟังก์ชั่นเลื่อน

ดังนั้น "ทำไมต้องคิดค้นล้อใหม่" เป็นภาษิตที่ดีในกรณีนี้

ในตัวอย่างเหล่านี้องค์ประกอบถูกติดตั้งทางกายภาพและมีหลายประเภทให้เลือก ด้านล่างเป็นสองตัวอย่างและรูปแบบ

หรืออะไรทำนองนี้Adesso

สองตัวเลือกที่ไม่ธรรมดา

• ใช้ Apple Magic Trackpad เพิ่มเติมจากแทร็กบอล (นี่คือโซลูชันปัจจุบันของฉัน) http://www.apple.com/magictrackpad/

• ซื้อตัวควบคุมการกระโดดและใช้นอกเหนือจากแทร็กบอล โบกมือข้างหน้าอุปกรณ์เพื่อเลื่อนขึ้นและลง https://www.leapmotion.com/product

เครดิตรูปภาพhttp://www5.pcmag.com/media/images/393268-leap-motion-controller.jpg

วิธีแก้ปัญหาที่ง่าย (และเหมาะกับการยศาสตร์ที่ฉันพูด) คือการใส่ฟังก์ชั่นการเลื่อนลงบนซ้ายของคุณ

สิ่งนี้สามารถทำได้โดยใช้เมาส์ด้วยมือซ้ายของคุณ / โดยใช้แป้นพิมพ์ที่มีล้อเลื่อนในตัวบนขอบด้านซ้าย / โดยการกำหนดฟังก์ชั่นการเลื่อนให้กับปุ่มของแป้นกดที่ตั้งโปรแกรมได้ด้วยโปรแกรมเช่น Mkey ( http: // www.seriosoft.org/en/index.php )

ทำไมฉันถึงคิดว่านี่มันถูกหลักสรีรศาสตร์มากกว่า - เพราะวิธีนี้ช่วยกระจายความตึงเครียดในมือทั้งสองให้เท่ากัน (เพิ่มเติมเกี่ยวกับสิ่งนี้: http://capsoff.org/checklist )

ฉันใช้ Windows7 และใช้ Kensington Orbit Optical Trackball โดยไม่ต้องเลื่อน - มันเป็น trackball สองปุ่มโดยไม่ต้องมีปุ่ม X ที่ต้องการโดยสคริปต์ AHK และแอพพลิเคชั่นส่วนใหญ่

อย่างไรก็ตามMouseImpใช้งานได้กับฉันใน Windows7 มันสามารถกำหนดค่าได้ แต่ฉันได้ตั้งค่าไว้เพื่อright-click + rollให้ฉันมีหน้าจอเลื่อน มันเป็นเหมือนการลากดังนั้นตัวชี้จึงเคลื่อนที่และคุณมีหน้าจอได้ครั้งละหนึ่งหน้าเท่านั้น [อัปเดต: อัตราการเลื่อนสามารถกำหนดค่าได้ดังนั้นจึงสามารถมีได้มากกว่า "หนึ่งหน้า"]

ในเวลาเดียวกัน, เคนซิงตันTrackballWorksleft-click + right-clickได้รับการกำหนดค่าให้ฉันเลื่อนหน้าลงบน น่าเสียดายที่มันไม่สามารถเลื่อนดูหน้าทีละหน้า (อย่างใดอย่างหนึ่ง)

นี่ไม่ใช่ปลั๊กผลิตภัณฑ์ - เป็นเพียงสิ่งที่ฉันได้พบกับแทร็กบอลรุ่น / ประเภทนี้

ข้อแม้: คุณมีอย่างต่อเนื่องทางด้านขวาและคลิกซ้ายและนี้สามารถนำไปสู่การเกิดความสับสนและการเชื่อมโยงการปฏิบัติตาม / js เปิดใช้งานเมื่อคุณต้องการเพียงแค่การเลื่อนหยุด ::: ::: ถอนหายใจ

ฉันเพิ่งได้แทร็กบอลไร้สายวงโคจรจากเคนซิงตันมันวิเศษมาก คุณมีลูกบอลคุณมีปุ่มทั้งสองข้างแต่ละข้างและคุณมีวงกลมอยู่นอกแทร็กบอลซึ่งทำให้เลื่อนขึ้นหรือลงหน้าได้ มันใช้งานได้จริงและฉันใช้กับ Windows และ Mac OSX

ฉันทำบางสิ่งบางอย่างสำหรับเรื่องนี้โดยใช้ AutoHotkey ในขณะที่กลับมาและคิดว่าฉันจะแบ่งปันที่นี่เช่นกัน: Mouse Wheel Emulator

นี่เป็นการจำลองล้อเลื่อนของเมาส์โดยเลื่อนเมาส์ไปรอบ ๆ ในขณะที่กดปุ่มซ้ายและขวาของเมาส์

คุณสามารถเลียนแบบการคลิกกลางด้วยการคลิกปุ่มซ้ายและขวาของเมาส์ในเวลาเดียวกัน

โซลูชันอื่นสำหรับ Windows 7 ที่อนุญาตให้เลื่อนในแอปพลิเคชันทั้งหมดรวมถึง Internet Explorer:

1. ติดตั้งAutoHotKey
2. บันทึกสคริปต์นี้เป็นscroll.ahkเดสก์ท็อป
3. scroll.ahkคลิกขวาบน
4. เลือกสคริปต์เรียกใช้
5. ยืนยันหากได้รับแจ้ง

สิ่งนี้จะทำให้การกดปุ่มขวาเล็ก ๆ เลื่อนในแนวตั้งเมื่อเลื่อนแทร็กบอล ปุ่มซ้ายเล็ก ๆ คือปุ่มย้อนกลับ

ในกรณีที่ลิงก์ไปยังรหัสของ Erik Elmore หายไปนี่คือ:

;;
;; Emulate_Scrolling_Middle_Button.ahk
;; Author: Erik Elmore <erik@ironsavior.net>
;; Version: 1.1 (Aug 16, 2005)
;;
;; Enables you to use any key with cursor movement
;; to emulate a scrolling middle button.  While
;; the TriggerKey is held down, you may move the
;; mouse cursor up and down to send scroll wheel
;; events.  If the cursor does not move by the
;; time the TriggerKey is released, then a middle
;; button click is generated.  I wrote this for my
;; 4-button Logitech Marble Mouse (trackball),  
;; which has no middle button or scroll wheel.
;;

;; Configuration

;#NoTrayIcon

;; Higher numbers mean less sensitivity
esmb_Threshold = 7

;; This key/Button activates scrolling
esmb_TriggerKey = XButton2

;; End of configuration

#Persistent
CoordMode, Mouse, Screen
Hotkey, %esmb_TriggerKey%, esmb_TriggerKeyDown
HotKey, %esmb_TriggerKey% Up, esmb_TriggerKeyUp
esmb_KeyDown = n
SetTimer, esmb_CheckForScrollEventAndExecute, 10
return

esmb_TriggerKeyDown:
  esmb_Moved = n
  esmb_FirstIteration = y
  esmb_KeyDown = y
  MouseGetPos, esmb_OrigX, esmb_OrigY
  esmb_AccumulatedDistance = 0
return

esmb_TriggerKeyUp:
  esmb_KeyDown = n
  ;; Send a middle-click if we did not scroll
  if esmb_Moved = n
    MouseClick, Middle
return

esmb_CheckForScrollEventAndExecute:
  if esmb_KeyDown = n
    return

  MouseGetPos,, esmb_NewY
  esmb_Distance := esmb_NewY - esmb_OrigY
  if esmb_Distance
    esmb_Moved = y

  esmb_AccumulatedDistance := (esmb_AccumulatedDistance + esmb_Distance)
  esmb_Ticks := (esmb_AccumulatedDistance // esmb_Threshold) ; floor divide
  esmb_AccumulatedDistance := (esmb_AccumulatedDistance - (esmb_Ticks * esmb_Threshold))
  esmb_WheelDirection := "WheelDown"
  if (esmb_Ticks < 0) {
    esmb_WheelDirection := "WheelUp"
    esmb_Ticks := (-1 * esmb_Ticks)
  }

  ;; Do not send clicks on the first iteration
  if esmb_FirstIteration = y
    esmb_FirstIteration = n
  else {
    Loop % esmb_Ticks {
      MouseClick, %esmb_WheelDirection%
    }
  }

  MouseMove,esmb_OrigX,esmb_OrigY,0
return

ผู้ใช้หินอ่อน Trackman คนอื่นที่นี่

ฉันใช้การควบคุมปุ่ม X-Mouseสำหรับการจำลองการเลื่อน การใช้งานคุณสมบัตินี้ยังไม่สมบูรณ์แบบ (ยัง?) แต่มันใช้งานได้ดีกว่าการใช้งาน Logitech ในซอฟต์แวร์ SetPoint ™ของพวกเขาเอง

ฉันแนะนำ XMBC ให้กับทุกคนที่ไม่ต้องการยุ่งกับ AutoHotKey และมองหาสิ่งที่ใช้งานได้