ฉันสามารถสร้างมาโครที่จะเสนอเมนูแบบเลื่อนลงสำหรับหัวเรื่องใน Outlook 2010 ได้หรือไม่

ฉันต้องการบรรทัดหัวเรื่องในข้อความ Outlook ของฉันเพื่อเริ่มต้นด้วยงานที่เกี่ยวข้องกับข้อความ เนื่องจากมีงานประมาณหนึ่งโหลเกิดขึ้นในเวลาใดเวลาหนึ่งจึงเป็นเรื่องยุ่งยากที่จะพิมพ์ชื่องานหรือคัดลอกและวางจากข้อความอื่น ฉันทำงานกับมาโครด้วยปุ่มบนเมนู Outlook ที่สร้างข้อความใหม่ แต่ตอนนี้ฉันติดอยู่กับงานหนึ่งเรื่องและไม่ได้หาวิธีทำให้เมนูแบบเลื่อนลงของตัวเอง ชื่องานที่เป็นไปได้ทั้งหมด ดังนั้นความช่วยเหลือใด ๆ จะได้รับการชื่นชมอย่างมาก

ลองอะไรเช่นนี้ ให้แน่ใจว่ามีรายการคงค้างเมื่อคุณเปิดตัว

http://www.vbaexpress.com/kb/getarticle.php?kb_id=369

http://www.vbaexpress.com/kb/getarticle.php?kb_id=303

'** The following code goes in a userform **

' Adapted for a single choice

Private Sub cmdOkay_Click()
Dim i As Long
Dim msg As String
Dim Check As String

Dim currItem As MailItem

'Generate a list of the selected items
With ListBox1
    For i = 0 To .ListCount - 1
        If .Selected(i) Then
            msg = .List(i)
            Exit For
        End If
    Next i
End With

If msg = vbNullString Then
    'If nothing was selected, tell user and let them try again
    MsgBox "Nothing was selected!  Please make a selection!"
    Exit Sub

Else

    Set currItem = Application.ActiveInspector.currentItem
    currItem.Subject = msg
    Unload Me

End If

End Sub

Private Sub cmdCancel_Click()
Unload Me
End Sub

Private Sub UserForm_Initialize()

With Me.ListBox1
     'Clear the rowsource in case it has been set
    .RowSource = ""
     'Add the items
    .AddItem ("Cat")
    .AddItem ("Dog")
    .AddItem ("Gerbil")
    .AddItem ("Lizard")
    .AddItem ("Rat")
    .AddItem ("Snake")
    .AddItem ("Turtle")
End With

End Sub


 '** The following code goes in a standard module **

Sub Launch()
'This code will launch the userform
    UserForm1.Show
End Sub