ใน Outlook2010 มีวิธีดูการเตือนการงีบหลับในปัจจุบันหรือไม่

มีวิธีใดใน Outlook 2010 ที่จะดึงรายชื่อของรายการที่ขณะนี้ปิดเสียงเตือนชั่วคราว ตัวอย่างเช่นสมมติว่าสองสัปดาห์จากนั้นฉันตั้งตัวเตือนให้ปรากฏขึ้นในวันศุกร์สำหรับการประชุมอาหารกลางวันที่สำคัญในวันจันทร์ถัดไป (ฉันชอบที่จะได้รับการเตือนเกี่ยวกับภารกิจวันจันทร์ก่อนวันหยุดสุดสัปดาห์) เมื่อการแจ้งเตือนปรากฏขึ้นในวันศุกร์ฉันจะปิดเสียงเตือนชั่วคราวสามวันเพื่อให้ปรากฏขึ้นอีกครั้งก่อนอาหารกลางวันในวันจันทร์ จากนั้นจันทร์หมุนไปรอบ ๆ และความทรงจำของฉันเลือนหายไปและฉันก็หวาดระแวงเล็กน้อยที่ฉันไม่ได้ตั้งใจเตือนเมื่อวันศุกร์แทนที่จะงีบหลับอย่างถูกต้อง ฉันยังสามารถเห็นการนัดหมายดั้งเดิมในปฏิทินของฉันได้ แต่ฉันต้องแน่ใจว่าจริง ๆ แล้วฉันจะได้รับการแจ้งเตือนปรากฏขึ้นเมื่อฉันคาดหวังว่ามันจะไม่พลาดการประชุม

มีวิธีใดใน Outlook 2010 ที่จะดึงรายชื่อการแจ้งเตือนที่มีการเตือนชั่วคราวหรือไม่ สิ่งนี้จะเป็นประโยชน์สำหรับกรณีเหล่านั้นที่ฉันทำงานให้เสร็จซึ่งมีการเตือนฉันปิดเสียงเตือนชั่วคราวจนกระทั่งในภายหลัง

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

ถ้าคุณไม่คุ้นเคยด้วย VBA เห็นหน้าคำอธิบาย Slipstick ของ คุณจะพบข้อมูลเกี่ยวกับ:

• การตั้งค่าความปลอดภัยของมาโคร
• ตำแหน่งที่จะวางโค้ด (คุณสามารถใช้โมดูลปกติด้วยการแทรก | โมดูล); และ
• วิธีสร้างปุ่ม

จากการโพสต์ในฟอรั่มView snoozed itemsมันเป็นไปไม่ได้ที่จะเห็นรายการของ snoozed items โพสต์แสดงให้เห็นว่าคุณอาจเห็นข้อมูลที่มีประโยชน์ในปริมาณ จำกัด โดยการสร้างมุมมองที่กำหนดเองซึ่งแสดงฟิลด์เตือนความจำบางส่วน

ลองคลิกที่แท็บปฏิทินเลือกดูและเปลี่ยนมุมมอง จากนั้นเลือกรายการ ปรากฏขึ้นเพื่อแสดงรายการการแจ้งเตือนทั้งหมด