ฉันจะอัปเดต Flash Player โดยอัตโนมัติเมื่อใดก็ตามที่มีเวอร์ชันใหม่ออกมา

สรุป:

บริการการปรับปรุงเล่นแฟลชไม่ทำงานในช่วงเวลาที่มีความน่าเชื่อถือและไม่ได้โดยอัตโนมัติดาวน์โหลดและใช้การปรับปรุงเมื่อมันไม่วิ่ง

ด้วยความสำคัญของการมีการติดตั้ง Flash Player รุ่นล่าสุด (สำหรับพวกเราที่ไม่ได้ใช้ Chrome กับเครื่องเล่นในตัว) ฉันต้องการค้นหาวิธีเพื่อให้แน่ใจว่ามีการตรวจพบการอัปเดตใหม่ทันที และติดตั้ง

ต่อไปนี้เป็นรายละเอียดของความพยายามของฉันในการแก้ไขปัญหานี้ด้วยตัวเอง ...

ภาคผนวก A: บริการอัปเดต Flash Player

ตกลงวิธีที่ย้อนกลับไปใน Flash Player 11.2 (หรือมากกว่านั้น) Adobe เพิ่มบริการอัปเดต Flash Player (FlashPlayerUpdateService.exe) มันควรจะอัปเดต Flash Player ...

• เมื่อติดตั้งแล้ว FPUS จะได้รับการกำหนดค่าให้เรียกใช้เป็นบริการของ Windows โดยตั้งค่าชนิดเริ่มต้นเป็นด้วยตนเอง

• เพิ่มงานที่กำหนดเวลาไว้ (Adobe Flash Player Updater.job) เพื่อเริ่มบริการนี้ทุกชั่วโมง

จนถึงตอนนี้ดีมาก - การตั้งค่านี้หลีกเลี่ยงการมีบริการที่ทำงานอยู่ตลอดเวลา แต่ตรวจสอบให้แน่ใจว่าการตรวจสอบทำงานบ่อยครั้งมากพอที่จะรับการอัปเดตใด ๆ ได้อย่างรวดเร็ว อัพเดทซอฟแวร์ของ Google มีการกำหนดค่าในแฟชั่นที่คล้ายกันและที่ทำงานได้ดี ...

... และเมื่อฉันตรวจสอบเวอร์ชันของ Flash Player ที่ติดตั้งแล้วฉันพบว่ามันคือ11.6.602.180ซึ่งดูจากการบันทึกเวลาของไฟล์ที่C:\Windows\System32\Macromed\Flashมีการอัปเดตล่าสุด (หรือติดตั้ง) บนTue, Mar 12, 2013 --- 3/12/13, 5:00:08 น .

ฉันทำข้อสังเกตนี้บนThu, 25 เมษายน 2013 --- 4/25/13, 07:00:00และเมื่อตรวจสอบเว็บไซต์ของ Adobeพบว่ารุ่นปัจจุบันของ Flash Player เป็น11.7.700.169

นับเป็นเวลาหนึ่งเดือนนับตั้งแต่การอัปเดตครั้งล่าสุดโดยมีการอัพเดทใหม่อย่างชัดเจนบนเว็บไซต์ แต่ไม่มีข้อบ่งชี้ว่าการตรวจสอบรายชั่วโมงที่ทำงานอยู่บนเครื่องของฉันสังเกตเห็นหรือมีความตั้งใจที่จะดาวน์โหลด

ภาคผนวก B: เรียกใช้ตัวอัปเดต Flash Player ด้วยตนเอง

กาลครั้งหนึ่งการรันจะทำให้คุณมีหน้าต่างพร้อมปุ่มติดตั้ง การกดจะเป็นการดาวน์โหลดตัวติดตั้งสำหรับเวอร์ชันปัจจุบัน (โดยอัตโนมัติโดยไม่ต้องเปิดเบราว์เซอร์) และเรียกใช้จากนั้นคุณจะคลิกผ่านตัวติดตั้งนั้น & เสร็จสิ้น มันเป็นคู่มือ แต่ก็ใช้งานได้! การค้นหาการติดตั้งปัจจุบันของฉันล้าสมัย (ดูภาคผนวก A) ฉันลองใช้กระบวนการอัปเดตด้วยตนเองเป็นครั้งแรก อย่างไรก็ตาม ...FlashUtil32_<version>_Plugin.exe -update plugin

• เล่น(ในกรณีของฉันว่า) ... เพียง แต่นำเสนอหน้าต่างที่มีปุ่มดาวน์โหลดการคลิกที่ปุ่มดาวน์โหลดจะเปิดเบราว์เซอร์ไปยัง URL https://get3.adobe.com/flashplayer/update/activexFlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• เล่น(ในกรณีของฉันว่า) ... เพียง แต่นำเสนอหน้าต่างที่มีปุ่มดาวน์โหลดการคลิกที่ปุ่มดาวน์โหลดจะเปิดเบราว์เซอร์ไปยัง URL https://get3.adobe.com/flashplayer/update/pluginFlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

ฉันสามารถดำเนินการต่อด้วยหน้าดาวน์โหลดที่ส่งไปให้ยกเลิกการเลือกกล่อง foistware ("ฟรี! McAfee Security Scan Plus") ดาวน์โหลดตัวติดตั้งนั้น (ActiveX, ไม่มี foistware: install_flashplayer11x32axau_mssd_aih.exe, ปลั๊กอิน, ไม่มี foistware: install_flashplayer11x32au_msd_ai อาจมี Flash ที่อัปเดตแล้ว ... แต่แล้วจุดประสงค์ของบริการอัปเดต Flash Player คืออะไรถ้าฉันต้องดาวน์โหลดและรัน exe ตัวอื่น?

ถ้อยคำส

ฉันสงสัยว่าบริการอัปเดตนั้นมีความตั้งใจในการขับเคลื่อนผู้ใช้งานไปยังหน้าดาวน์โหลดด้วยตนเอง ถ้านี่เป็นเรื่องจริงคงไม่มีทางแก้ไขข้อผิดพลาดนี้ในการเขียนตัวอัปเดตของตัวเอง หวังว่าฉันผิด

บางทีตัวอัปเดตจะใช้การอัปเดตในช่วง 11.6.x เท่านั้นหรือ

คุณสามารถใช้ลิงก์โดยตรงไปยังตัวติดตั้งซึ่งฉันพบว่าเชื่อถือได้มากกว่า: ActiveX ; ปลั๊กอิน

ด้วยไฟล์. batนี้จะพยายามอัปเดตหรือติดตั้งFlash Playerโดยอัตโนมัติสำหรับ Internet Explorer, Firefox (SeaMonkey และอื่น ๆ ), Chromium based (Chrome, Opera 15+ และอื่น ๆ ):

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

wget ที่ต้องการคุณสามารถดาวน์โหลดได้ที่นี่และต้องวางไว้ในไดเรกทอรีเดียวกันกับที่มีการใส่. bat ไว้

ตัวอย่างเล็ก ๆ น้อย ๆ ที่สูงขึ้นเขียนในAutoIt

คุณสมบัติ: ตรวจสอบเวอร์ชั่นใหม่อย่างง่ายถ้าที่นี่ไม่มีเวอร์ชั่นใหม่แล้วออกจากโปรแกรมโดยไม่ต้องดาวน์โหลดตัวติดตั้งแฟลชเพลเยอร์ หากตัวติดตั้งดาวน์โหลดล้มเหลวให้แสดงกล่องข้อความพร้อมข้อผิดพลาดและออก หน้าต่างพรอมต์คำสั่งที่ซ่อนอยู่ ไม่ต้องการ wget

หลังจากติดตั้งAutoItและบรรณาธิการ คลิกขวาที่เดสก์ท็อป -> ใหม่ -> สคริปต์ Autoit คลิกขวาที่ไฟล์ที่สร้างขึ้นนี้ -> แก้ไข ตอนนี้คุณควรเห็นหน้าต่าง Scite และหลังบรรทัด "เพิ่มรหัสของคุณด้านล่างที่นี่" เพิ่มรหัสนี้:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

จากนั้นในหน้าต่าง SciTE กด Tools-> Build หรือกด F7 ตอนนี้คุณจะได้ไฟล์แบบสแตนด์อโลนในไดเรกทอรีเดียวกันซึ่งเป็นสคริปต์ Autoit

ฉันขอแนะนำให้สร้างโฟลเดอร์ใหม่ (ที่มีสิทธิ์การเข้าถึงเพื่อเขียน) สำหรับ "updater" นี้ คุณสามารถเพิ่มทางลัดไปยัง "updater" เพื่อเริ่มต้นด้วย

แอปที่นี่สำหรับถอนการติดตั้งโปรแกรมเล่นแฟลช

เพียงแค่ฉันต้องการแชร์สคริปต์แบทช์ของฉันกับคุณเพียงบันทึกชิ้นส่วนของรหัสนี้ลงใน Notepad ของคุณและตั้งชื่อเป็นDownload_Install_Last_Flash_Player.bat

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************