วิธีการเปลี่ยนชื่อไฟล์ตามการประทับเวลาด้วยแบทช์สคริปต์?

สมมติว่าฉันมี 10 ไฟล์ที่ระบบสร้างขึ้นทุกวันภายใต้ D: \ Temp ชื่อถูกสร้างขึ้นแบบสุ่ม

สมมติว่าฉันต้องเปลี่ยนชื่อเก่าที่สุดให้เป็น 'aaa' อันที่เก่าแก่ที่สุดที่สองเป็น 'bbb' จากนั้น 'ccc', 'ddd' และอื่น ๆ

สมมติว่านี่เป็นชื่อเป้าหมายที่ฉันจะใช้:

Beijing
shanghai
hangzhou
suzhou
newyork
lanzhou
huzhou
guangzhou
tianjin
sichuang

ใครสามารถช่วยสคริปต์ชุดงานเพื่อให้บรรลุนี้

ฉันถามคำถามนี้เมื่อวานนี้จริง ๆและได้รับคำตอบที่ยอดเยี่ยมในการใช้ PowerShell แต่วันนี้ฉันสังเกตเห็นใน VM ของ บริษัท ฉันไม่ได้ติดตั้ง PowerShell (ไม่ได้รับอนุญาตให้ติดตั้งด้วยตัวเอง) ดังนั้นต้องโพสต์คำถามอีกครั้ง สามารถรักษา (ยอมรับ) คะแนนของพวกเขา

@echo off
setlocal disableDelayedExpansion
set "file1=aaa"
set "file2=bbb"
set "file3=ccc"
set "file4=ddd"
set "file5=eee"
set "file6=fff"
set "file7=ggg"
set "file8=hhh"
set "file9=iii"
set "file10=jjj"

for /f "tokens=1,2* delims=: " %%A in (
  'wmic datafile where "drive='d:' and path='\\temp\\'" get creationDate^, name ^| findstr "^[0-9]" ^| sort ^| findstr /n "^"'
) do for /f "delims=" %%F in ("%%C") do (
  setlocal enableDelayedExpansion
  for %%N in ("!file%%A!") do (
    endlocal
    ren "%%F" %%N
  )
)

หากคุณต้องการที่จะเปลี่ยนเส้นทางแล้วคุณต้องให้แน่ใจว่าสองครั้งขึ้นทั้งหมด\เป็นและให้แน่ใจว่าเส้นทางจะเริ่มต้นและจบลงด้วยการ\\ \\อักษรระบุไดรฟ์ที่เหมาะสม (พร้อมโคลอน) ต้องปรากฏในตัวเลือกไดรฟ์

ทั้งค่าไดรฟ์และเส้นทางจะต้องอยู่ในเครื่องหมายคำพูดเดียว - WMIC ใช้ไวยากรณ์ SQL

สิ่งนี้น่าจะเหมาะกับคุณ มันเปลี่ยนชื่อ 26 ไฟล์ไปaaaสู่ความzzzวันที่สร้างเก่าแก่ที่สุดเป็นครั้งแรก ดูที่เอาต์พุตและลบechoคำสั่งถ้าตกลง

@echo off&setlocal
set "startfolder=D:\temp"
set "alphas=abcdefghijklmnopqrstuvwxyz"
cd /d "%startfolder%"

set /a counter=0
for /f "tokens=3*" %%a in ('dir /a-d /od /tc ^| findstr "^[0-9]"') do set "fname=%%b"&call:process
goto:eof

:process    
setlocal enabledelayedexpansion
set "nname=!alphas:~%counter%,1!!alphas:~%counter%,1!!alphas:~%counter%,1!"
if not defined nname goto:eof
echo rename "%fname%" "!nname!"
endlocal
set /a counter+=1
goto:eof

หากdirคำสั่ง showes เวลากับ AM / PM tokens=4*ตั้ง