วิธีการ“ ตอบกลับทั้งหมด” และเก็บไฟล์แนบดั้งเดิมไว้ใน Outlook ได้อย่างไร

ฉันจะดำเนินการ "ตอบกลับทั้งหมด" ใน Outlook ได้ แต่ส่งไฟล์แนบเดิมกลับไปเป็นทั้งหมดได้อย่างไร

เห็นได้ชัดว่าไม่มีโค้ด VBA บางตัว นี่คือสิ่งที่ฉันพบว่าเจตนาที่จะทำอย่างนั้น ( ที่มา )

คำอธิบาย:ตัวอย่าง VBA ของ Outlook นี้สร้างและแสดงการตอบกลับไปยังข้อความที่เปิดหรือที่เลือกในปัจจุบันรวมถึงเอกสารแนบในต้นฉบับ

Sub ReplyWithAttachments()
    Dim rpl As Outlook.MailItem
    Dim itm As Object

    Set itm = GetCurrentItem()
    If Not itm Is Nothing Then
        Set rpl = itm.Reply
        CopyAttachments itm, rpl
        rpl.Display
    End If

    Set rpl = Nothing
    Set itm = Nothing
End Sub

Function GetCurrentItem() As Object
    Dim objApp As Outlook.Application

    Set objApp = Application
    On Error Resume Next
    Select Case TypeName(objApp.ActiveWindow)
        Case "Explorer"
            Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
        Case "Inspector"
            Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
    End Select

    Set objApp = Nothing
End Function

Sub CopyAttachments(objSourceItem, objTargetItem)
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set fldTemp = fso.GetSpecialFolder(2) ' TemporaryFolder
   strPath = fldTemp.Path & "\"
   For Each objAtt In objSourceItem.Attachments
      strFile = strPath & objAtt.FileName
      objAtt.SaveAsFile strFile
      objTargetItem.Attachments.Add strFile, , , objAtt.DisplayName
      fso.DeleteFile strFile
   Next

   Set fldTemp = Nothing
   Set fso = Nothing
End Sub

หมายเหตุเกี่ยวกับรหัส:

1. ใช้GetCurrentItem()ฟังก์ชั่นเพื่อส่งคืนรายการที่เลือกหรือแสดงในปัจจุบัน

2. ใช้CopyAttachments()ขั้นตอนเพื่อคัดลอกไฟล์แนบไปยังการตอบกลับ

3. แทนที่itm.Replyด้วยitm.ReplyAllหากคุณต้องการตอบกลับทั้งหมด

(โอ้และฉันพบสิ่งนี้ในเวลาประมาณ 30 วินาทีในการค้นหาเว็บเพื่อ "ตอบกลับทั้งหมดพร้อมไฟล์แนบใน Outlook")

ทางออกที่เป็นไปได้:

บุคคลที่ส่งจดหมายนี้ในครั้งแรกจะเปิดโฟลเดอร์ "รายการที่ถูกส่ง" ของเขาเปิดจดหมายแล้วเลือกการกระทำ - "ส่งข้อความนี้อีกครั้ง.... "อีกครั้ง