ฉันจะแปลงสคริปต์แบตช์ Windows เป็น. exe ได้อย่างไร

ฉันมีสคริปต์แบทช์ที่ค่อนข้างเรียบง่ายที่ฉันต้องการเรียกใช้โดยใช้มาโครบนคีย์บอร์ดเกมแฟนซีของฉัน อย่างไรก็ตาม SteelSeries Engine รองรับเฉพาะการเปิดไฟล์. exe ด้วยปุ่มมาโคร มีวิธีการแปลงสคริปต์เป็นปฏิบัติการง่าย ๆ ?

ใช่แล้ว มันไม่สวย แต่ก็สะอาด (ไม่มีอะไรจะทำความสะอาดหลังจากนั้น) และมันมีอยู่แล้วในระบบของคุณ!

ของคุณในโฟลเดอร์ที่มีไฟล์ที่เรียกว่า C:\Windows\System32\iexpress.exe

• คลิกขวาที่มันRun as administratorและ
• สร้าง SED ใหม่และเลือก "แตกไฟล์แล้วรันคำสั่งการติดตั้ง"
• เพิ่มสคริปต์ที่คุณต้องการและตรวจสอบให้แน่ใจว่าในหน้าจอถัดไปคุณตั้งค่าโปรแกรมติดตั้งเป็นcmd /c [your_script.bat]ที่ [your_script.bat] เป็นไฟล์สคริปต์ที่คุณต้องการดำเนินการ หากคุณไม่ทำเช่นนี้ windows จะพยายามใช้ Command.com (Command Prompt รุ่นเก่า) ซึ่งไม่ได้ใช้งานมาระยะหนึ่งแล้ว
• เลือกการตั้งค่า (คุณอาจต้องเลือก "จัดเก็บไฟล์โดยใช้ชื่อไฟล์แบบยาวภายในแพ็คเกจ) ตั้งค่าเส้นทางออก (เป็นไฟล์. exe ที่คุณต้องการสร้าง) และเลือก" ไม่รีสตาร์ท "
• คลิกถัดไปและคุณควรมี. exe!

เพียงแค่ทราบว่าไฟล์นี้ทำหน้าที่เป็น wrapper สำหรับสคริปต์ของคุณเท่านั้นและสคริปต์นั้นจะถูกเรียกใช้งานในโฟลเดอร์ temp ที่สร้างขึ้นจากการเรียกใช้งาน (และลบทิ้งในภายหลัง) ดังนั้นโปรดอย่าใช้เส้นทางที่สัมพันธ์กัน

นี่คือ 2 โปรแกรมฟรีที่ฉันแนะนำเป็นอย่างยิ่งสำหรับการสร้างไฟล์แบตช์ EXE

1 - Bat To exe Converter

2 - Bat 2 Exe

คุณสามารถใช้ทั้งสองโปรแกรมด้วย GUI ที่เรียบง่าย

Bat To Exe Converterรองรับคำสั่ง CLI ( \?ตั้งค่าสถานะเพื่อขอความช่วยเหลือ) ตัวอย่างพื้นฐานจากเอกสาร:

Bat_To_Exe_Converter.exe -bat mybatfile.bat -save myprogram.exe -icon myicon

หากซอฟต์แวร์แป้นพิมพ์ของคุณรองรับการส่งผ่านของข้อโต้แย้งไปยังปฏิบัติการ (ซึ่งไม่น่าจะเป็นไปได้) คุณไม่จำเป็นต้องทำ

cmd.exe /c <path to batchfile>

จะเรียกใช้แบตช์ไฟล์และให้ไฟล์ปฏิบัติการที่ถูกต้องแก่คุณสำหรับซอฟต์แวร์คีย์บอร์ด ไม่จำเป็นต้องมีการแปลงหมายความว่าคุณสามารถเปลี่ยนแปลงค้างคาวของคุณได้อย่างง่ายดายโดยไม่ต้องทำตามขั้นตอนเพิ่มเติม

ฉันพบนี้บทความที่แสดงให้เห็นถึงวิธีการแปลงค้างคาวให้ไฟล์ exe โดยใช้ชุด scipt:

@ECHO OFF
ECHO Make EXE From BAT
ECHO Written by: Jason Faulkner
ECHO SysadminGeek.com
ECHO.
ECHO.

REM Usage:
REM MakeExeFromBat BatFileToConvert [IncludeFile1] [IncludeFile2] [...]
REM
REM Required Parameters:
REM  BatFileToConvert
REM      Source batch file to use to produce the output Exe file.
REM
REM Optional Parameters:
REM  IncludeFile
REM      Additional files to include in the Exe file.
REM      You can include external tools used by the batch file so they are available on the executing machine.

SETLOCAL

REM Configuration (no quotes needed):
SET PathTo7Zip=


REM ---- Do not modify anything below this line ----

SET OutputFile="%~n1.exe"
SET SourceFiles="%TEMP%MakeEXE_files.txt"
SET Config="%TEMP%MakeEXE_config.txt"
SET Source7ZFile="%Temp%MakeEXE.7z"

REM Remove existing files
IF EXIST %OutputFile% DEL %OutputFile%

REM Build source archive
ECHO "%~dpnx1" > %SourceFiles%
:AddInclude
IF {%2}=={} GOTO EndInclude
ECHO "%~dpnx2" >> %SourceFiles%
SHIFT /2
GOTO AddInclude
:EndInclude
"%PathTo7Zip%7za.exe" a %Source7ZFile% @%SourceFiles%

REM Build config file
ECHO ;!@Install@!UTF-8! > %Config%
ECHO RunProgram="%~nx1" >> %Config%
ECHO ;!@InstallEnd@! >> %Config%

REM Build EXE
COPY /B "%PathTo7Zip%7zsd.sfx" + %Config% + %Source7ZFile% %OutputFile%

REM Clean up
IF EXIST %SourceFiles% DEL %SourceFiles%
IF EXIST %Config% DEL %Config%
IF EXIST %Source7ZFile% DEL %Source7ZFile%

ENDLOCAL

การดาวน์โหลดที่สำคัญ:

• ดาวน์โหลด Make EXE จาก BAT Script จาก Sysadmin Geek
• ดาวน์โหลดเครื่องมือบรรทัดคำสั่ง 7-Zip
• ดาวน์โหลด 7-Zip Advanced 7zSD SFX