แป้นพิมพ์ลัดเพื่อสลับระหว่างแผ่นงานใน Excel

Excel 2007 มีแป้นพิมพ์ลัดที่สลับระหว่างแผ่นงานหรือไม่

Ctrl+ PgUpเพื่อเลื่อนไปทางซ้าย

Ctrl+ PgDnเพื่อเลื่อนไปทางขวา

VBA Macros และแป้นพิมพ์ลัดแบบกำหนดเองเพื่อเปิดใช้งานแผ่นงานแผ่นแรกหรือแผ่นสุดท้าย

หากคุณต้องการแป้นพิมพ์ลัดจริงเพื่อข้ามไปยังแผ่นงานแผ่นแรกหรือแผ่นสุดท้ายให้วางรหัสนี้ลงในโมดูลในสมุดงาน "PERSONAL":

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

ไปที่แท็บนักพัฒนา> มาโคร เรียกดูมาโครเหล่านี้ (ToFirstSheet และ ToLastSheet) เลือกหนึ่งคลิกตัวเลือกและกำหนดแป้นพิมพ์ลัด ทำเช่นเดียวกันสำหรับคนอื่น ๆ

ด้วยการบันทึกลงในสมุดงาน "PERSONAL" จะสามารถใช้งานได้ในไฟล์ Excel ใด ๆ

แป้นพิมพ์ลัดในตัวเพื่อเปิดใช้งานชีตก่อนหน้าหรือถัดไป

หากต้องการข้ามแผ่นงานหนึ่งไปทางซ้ายหรือขวาคุณสามารถใช้แป้นพิมพ์ลัดเริ่มต้นเหล่านี้:

Ctrl+PgUp

Ctrl+PgDn

แมโคร VBA เพื่อเปิดใช้งานชีตก่อนหน้าหรือถัดไป

ต่อไปนี้เป็นวิธีการใช้ VBA ให้สำเร็จ:

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

ฟังก์ชัน VBA เพื่อส่งคืนแผ่นงานก่อนหน้าหรือถัดไป

ใช้ฟังก์ชั่นนี้หากคุณต้องการรับวัตถุแผ่นงานก่อนหน้าหรือถัดไป:

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

ใช้ฟังก์ชั่นเช่นนี้:

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub

คุณยังสามารถใช้ปุ่มเร่งความเร็วเพื่อไปที่Goกล่องโต้ตอบ จากนั้นคุณสามารถพิมพ์สิ่งที่ต้องการfoo!A1นำทางไปยังเซลล์ด้านบนซ้ายในแผ่นงานที่ชื่อว่า "foo" ในขณะที่เลื่อนหน้าลงและเลื่อนหน้าลงโดยทั่วไปเร็วขึ้น หากคุณมีแผ่นงานที่มีชื่อจำนวนมาก (เช่น 20+) แผ่นงานนี้อาจเร็วกว่า ทำงานได้ดีเช่นกันหากคุณตั้งชื่อตารางในแผ่นงานของคุณ

การกด F5 ปกติจะเปิดGoกล่องโต้ตอบ