ลายเซ็นอีเมล HTML ไม่แสดงเสมอ

ฉันมีลายเซ็นอีเมล HTML มันไม่แสดงตลอดเวลาเพราะบางครั้งผู้คนตอบกลับเป็นข้อความธรรมดา ดังนั้นคำตอบของฉันก็เป็นข้อความธรรมดาเช่นกัน

ดังนั้นฉันจึงพบมาโครบนอินเทอร์เน็ตที่ส่งอีเมลของฉันทั้งหมดในรูปแบบ HTML เห็นได้ชัดว่าคุณไม่ควรทำเช่นนี้ แต่เนื่องจากฉันส่งอีเมลใหม่ทั้งหมดใน HTML ฉันไม่สามารถเห็นได้ว่าทำไม

อย่างไรก็ตามตอนนี้แทนที่จะเป็นข้อความธรรมดาพวกเขาเป็น HTML แต่มักจะอยู่ใน Times New Roman และลายเซ็นต์ไม่ได้แสดงโลโก้เพียงแค่ข้อความ แต่ไม่ได้จัดรูปแบบ ไม่มีใครรู้วิธีแก้ปัญหานี้หรือไม่

ขอบคุณล่วงหน้า

ฉันลงเอยด้วยการใช้บทความนี้เพื่ออัปเดตมาโครของฉัน

http://www.howto-outlook.com/howto/replyinhtml.htm

Sub ForceReplyInHTML()

    '=================================================================
    'Description: Outlook macro to reply to a message in HTML
    '             regardless of the current message format.
    '             The reply will use your HTML signature as well.
    '
    'author : Robert Sparnaaij
    'version: 1.0
    'website: http://www.howto-outlook.com/howto/replyinhtml.htm
    '=================================================================

        Dim objOL As Outlook.Application
        Dim objSelection As Outlook.Selection
        Dim objItem As Object
        Set objOL = Outlook.Application

        'Get the selected item
        Select Case TypeName(objOL.ActiveWindow)
            Case "Explorer"
                Set objSelection = objOL.ActiveExplorer.Selection
                If objSelection.Count > 0 Then
                    Set objItem = objSelection.Item(1)
                Else
                    Result = MsgBox("No item selected. " & _
                                "Please make a selection first.", _
                                vbCritical, "Reply in HTML")
                    Exit Sub
                End If

            Case "Inspector"
                Set objItem = objOL.ActiveInspector.CurrentItem

            Case Else
                Result = MsgBox("Unsupported Window type." & _
                            vbNewLine & "Please make a selection" & _
                            " or open an item first.", _
                            vbCritical, "Reply in HTML")
                Exit Sub
        End Select

        Dim olMsg As Outlook.MailItem
        Dim olMsgReply As Outlook.MailItem
        Dim IsPlainText As Boolean

        'Change the message format and reply
        If objItem.Class = olMail Then
            Set olMsg = objItem
            If olMsg.BodyFormat = olFormatPlain Then
                IsPlainText = True
            End If
            olMsg.BodyFormat = olFormatHTML
            Set olMsgReply = olMsg.Reply
            If IsPlainText = True Then
                olMsg.BodyFormat = olFormatPlain
            End If
            olMsg.Close (olSave)
            olMsgReply.Display

        'Selected item isn't a mail item
        Else
            Result = MsgBox("No message item selected. " & _
                        "Please make a selection first.", _
                        vbCritical, "Reply in HTML")
            Exit Sub
        End If

        'Cleanup
        Set objOL = Nothing
        Set objItem = Nothing
        Set objSelection = Nothing
        Set olMsg = Nothing
        Set olMsgReply = Nothing

    End Sub

ฉันสร้างมาโครใหม่สามครั้งครั้งต่อไปข้างหน้าหนึ่งครั้งเพื่อตอบหนึ่งครั้งสำหรับการตอบกลับทั้งหมดฉันเปลี่ยนชื่อSub ForceReplyInHTMLแมโครที่ด้านบนเพื่อสร้างมาโครที่ต่างกันสามตัว

ฉันยังใช้บทความที่เกี่ยวข้องในลิงก์นั้นเพื่อสร้างปุ่มของตัวเองและลงชื่อในมาโครของฉัน ในขั้นตอนสุดท้ายฉันใช้ปุ่ม Modify เพื่อเปลี่ยนไอคอนของ Macros เพื่อให้จำได้ง่ายขึ้น