วิธีคัดลอกข้อความที่มีแท็บจาก Excel โดยไม่มีเครื่องหมายคำพูด?

ฉันสังเกตเห็นว่าเซลล์ที่มีแท็บนั้นถูกคัดลอกด้วยอัญประกาศ ฉันกำลังมองหาการคัดลอกเซลล์ชนิดนี้โดยไม่มีเครื่องหมายคำพูด

ตัวอย่างที่เป็นตัวอย่าง

ฉันมี 5 เซลล์ A1, A2, A3, A4 และ A5 สูตรสำหรับพวกเขาคือ:

นี่คือลักษณะที่ปรากฏบน Excel:

สูตรถูกตั้งค่าเช่นนั้นเพื่อให้ได้ผลลัพธ์ตามที่คาดไว้เมื่อคัดลอกเซลล์ไปยังโปรแกรมแก้ไขข้อความเป็นดังนี้:

น่าเสียดายนี่คือสิ่งที่ฉันได้รับ:

ปัญหาอยู่ที่คำพูด สิ่งที่ฉันต้องการคือการคัดลอกเซลล์เหล่านั้นโดยไม่มีเครื่องหมายอัญประกาศ

วิธีการแก้ปัญหา VBA? การดำเนินการนี้จะคัดลอกตัวเลือกทั้งหมดจากเซลล์ที่เลือกด้านบนซ้ายไปยังเซลล์ที่เลือกด้านล่างขวา หากคุณเลือกเซลล์ที่ไม่ลงรอยกันรหัสนี้จะรวบรวมทุกอย่างระหว่างด้านบนซ้ายและขวาล่าง คุณสามารถเปลี่ยนได้แน่นอน วิธีนี้ง่ายกว่า มันทำให้แท็บระหว่างคอลัมน์และตัวแบ่งบรรทัดระหว่างแถว

Sub CopyText()

    Dim obj As Object
    Dim rng As Range
    Dim r As Long, c As Long
    Dim s As String
    Dim rTL, rBR, cTL, cBR

    rTL = Selection.Cells(1, 1).Row
    cTL = Selection.Cells(1, 1).Column

    For Each rng In Selection.Cells
        If rng.Row < rTL Then rTL = rng.Row
        If rng.Column < cTL Then cTL = rng.Column
        If rng.Row > rBR Then rBR = rng.Row
        If rng.Column > cBR Then cBR = rng.Column
    Next

    For r = rTL To rBR
        For c = cTL To cBR
            s = s & Cells(r, c).Value
            If c < cBR Then s = s & Chr(9)
        Next
        If r < rBR Then s = s & vbNewLine
    Next

    Set obj = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
    obj.SetText s
    obj.PutInClipboard
    Set obj = Nothing

End Sub

หากคุณสงสัยเกี่ยวกับส่วนนี้:

Set obj = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")

... นั่นเป็นเพียงเวอร์ชันล่าช้าSet obj = New DataObjectดังนั้นคุณไม่จำเป็นต้องเพิ่มการอ้างอิงใด ๆ ใน VBA