การทดสอบ LS_COLORS ใน zsh

LS_COLORSไม่กี่ปีที่ผ่านมาผมพบว่าข้อมูลโค้ดที่น่าสนใจที่พิมพ์แต่ละประเภทของไฟล์สีที่สอดคล้องกันตามสีที่กำหนดขึ้นมาใน น่าเสียดายที่ฉันจำลิงค์ไม่ได้อีกต่อไป

นี่คือตัวอย่างที่เป็นtest_colors.shปัญหา

eval $(echo "no:global default;fi:normal file;di:directory;ln:symbolic link;pi:named pipe;so:socket;do:door;bd:block device;cd:character device;or:orphan symlink;mi:missing file;su:set uid;sg:set gid;tw:sticky other writable;ow:other w\
ritable;st:sticky;ex:executable;"|sed -e 's/:/="/g; s/\;/"\n/g')                                                                                                                                                                            
{                                                                                                                                                                                                                                           
  IFS=:                                                                                                                                                                                                                                     
  for i in $LS_COLORS                                                                                                                                                                                                                       
  do                                                                                                                                                                                                                                        
    echo -e "\e[${i#*=}m$( x=${i%=*}; [ "${!x}" ] && echo "${!x}" || echo "$x" )\e[m"                                                                                                                                                       
  done                                                                                                                                                                                                                                      
}   

ตัวอย่างทำงานได้ดีbashแต่ไม่ได้อยู่ในzshและฉันไม่สามารถบอกได้ว่าทำไม เมื่อฉันเรียกใช้ในzshฉันได้รับข้อผิดพลาดต่อไปนี้:

> sh .test_colors.sh
.eval_colors:1: * not found
[00:fi=00:di=01;34:ln=01;36:pi=40;33:so=01;35:do=01;35:bd=40;33;01:cd=40;33;01:or=40;31;01:su=37;41:sg=30;43:tw=30;42:ow=34;42:st=37;44:ex=01;32:*.tar=01;31:*.tgz=01;31:*.arj=01;31:*.taz=01;31:*.lzh=01;31:*.zip=01;31:*.z=01;31:*.Z=01;31:*.gz=01;31:*.bz2=01;31:*.deb=01;31:*.rpm=01;31:*.jar=01;31:*.jpg=01;35:*.jpeg=01;35:*.gif=01;35:*.bmp=01;35:*.pbm=01;35:*.pgm=01;35:*.ppm=01;35:*.tga=01;35:*.xbm=01;35:*.xpm=01;35:*.tif=01;35:*.tiff=01;35:*.png=01;35:*.mov=01;35:*.mpg=01;35:*.mpeg=01;35:*.avi=01;35:*.fli=01;35:*.gl=01;35:*.dl=01;35:*.xcf=01;35:*.xwd=01;35:*.flac=01;35:*.mp3=01;35:*.mpc=01;35:*.ogg=01;35:*.wav=01;35:m

อัปเดต (1 พฤศจิกายน 2011)

ฉันทดสอบสคริปต์โดย @ Stéphane Gimenez ด้านล่าง ฉันสังเกตเห็นว่าตัวละครบางตัวดูเหมือนจะหลบหนีไม่ถูกต้อง ความคิดใด ๆ

คำตอบ: ดูความคิดเห็นเกี่ยวกับคำตอบของ @ Stéphane Gimenez

เขียนเหมือนกันสำหรับ zsh ในวิธีที่สะอาดกว่ามาก:

#!/bin/zsh

typeset -A names
names[no]="global default"
names[fi]="normal file"
names[di]="directory"
names[ln]="symbolic link"
names[pi]="named pipe"
names[so]="socket"
names[do]="door"
names[bd]="block device"
names[cd]="character device"
names[or]="orphan symlink"
names[mi]="missing file"
names[su]="set uid"
names[sg]="set gid"
names[tw]="sticky other writable"
names[ow]="other writable"
names[st]="sticky"
names[ex]="executable"

for i in ${(s.:.)LS_COLORS}
do
    key=${i%\=*}
    color=${i#*\=}
    name=${names[(e)$key]-$key}
    printf '\e[%sm%s\e[m\n' $color $name
done

คุณจำเป็นต้องหลบหนี=ใน${i%=*}เพราะมิฉะนั้นต่อท้ายรูปแบบ=*ผ่านการ=ขยายตัวจึง=ถูกตีความว่าเป็นชื่อคำสั่ง นี่คือสาเหตุของ* not foundข้อผิดพลาด

Zsh ไม่ได้แบ่งคำในการแทนที่ตัวแปรตามค่าเริ่มต้นดังนั้นจึง$LS_COLORSขยายเป็นคำเดียว จะมีforห่วงดำเนินการในส่วนที่ลำไส้ใหญ่แยกของใช้$LS_COLORS for i in $=LS_COLORSหรือมากกว่า idiomatically ใน zsh ไม่ได้ใช้แต่แทนที่จะระบุอย่างชัดเจนถึงวิธีการแยก:IFSfor i in ${(s.:.)LS_COLORS}

ไวยากรณ์${!x}ที่หมายถึง "ค่าของตัวแปรที่มีชื่อ$x" นั้นเฉพาะเจาะจงกับการทุบตี zsh มีโครงสร้างเทียบเท่าที่P ธงขยายตัวพารามิเตอร์${(P)x} :