ลองดูสิ มัน remaps @เพื่อให้g@(บวกการเคลื่อนไหวหุ่นl) .ถูกนำมาใช้หลังจากนั้นจึงกลายเป็นผู้ประกอบการที่ผ่านมาและอาจมีการทำซ้ำกับ
" When . repeats g@, repeat the last macro.
fun! AtRepeat(_)
" If no count is supplied use the one saved in s:atcount.
" Otherwise save the new count in s:atcount, so it will be
" applied to repeats.
let s:atcount = v:count ? v:count : s:atcount
" feedkeys() rather than :normal allows finishing in Insert
" mode, should the macro do that. @@ is remapped, so 'opfunc'
" will be correct, even if the macro changes it.
call feedkeys(s:atcount.'@@')
endfun
fun! AtSetRepeat(_)
set opfunc=AtRepeat
endfun
" Called by g@ being invoked directly for the first time. Sets
" 'opfunc' ready for repeats with . by calling AtSetRepeat().
fun! AtInit()
" Make sure setting 'opfunc' happens here, after initial playback
" of the macro recording, in case 'opfunc' is set there.
set opfunc=AtSetRepeat
return 'g@l'
endfun
" Enable calling a function within the mapping for @
nno <expr> <plug>@init AtInit()
" A macro could, albeit unusually, end in Insert mode.
ino <expr> <plug>@init "\<c-o>".AtInit()
fun! AtReg()
let s:atcount = v:count1
let c = nr2char(getchar())
return '@'.c."\<plug>@init"
endfun
nmap <expr> @ AtReg()
ฉันพยายามที่จะจัดการกับกรณีมุมมากที่สุดเท่าที่ฉันสามารถคิด คุณสามารถทำซ้ำกับ@: .นับไป@หรือจะถูกเก็บไว้สำหรับกดที่ตามมาของ..
นี่คือเล่ห์เหลี่ยมและฉันไม่เชื่อว่าบางสิ่งบางอย่างจะไม่แตกไปตามทาง ดังนั้นจึงไม่มีการรับประกันรับประกันหรือสัญญากับสิ่งนี้
ส่วนตัวผมโอเคที่มีความแตกต่างระหว่างซ้ำเม็ดเล็กของการเปลี่ยนแปลงที่ผ่านมาและซ้ำมาโคร.@@
แก้ไข
ฉันคิดว่าได้ไปไกลขนาดนี้แล้วฉันอาจเพิ่มรหัสเพิ่มเติมที่จะอนุญาตให้กด.ทันทีหลังจากบันทึกแมโครเพื่อเล่น
fun! QRepeat(_)
call feedkeys('@'.s:qreg)
endfun
fun! QSetRepeat(_)
set opfunc=QRepeat
endfun
fun! QStop()
set opfunc=QSetRepeat
return 'g@l'
endfun
nno <expr> <plug>qstop QStop()
ino <expr> <plug>qstop "\<c-o>".QStop()
let s:qrec = 0
fun! QStart()
if s:qrec == 1
let s:qrec = 0
return "q\<plug>qstop"
endif
let s:qreg = nr2char(getchar())
if s:qreg =~# '[0-9a-zA-Z"]'
let s:qrec = 1
endif
return 'q'.s:qreg
endfun
nmap <expr> q QStart()
Enter