เป็นไปได้หรือไม่ที่จะใช้พื้นหลังสีสองแบบในบัฟเฟอร์กลุ่มเดียว?

ฉันกำลังมองหาวิธีแก้ปัญหาที่เป็นไปได้สำหรับการใช้สีพื้นหลังที่แตกต่างกันสองสีภายในบัฟเฟอร์ vim เดียวโดยขึ้นอยู่กับบริบทเช่นในตัวอย่างข้อความประเสริฐนี้

กรณีการใช้งานหนึ่งกรณีนั่นคือการโค้ดสีในไฟล์มาร์กอัปแตกต่างกันดังนั้นพวกเขาจึงโดดเด่นกว่า

อย่างไรก็ตามฉันไม่เคยเห็นตัวอย่างพร้อมการตั้งค่าเช่นนั้น

เป็นไปได้ทั้งหมดในกลุ่ม?

เพราะฉันสงสัยว่ามันจะทำงานได้ดีแค่ไหนฉันจึงแฮกบางอย่างเข้าด้วยกัน

ดังที่ได้กล่าวไว้ในความคิดเห็นเกี่ยวกับคำตอบก่อนหน้านี้วิธีเดียวที่จะทำเช่นนี้คือการเติมภูมิภาคที่มีช่องว่าง ซึ่งเป็นสิ่งที่เราทำ ก่อนที่จะเขียนเราจะลบช่องว่างเหล่านี้ดังนั้นคุณไม่ควรรบกวนใครด้วย

โปรดทราบว่าตัวอย่างนี้เฉพาะเจาะจงมากสำหรับไฟล์ประเภท markdown!

ผลข้างเคียง :

• การคัดลอกข้อความจะเป็นการคัดลอกช่องว่างจำนวนมาก
• การใช้$และEndไม่ทำงานตามที่คาดไว้ (ไปที่คอลัมน์ 80) และปุ่มต่างๆเช่น jและkยังทำงานแตกต่างกัน
• พื้นหลังไม่ปรากฏเมื่อ'list'เปิดใช้งาน
• บรรทัดว่างเปล่าไม่ทำงานคุณต้องเพิ่มแท็บหรือช่องว่าง 4 ด้วยตนเอง
• ... อาจจะมากกว่านี้?

ก่อนอื่นคุณต้องเพิ่มสิ่งนี้ใน~/.vim/after/syntax/markdown.vim:

syn clear markdownCodeBlock                                                 
syn region markdownCodeBlock start="    \|\t" end="$"                       
hi def markdownCodeBlock ctermbg=230 guibg=lightyellow                      

คุณสามารถปรับสีตามที่คุณต้องการแน่นอน ;-)

จากนั้นเพิ่มไปยัง vimrc ของคุณ:

fun! MarkdownBlocks()                                                       
    fun! s:fill(line)                                                       
        " Remove all trailing whitespace                                    
        let l:line = substitute(a:line, " *$", "", "")                      

        " Add trailing whitespace up to 'textwidth' length                  
        return l:line . repeat(' ', (&tw > 0 ? &tw : 80) - strdisplaywidth(l:line))
    endfun                                                                  

    " Get all lines in a list                                               
    let l:lines = getline(1, line('$'))                                     

    " Map s:fill() to the lines that are a code block                       
    call map(l:lines, 'v:val[0] == "\t" || v:val[:3] == "    " ? s:fill(v:val) : v:val')

    " Reset the buffer to the lines                                         
    call setline(1, l:lines)                                                
endfun                                                                      

" Remove all the trailing spaces                                            
fun! MarkdownBlocksClean()                                                  
    let l:save_cursor = getpos(".")                                         
    silent %s/^\(    \|\t\)\(.\{-}\)\( *\)$/\1\2/e                          
    call setpos('.', l:save_cursor)                                         
endfun                                                                      
au BufWritePre *.markdown call MarkdownBlocksClean()                        

" Set spaces on loading the file, leaving insert mode, and after writing it 
au FileType markdown call MarkdownBlocks()                                  
au InsertLeave *.markdown call MarkdownBlocks()                             
au BufWritePost *.markdown call MarkdownBlocks()                            

ฉันจะไม่อธิบายรหัสทีละบรรทัดความคิดเห็นควรให้ความสำคัญกับมันชัดเจน ;-)

แน่นอนเป็นไปได้ที่จะใช้สีพื้นหลังที่แตกต่างกันสำหรับองค์ประกอบที่เน้นไวยากรณ์ เพียงกำหนดguibgและctermbgสีในhilightคำสั่งของคุณ อดีตตั้งค่าสีพื้นหลังสำหรับ GUI Vim และสีหลังสำหรับ Terminal Vim

อย่างไรก็ตามสิ่งนี้มีข้อ จำกัด ที่สำคัญที่สามารถกำหนดสีพื้นหลังสำหรับอักขระที่มีอยู่จริงในไฟล์เท่านั้น

ผลลัพธ์ของสิ่งนี้คือสีพื้นหลังไม่สามารถขยายผ่านจุดสิ้นสุดของข้อความบนบรรทัดไปที่ขอบหน้าต่างดังนั้นการระบายสีของบล็อครหัสที่แสดงในตัวอย่างของคุณจึงเป็นไปไม่ได้:

คุณยังสามารถเปลี่ยนสีพื้นหลังของทั้งบรรทัดโดยใช้คุณสมบัติลงชื่อเข้าใช้ (ดูlinehlใน:help sign.txt)

อย่างไรก็ตามโปรดทราบว่า:

1. การทำเช่นนั้นจำเป็นต้องเขียนรหัสเพื่อวางเครื่องหมายบนแต่ละบรรทัดที่ต้องมีสีและปรับปรุงเหล่านี้เมื่อเนื้อหาของไฟล์เปลี่ยนแปลง

2. ตามค่าเริ่มต้นเมื่อวางสัญลักษณ์คอลัมน์สัญญาณจะปรากฏทางด้านซ้ายของหน้าต่าง เป็นไปได้ที่จะเปลี่ยนสีของคอลัมน์สัญญาณด้วยSignColumnกลุ่มไฮไลต์และในเวอร์ชันล่าสุดของ Vim จะสามารถลบออกได้ทั้งหมด (ดู:help 'signcolumn'.)

ตัวอย่างเช่นหากต้องการปรับเปลี่ยนโซลูชันของ Carpetsmokerเพื่อใช้กลไกสัญญาณ (มีประสิทธิภาพมากขึ้น) คุณสามารถทำสิ่งต่อไปนี้:

" Define a highlight group and a sign that uses it
highlight default markdownCodeBlock ctermbg=230 guibg=lightyellow
sign define codeblock linehl=markdownCodeBlock

" Use signs to highlight code blocks
function! MarkdownBlocks()
    function! s:applySign(idx, val)
        if a:val[0] == "\t" || a:val[:3] == "    "
            let l = a:idx + 1
            execute "sign place " . l . " line=" . l . " name=codeblock file=" . expand("%:p")
        endif
    endfunction

    " Remove old signs
    execute "sign unplace * file=" . expand("%:p")

    " Get all lines in a list
    let l:lines = getline(1, line('$'))
    " Add new signs
    call map(l:lines, function('s:applySign'))
endfunction

" Set signs on loading the file, leaving insert mode, and after writing it
au FileType markdown call MarkdownBlocks()
au InsertLeave *.markdown call MarkdownBlocks()
au BufWritePost *.markdown call MarkdownBlocks()

สิ่งนี้จะทำให้รหัสง่ายขึ้นและมี caveats น้อยกว่าเวอร์ชั่นของ Carpetsmoker

@ChristianBrabandt 's DynamicSignsปลั๊กอินทำให้การใช้คุณลักษณะการเข้าสู่ระบบเพื่อการนี้ได้ง่ายขึ้น: เขาอธิบายวิธีการใช้งานให้ทำเช่นนั้นในคำตอบนี้