ผสานบล็อกด้วยเส้นแทรก

มีวิธีเฉพาะในการรวมสองบล็อกข้อความโดย interleaving บรรทัดเช่นผ่านจากนี้

a1
a2
a3
a4
  b1
  b2
  b3
  b4

เพื่อที่:

a1
  b1
a2
  b2
a3
  b3
a4
  b4

ในคำสั่งไม่กี่?

แก้ไข : ฉันชอบโซลูชันของ Sato Katsuraนี่คือวิธีที่ฉันใช้งาน:

function! Interleave()
    " retrieve last selected area position and size
    let start = line(".")
    execute "normal! gvo\<esc>"
    let end = line(".")
    let [start, end] = sort([start, end], "n")
    let size = (end - start + 1) / 2
    " and interleave!
    for i in range(size - 1)
        execute (start + size + i). 'm' .(start + 2 * i)
    endfor
endfunction

" Select your two contiguous, same-sized blocks, and use it to Interleave ;)
vnoremap <pickYourMap> <esc>:call Interleave()<CR>

ไม่มีวิธีเฉพาะในการทำ (เท่าที่ฉันรู้) แต่ใช่มันสามารถทำได้ด้วยคำสั่งไม่กี่:

function! Interleave(start, end, where)
    if a:start < a:where
        for i in range(0, a:end - a:start)
            execute a:start . 'm' . (a:where + i)
        endfor
    else
        for i in range(a:end - a:start, 0, -1)
            execute a:end . 'm' . (a:where + i)
        endfor
    endif
endfunction

:call Interleave(5, 8, 1)คุณสามารถเรียกใช้มันด้วย พารามิเตอร์แรกคือบรรทัดแรกที่จะย้ายบรรทัดที่สองเป็นบรรทัดสุดท้ายและบรรทัดที่สามที่จะย้าย คุณอาจต้องการเปิดหมายเลขบรรทัดเพื่อดูว่าคุณกำลังทำอะไร ( :set number)

สิ่งนี้จะถือว่าบล็อกไม่ทับซ้อนกัน ดู:help :moveและ:help range()เข้าใจการทำงานของฟังก์ชัน

อาจมีวิธีที่ดีกว่าในการรับทั้งสองช่วงตึก มีปลั๊กอินที่ลอยอยู่รอบ ๆ ที่ควรให้คุณสลับสองช่วงตึก ฉันจำชื่อปลั๊กอินไม่ได้ แต่ผู้แต่ง (อาจเป็น Dr. Chip ที่มีชื่อเสียง?) ได้คิดมากขึ้นในการค้นหาส่วนต่อประสานมากกว่าที่ฉันทำ :)

นี่คือทางเลือกอื่น:

:g/^a/+4t .
:+,+5d 

ก่อนอื่นให้คัดลอกบรรทัดที่มี 4 บรรทัดด้านล่างเป็นหลังบรรทัดปัจจุบัน ( :h :t) จากนั้นลบบรรทัด b ต่อเนื่อง ( :h :d)

คำสั่งนี้ดียิ่งขึ้น:

 :g/^a//^\s*b/m .

ซึ่งหมายความว่าสำหรับแต่ละบรรทัดที่เริ่มต้นด้วยการค้นหาบรรทัดถัดไปที่เริ่มต้นด้วย 'b' และย้ายไปด้านล่างบรรทัดปัจจุบัน

หากคุณต้องการมีความสนุกสนานเล็กน้อยกับมาโครและทำเครื่องหมายคุณสามารถลองดังนี้:

• ก่อนนำเครื่องหมาย (ที่นี่a) บนบรรทัดที่มีa1กับma

• ไปที่บรรทัดที่มีb1และทำเครื่องหมายด้วยmb

• เริ่มการบันทึกแมโครในการลงทะเบียนที่คุณต้องการ (ที่นี่การลงทะเบียนq) ด้วยqq

• แทรก folowing ในแมโครของคุณ: ddmb'apjma'b

• หยุดการบันทึกแมโครด้วย q

• เล่นได้หลายครั้งตามความจำเป็นกับX@qที่Xคือจำนวนของเวลาที่จะเล่นมัน

วิธีดูรายละเอียดของแมโคร:

dd mb 'a p j ma 'b
 |  |  | | |    |
 |  |  | | |    go back to line marked `b`
 |  |  | | |
 |  |  | | move of one line and replace the mark `a`
 |  |  | insert the deleted line under the line marked `a`
 |  |  go to line marked `a`
 |  mark the future line to move with `b`
 delete the line to move

แก้ไขตามที่ lago-lito พูดถึงในความคิดเห็นวิธีนี้จะเขียนทับเครื่องหมายและบัฟเฟอร์

• สำหรับเครื่องหมายที่ฉันไม่คิดว่าเป็นปัญหาจริง: ฉันไม่ค่อยใช้ทั้งหมด 26 คะแนนในบัฟเฟอร์และฉันคิดว่าหนึ่งครั้งส่วนใหญ่จะพบเครื่องหมาย 2 ฟรี

• สำหรับบัฟเฟอร์มันเป็นไปได้ที่จะบันทึกในตัวแปรชั่วคราว: ก่อนที่จะบันทึกการใช้แมโคร:let saveReg=getreg('"')เพื่อบันทึกการลงทะเบียนและเมื่อการกระทำเสร็จแล้วใช้:call setreg('"', saveReg)เพื่อให้รีจิสเตอร์กลับสู่สถานะก่อนหน้า

อย่างไรก็ตามฉันต้องยอมรับว่าวิธีนี้เป็นวิธีแก้ปัญหาที่รวดเร็วและไม่เหมาะสมที่สุด: ในความเห็นของฉันคำตอบของ Christan เป็นคำตอบที่ดีที่สุดและควรได้รับการยอมรับเพราะไม่ยุ่งกับบัฟเฟอร์และเครื่องหมายไม่บังคับให้ผู้ใช้สร้าง ฟังก์ชั่นและแสดงพลังของคำสั่งทั่วโลก

ฉันเพิ่งเห็นคำถามที่คล้ายกันอื่นและการแก้ปัญหาประกอบด้วย:

ข้ามไปที่กลางบวกหนึ่ง:

Mj

และเรียกใช้:

:,$g/./exe 'm' 2*line('.')-line('$')-1