ฉันจะหยุด Vim ไม่ให้เขียนไฟล์โดยไม่เกิดข้อผิดพลาดได้อย่างไร

ฉันพยายามปรับปรุงรหัสจากคำตอบนี้เพื่อขอการยืนยันก่อนสร้างไดเรกทอรีที่ขาดหายไปนี่คือสิ่งที่ฉันเขียน:

function! CreateDirectoryAskConfirmation(path)
    if !isdirectory(a:path)
        echohl Question
        echo "Create directory " . a:path . "?"
        echohl None

        let response = nr2char(getchar())
        if response ==? "y"
            call mkdir(a:path, "p")
        endif
    endif
endfunction

autocmd BufWritePre * call CreateDirectoryAskConfirmation(expand("<afile>:p:h"))

สิ่งหนึ่งที่ฉันหายไป: เมื่อฉันไม่กดyที่พรอมต์ฉันต้องการให้ Vim ยกเลิกการเขียนดังนั้นฉันจึงไม่ได้รับข้อผิดพลาดE212: Can't open file for writingและฉันไม่จำเป็นต้องกดปุ่มอื่นเพื่อให้ข้อความแสดงข้อผิดพลาดหายไป มีวิธีที่จะบรรลุเป้าหมายนี้หรือไม่?

แทนที่จะใช้BufWritePreautocmd คุณสามารถใช้BufWriteCmd autocmd ได้จาก:help BufWriteCmd:

ควรเขียนไฟล์และรีเซ็ต 'แก้ไข' หากทำได้สำเร็จเว้นแต่ '+' อยู่ใน 'cpo' และเขียนไปยังไฟล์อื่น cpo- +

เราสามารถโทร:writeจาก autocmd modifiedนี้จะดูแลของการตั้งค่า

ดังนั้นตรรกะจะถูกปรับเปลี่ยนให้เรียก:writeเมื่อไดเรกทอรีมีอยู่แล้วและโทร:writeหลังจากสร้างไดเรกทอรีหากยังไม่มี ถ้าคุณกดnเราไม่ทำอะไรเลย สิ่งนี้จะทำให้บัฟเฟอร์ตามเดิมและจะไม่ถูกตั้งค่าmodifiedใหม่ดังนั้น:qจะยังคงมีE37: No write since last changeข้อผิดพลาด

function! CreateDirectoryAskConfirmation(path, dir)
    silent doautocmd BufWritePre

    " Directory exists, :write and return
    if isdirectory(a:dir)
        execute 'write ' . a:path
        silent doautocmd BufWritePost
        return
    endif

    " Ask for confirmation to create this directory
    echohl Question
    echo "Create directory `" . a:dir . "' [y/N]?"
    echohl None

    let response = nr2char(getchar())
    " mkdir() and :write if we want to make a directory
    if response ==? "y"
        call mkdir(a:dir, "p")
        execute 'write ' . a:path
        silent doautocmd BufWritePost
    endif
endfunction

autocmd BufWriteCmd * call CreateDirectoryAskConfirmation(expand("<amatch>:p"), expand("<amatch>:p:h"))