ฉันใช้ฟังก์ชั่นนี้เป็นส่วนใหญ่:
cf() {
cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}
คุณสามารถกำหนดทางลัดให้กับสคริปต์เช่นเดียวกับด้านล่าง
ใช้แท็บที่มีอยู่ซ้ำหรือสร้างหน้าต่างใหม่ (เทอร์มินัล):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if (exists window 1) and not busy of window 1 then
do script "cd " & quoted form of p in window 1
else
do script "cd " & quoted form of p
end if
activate
end tell
ใช้แท็บที่มีอยู่ซ้ำหรือสร้างแท็บใหม่ (เทอร์มินัล):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if not (exists window 1) then reopen
activate
if busy of window 1 then
tell application "System Events" to keystroke "t" using command down
end if
do script "cd " & quoted form of p in window 1
end tell
สร้างแท็บใหม่เสมอ (iTerm 2):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
if exists current terminal then
current terminal
else
make new terminal
end if
tell (launch session "Default") of result to write text "cd " & quoted form of p
activate
end tell
สองสคริปต์แรกมีข้อได้เปรียบเล็กน้อยเมื่อเปรียบเทียบกับบริการที่เพิ่มใน 10.7:
- ณ วันที่ 10.9 มีข้อผิดพลาดที่บริการที่รับโฟลเดอร์เป็นอินพุตจะไม่แสดงรายการในเมนูบริการในมุมมองคอลัมน์ หากคุณกำหนดแท็บ Terminal ใหม่ที่โฟลเดอร์บริการแป้นพิมพ์ลัดจะไม่สามารถใช้งานได้ในมุมมองคอลัมน์
- พวกเขาใช้โฟลเดอร์บนแถบชื่อเรื่องแทนที่จะกำหนดให้คุณเลือกโฟลเดอร์ก่อน
- มันจะใช้แท็บที่อยู่ข้างหน้าถ้าไม่ว่างเช่นการรันคำสั่งการแสดง man page หรือการรัน emacs
หากคุณใช้ 10.7 หรือ 10.8 เปลี่ยนtell application "Finder" to set p to POSIX path of (insertion location as alias)เป็น:
tell application "Finder"
if exists Finder window 1 then
set p to POSIX path of (target of Finder window 1 as alias)
else
set p to POSIX path of (path to desktop)
end if
end tell
มีข้อผิดพลาดใน 10.7 และ 10.8 (แต่ไม่ใช่ใน 10.9 หรือ 10.6) ที่ Finder ข้ามหน้าต่างที่สร้างขึ้นหลังจากการโฟกัสครั้งล่าสุดถูกย้ายไปยังแอปพลิเคชันอื่นและกลับมาเมื่อรับinsertion locationคุณสมบัติ
