การเพิ่มที่คั่นหน้าสำหรับหลายแท็บใน Safari ด้วยแป้นพิมพ์ลัด

ใน Safari มี Add Bookmarks for These N Tabs… ฟังก์ชัน น่าเสียดายที่คุณไม่สามารถสร้างแป้นพิมพ์ลัดได้เนื่องจากสิ่งเหล่านั้นจำเป็นต้องตรงกับชื่อของรายการเมนู

คุณสามารถใช้ Applescript นี้ มันสร้างเชลล์สคริปต์ที่มีลิงค์สำหรับแท็บทั้งหมดในหน้าต่าง Safari ปัจจุบัน:

-- Set the default folder to Home -> bookmarks
set bookmarkFolder to "/bookmarks"
set username to do shell script "whoami"
set defaultFolder to POSIX file ("/Users/" & username & bookmarkFolder)

-- Initialize the text ot the script.
set cmd to "#!/bin/bash" & linefeed & linefeed

-- Add commands to open all the tabs.
tell application "Safari"
    set n to count of tabs in front window
    repeat with i from 1 to n
        set cmd to cmd & "open -g " & URL of tab i of front window & linefeed
    end repeat
end tell

-- Open/create a file and save the script.

tell me
    activate
    set scriptAlias to choose file name default name "tabset" default location (defaultFolder as alias)
end tell
set scriptPath to quoted form of POSIX path of scriptAlias
set scriptFile to open for access scriptAlias with write permission
set eof scriptFile to 0
write cmd to scriptFile starting at eof
close access scriptFile

-- Change the file attributes to make it double-clickable.
do shell script "chmod 777 " & scriptPath
do shell script "xattr -wx com.apple.FinderInfo '00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00' " & scriptPath

รุ่นเดิมคือโดย Drang .

ฉันเปลี่ยนสองสิ่ง:

• สคริปต์อนุญาตให้มีช่องว่างในชื่อไฟล์
• โฟลเดอร์เริ่มต้นคือ ~/bookmarks

หากต้องการเรียกใช้คุณสามารถใช้ตัวเรียกใช้งาน (เช่น Quicksilver หรือ Butler ) หรือห่อใน System Service กับ Automator:

• สร้างบริการ
  • เพิ่ม Run Applescript ชิ้น
  • เลือก Service receives ไม่มีการป้อนข้อมูล in การแข่งรถวิบาก
  • วาง Applescript
• สร้างทางลัดใน System Preferences > Keyboard > Shortcuts > Services
  • ⌘⌥D ไม่ทำงานหากคุณใช้เพื่อสลับการมองเห็น Dock