มีวิธีสร้างสไลด์โชว์ของวิดีโอและรูปภาพทั้งหมดที่อยู่ในโฟลเดอร์เดียวหรือไม่?

ฉันกำลังตั้งค่าสไลด์โชว์พื้นที่ค้าปลีก นึกคิดฉันต้องการมีโฟลเดอร์วิดีโอและรูปภาพที่สามารถเพิ่มหรือลบออกจากและจะอัปเดตสไลด์โชว์ คล้ายกับสกรีนเซฟเวอร์สไลด์โชว์ แต่มีความจุวิดีโอ มีแอพที่จะทำสิ่งนี้หรือสิ่งที่สคริปต์?

1. เปิด/Applications/Photos.appและไปที่ไฟล์> อัลบั้มใหม่
2. สร้างอัลบั้มใหม่ด้วยชื่อ "Store Display"
3. เปิด /Applications/Utilities/Script Editor.app
4. คัดลอกและวางสคริปต์ด้านล่าง
5. ไปที่ไฟล์> ส่งออก
   • รูปแบบไฟล์: แอปพลิเคชัน
6. เปิดแอปพลิเคชัน
7. เลือกโฟลเดอร์ของคุณที่มีรูปถ่ายและวิดีโอ
8. คลิกเลือก
9. ฉลอง!

นี่คือรหัส (แก้ไขโดย @ wch1zpink):

set imageNameExtensions to {"jpg", "jpeg", "png", "tiff", "bmp", "gif"}
set videoNameExtensions to {"mov", "mp4", "m4v", "avi"}
set nameExtensions to (videoNameExtensions & imageNameExtensions)

set myFolder to (choose folder) as text

set theChoice to display dialog ¬
    "Select Your Option" buttons {"Cancel", "Main Folder", "Main Folder And Sub-Folders"} ¬
    default button 3 ¬
    cancel button 1 ¬
    with title ¬
    "CHOOSE A FOLDER" giving up after 30

if button returned of theChoice is "Main Folder And Sub-Folders" then
    tell application "Finder"
        set mediaItems to (files of (entire contents of folder myFolder) ¬
            whose name extension is in nameExtensions) as alias list
    end tell
else if button returned of theChoice is "Main Folder" then
    tell application "Finder"
        set mediaItems to (files of (folder myFolder) ¬
            whose name extension is in nameExtensions) as alias list
    end tell
end if

tell application "Photos"
    import mediaItems into container named "Store Display" with skip check duplicates
    start slideshow using media items of album "Store Display"
end tell