รหัส AppleScript นี้ใช้ได้กับฉันโดยใช้ macOS Mojave เวอร์ชันล่าสุด
รหัสนี้จะวนซ้ำทุกรายการในถังขยะโดยวางแต่ละรายการกลับไปที่ตำแหน่งเดิม
หากโฟลเดอร์ต้นฉบับดั้งเดิมของไฟล์ในถังขยะไม่มีอยู่อีกต่อไปrepeat until trashCount is 0คำสั่งจะออกจากลูป ไฟล์ที่เหลืออยู่ในถังขยะจะเป็นไฟล์ที่ไม่สามารถนำกลับมาได้เนื่องจากเหตุผลนี้
UPDATE
เนื่องจากเป็นไปได้ที่จะเลือกรายการบนเดสก์ท็อปของคุณในระหว่างวนซ้ำของกระบวนการนำไฟล์กลับมาจากถังขยะรายการเดสก์ท็อปที่เลือกสามารถติดตามในกระบวนการและย้ายไปที่ถังขยะ เพื่อหลีกเลี่ยงสถานการณ์นี้ฉันได้เพิ่มรหัสซึ่งจะล็อครายการเดสก์ท็อปที่ถูกปลดล็อคในปัจจุบันและจะปลดล็อคพวกเขาในตอนท้ายของสคริปต์
เนื่องจากรายการเดสก์ท็อปทั้งหมดถูกล็อค ... ในระหว่างขั้นตอนการนำไฟล์กลับมาจากถังขยะหากด้วยเหตุผลบางประการคุณบังเอิญเลือกไฟล์หรือโฟลเดอร์บนเดสก์ท็อปของคุณและรหัสพยายามประมวลผลรายการเดสก์ท็อปที่เลือก ... สร้างหน้าต่างข้อความที่กล่าวถึงรายการที่ถูกล็อคและถามว่าคุณต้องการส่งต่อไปยังถังขยะหรือไม่ เหตุการณ์ของระบบบอกบล็อกต่อท้ายสคริปต์จะจัดการกล่องโต้ตอบใด ๆ ที่อาจถูกสร้างขึ้น
property desktopFolder : path to desktop
property unlockedFiles : missing value
tell application "Finder"
set trashCount to count of every item of trash
set unlockedFiles to (items of desktopFolder whose locked is false)
repeat with i in unlockedFiles
set locked of i to true
end repeat
end tell
repeat until trashCount is 0
tell application "Finder" to set orphanCount to count of every item of trash
putFilesBack()
tell application "Finder" to set trashCount to count of every item of trash
if orphanCount is equal to trashCount then exit repeat
end repeat
delay 1
tell application "System Events"
repeat until not (exists of button "Stop" of scroll area 1 of window 2 of application process "Finder")
if exists of button "Stop" of scroll area 1 of window 2 of application process "Finder" then
click button "Stop" of scroll area 1 of window 2 of application process "Finder"
end if
end repeat
end tell
tell application "Finder"
close every Finder window
delay 1
repeat with i in unlockedFiles
set locked of i to false
end repeat
end tell
on putFilesBack()
global trashFiles, trashCount, thisItem
tell application "Finder"
set trashFiles to every item of trash
set frontmost to true
repeat while not frontmost
delay 0.1
end repeat
my closeFinderWindows()
end tell
delay 0.1
tell application "System Events"
tell application process "Finder"
repeat with i from 1 to count of trashFiles
set thisItem to item i of trashFiles
delay 0.1
set frontmost to true
select thisItem
delay 0.1
try
key code 51 using {command down}
end try
delay 0.1
my closeFinderWindows()
delay 0.1
end repeat
end tell
end tell
tell application "Finder" to set trashCount to count of every item of trash
end putFilesBack
on closeFinderWindows()
tell application "Finder"
set finderWindowRef to (a reference to (every Finder window whose name is not "Trash"))
set finderWindowRef to contents of finderWindowRef
close (items of finderWindowRef)
end tell
end closeFinderWindows