มีวิธีให้ AppleScript แสดงผลในแถบเมนูหรือไม่?

ก่อนที่จะอ่านเพิ่มเติม: ฉันรู้เกี่ยวกับบัตเลอร์และโปรแกรมที่คล้ายกัน ฉันกำลังมองหาวิธีที่จะทำสิ่งนี้โดยไม่ต้องใช้แอพของบุคคลที่สาม

อย่างไรก็ตามฉันเขียน AppleScript ที่รันคำสั่งเชลล์ ฉันต้องการแสดงผลลัพธ์นั้นในแถบเมนูด้านบน ... โดยไม่มีบัตเลอร์ฉันจะทำสิ่งนี้ได้อย่างไร

โดยทั่วไปแล้วหากไม่มีโปรแกรมของบุคคลที่สามเช่น Growl จึงไม่มีวิธีสร้างสิ่งนี้

อย่างไรก็ตามคุณสามารถเขียนสคริปต์หรือโปรแกรมอื่น ๆ เช่นที่ฉันพบที่นี่ที่ให้บริการเมนูสำหรับคุณ ฉันแน่ใจว่าการรวมเข้าด้วยกันของ Growl จะทำได้ง่ายกว่ามาก

ไม่มีวิธีในการทำสิ่งนี้ใน OS X อย่างไรก็ตามเมื่อใช้Growlคุณสามารถมีการแจ้งเตือนได้ นี่เป็นสคริปต์ตัวอย่างสำหรับสิ่งนั้น:

--Make sure Growl is running
tell application "System Events"
    set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
end tell

if isRunning then
    tell application id "com.Growl.GrowlHelperApp"
        set the allNotificationsList to ¬
            {"Test Notification", "Another Test Notification"}
        --Notifications can be enabled in System Preferences>Growl>Applications>Display Options
        set the enabledNotificationsList to ¬
            {"Test Notification"}
        register as application ¬
            "Growl AppleScript Sample" all notifications allNotificationsList ¬
            default notifications enabledNotificationsList ¬
                    -- Set the icon. You can use any icon from any application
            icon of application "AppleScript Editor"

        notify with name ¬
            "Test Notification" title ¬
            "Test Notification" description ¬
            "This is a test AppleScript notification." application name "Growl AppleScript Sample"

        notify with name ¬
            "Another Test Notification" title ¬
            "Another Test Notification :) " description ¬
            "Alas — you won't see me until you enable me..." application name "Growl AppleScript Sample"

    end tell
end if

ที่ควรแสดงสิ่งนี้:

และหากคุณเปิดใช้งานการแจ้งเตือนอื่นด้วย:

เทคนิคขั้นสูงเพิ่มเติมได้อธิบายไว้ที่นี่

เนื่องจากAppleScriptObjCเป็นส่วนหนึ่งของ macOS จึงเป็นไปได้ที่จะใช้เฟรมเวิร์ก "พื้นฐาน" (รวมถึงวิธีการของ NSMenu) เพื่อให้บรรลุสิ่งที่อาจเป็นไปไม่ได้ในปี 2555

ฉันพบสคริปต์ที่น่าสนใจในการสร้างเมนูที่กำหนดเองจากภายใน AppleScript; จากนี้ฉันสกัดรหัสที่เหมาะสมกับข้อความที่เกิดขึ้นในแถบเมนูของ MacOS อันที่จริงมันใช้เพียงแค่ "ชื่อ" ของเมนูเพื่อแทรกเนื้อหาบางอย่าง

เพื่อแสดงให้เห็นถึงสิ่งนี้ฉันได้ติดตั้งสคริปต์โต้ตอบพื้นฐานที่ขอให้ผู้ใช้ป้อนข้อความ (รอ 6 วินาที) ซึ่งจะปรากฏในแถบเมนูชั่วคราว (5 วินาที)
นี่มันคือ:

use framework "Foundation"
use framework "AppKit"
use scripting additions
property StatusItem : missing value
property newMenu : class "NSMenu"

display dialog "Write something:" default answer "" giving up after 6
set myText to text returned of the result
if myText is "" then set myText to "TOOOOO slow … try again !"
set myText to ">>    " & myText & "    <<"

set bar to current application's NSStatusBar's systemStatusBar
set StatusItem to bar's statusItemWithLength:-1.0
StatusItem's setTitle:myText
set newMenu to current application's NSMenu's alloc()'s initWithTitle:"Custom"
StatusItem's setMenu:newMenu

delay 5
current application's NSStatusBar's systemStatusBar()'s ¬
        removeStatusItem:StatusItem  

รหัส AppleScript นี้สามารถใช้ในสคริปต์ใด ๆ ของคุณ (ส่วน "โต้ตอบ" เป็นตัวเลือก…)

user3439894 ช่วยด้วยการปิด "เมนู" ของฉันดูบรรทัดสุดท้ายของสคริปต์ ขอบคุณมาก!