วางตำแหน่งไอคอนเดสก์ท็อปทางด้านซ้ายแทนขวา

วิธีใดก็ตามที่จะสร้างนามแฝงหรือไอคอนให้แสดงที่ด้านซ้ายของเดสก์ท็อป Apple โดยอัตโนมัติ โดยค่าเริ่มต้นพวกเขาไปทางขวา

ไม่มีวิธีบังคับให้ไอคอนไปทางซ้ายโดยอัตโนมัติ (และจัดเรียงตามเกณฑ์ที่คุณเลือก)

คุณสามารถเปลี่ยนตัวเลือกมุมมองในตัวค้นหาเพื่อไม่จัดเรียงรายการตามเกณฑ์และวางไอคอนด้วยตนเองทางซ้าย

• คลิกที่พื้นที่ว่างบนเดสก์ท็อป
• กดCmd+ Jหรือใช้เมาส์ไปที่การค้นหาของมุมมอง> แสดงตัวเลือกมุมมองเมนู
• ในการเรียงลำดับโดย:เลื่อนลงในกล่องโต้ตอบให้เลือกอย่างใดอย่างหนึ่งไม่มีหรือSnap เพื่อกริด
• คุณจะสามารถวางไฟล์ได้ทุกที่บนเดสก์ท็อปของคุณและไฟล์จะอยู่ที่นั่น

ดูMac Basics: ปรับเปลี่ยน windows ของคุณสำหรับข้อมูลเพิ่มเติม

ไปยังหน้าMac Basicsเพื่อเรียนรู้เพิ่มเติมเกี่ยวกับการใช้ Mac

นี่ไม่ใช่ทางออกที่ดีที่สุด แต่สามารถใช้งานได้หากไม่มีสิ่งใดที่ ...

1. สร้าง Automator Folder Action ที่เกี่ยวข้องกับเดสก์ท็อป
2. เพิ่มรายการ: "เรียกใช้ applescript"

3. วางรหัสต่อไปนี้ในกล่องข้อความ applescript:

   -- https://gist.github.com/mrienstra/8330528
   -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
   -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
   
   -- Rearranges Desktop icons to flow from left to right, top to bottom.
   
   -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
   
   -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
   
   -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
   
   
   
   -- Adjust these for different spacing
   property theSpacingFactor : 1.0
   property theGutterXFactor : 0.57
   property theGutterYFactor : 0.57
   
   
   
   on rearrangeDesktopIcons()
       tell application "Finder"
           tell icon view options of window of desktop
               set theArrangement to arrangement
               set theArrangementString to theArrangement as string
               if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                   display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                   return
               end if
               set theIconSize to icon size
               set theLabelSize to text size
           end tell
   
           set theDesktopBounds to bounds of window of desktop
           set theDesktopWidth to item 3 of theDesktopBounds
           set theDesktopHeight to item 4 of theDesktopBounds
   
           -- Retrieve a list of items on the desktop
           set theDesktopItems to every item of desktop
           set theContestantOffset to theIconSize / 2
   
           set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
           set theGuttersX to theSpacing * theGutterXFactor
           set theGuttersY to theSpacing * theGutterYFactor
           set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
           set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
           set theMaxLocations to theMaxRows * theMaxColumns
   
           set y to 1
           repeat with a from 1 to length of theDesktopItems
               set x to a mod theMaxColumns
               if x is 0 then
                   set x to theMaxColumns
               end if
   
               if a is greater than theMaxLocations then
                   set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
               else
                   set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
               end if
   
               if a mod theMaxColumns is 0 then
                   set y to y + 1
               end if
           end repeat
       end tell
   end rearrangeDesktopIcons
   
   
   
   on adding folder items to alias after receiving listOfAlias
       rearrangeDesktopIcons()
   end adding folder items to
   
   on removing folder items from alias after losing listOfAliasOrText
       rearrangeDesktopIcons()
   end removing folder items from
   
   rearrangeDesktopIcons()
   

ดังนั้นเมื่อใดก็ตามที่มีการเพิ่มไฟล์ไปยังเดสก์ท็อปของคุณไฟล์ทั้งหมดจะถูกจัดเรียงใหม่ตามตัวอักษร ...

จัดระเบียบโฟลเดอร์ทั้งหมดตามลำดับที่คุณต้องการ จากนั้นภายใต้มุมมอง 'การล้างข้อมูล' สิ่งนี้จะจัดแนวทุกอย่างไว้อย่างดี จากนั้นคุณสามารถไฮไลต์โฟลเดอร์ทั้งหมดและจัดตำแหน่งให้ตรงตามที่คุณต้องการ Macs ไม่จัดระเบียบโฟลเดอร์ทางด้านซ้ายเพียงขวา แต่ด้วยขั้นตอนง่าย ๆ สองขั้นตอนคุณสามารถจัดระเบียบทุกอย่างได้อย่างเรียบร้อยทางด้านซ้าย

ฉันเพิ่งไฮไลต์โฟลเดอร์ทั้งหมดจากด้านขวามือจากนั้นก็คว้ามันทั้งหมดแล้ววางไปทางซ้าย