สร้างไฟล์ (.txt) ใหม่ใน Finder - แป้นพิมพ์ลัด

ฉันต้องการทราบว่ามีวิธีตั้งค่าแป้นพิมพ์ลัดเพื่อสร้างไฟล์ใหม่ใน Finder หรือไม่ ตัวอย่างเช่นโดยการเริ่มต้นคุณสามารถสร้างโฟลเดอร์ใหม่โดยใช้CMD+ +Shift Nมีแป้นพิมพ์ลัดเพื่อสร้างไฟล์ข้อความใหม่หรือไม่? ฉันเป็นโปรแกรมเมอร์ดังนั้นมันจะมีประโยชน์มาก

ฉันยังสนใจที่จะสร้างไฟล์ประเภทอื่นโดยใช้แป้นพิมพ์ลัด

ฉันพยายามใช้ระบบอัตโนมัติ แต่ฉันพบว่ามันค่อนข้างสับสนและฉันไม่แน่ใจว่าจะเชื่อมต่อแป้นพิมพ์ลัดเข้ากับมันอย่างไร

คุณไปกับ AppleScript แล้ว

ก่อนอื่นให้สร้าง AppleScript:

1. เปิด Automator
2. สร้างแอคชั่นด่วน
3. ตั้งค่าอินพุตเป็นไม่มีอินพุต
4. ลากแล้วปล่อยองค์ประกอบเวิร์กโฟลว์Run AppleScriptไปยังพื้นที่สีเทา
5. วางรหัสจากด้านล่างลงใน AppleScript
6. บันทึกเวิร์กโฟลว์เป็นสร้างไฟล์ใหม่
   หากคุณเปิดใช้งาน iCloud Drive ตรวจสอบให้แน่ใจว่าคุณได้บันทึกไฟล์ไว้Library/Services/ใน Home Folder ของคุณ

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

หากต้องการเพิ่มเป็นช็อตคัท:

• ไปที่การตั้งค่าระบบ -> คีย์บอร์ด -> ทางลัด -> บริการ
• เลื่อนลงจนกว่าคุณจะพบบริการสร้างไฟล์ใหม่
• กำหนดทางลัดไปโดยคลิกที่ด้านขวาไม่มีใครAdd Shortcutที่จะกลายเป็น
  คลิกปุ่มและพิมพ์ทางลัดที่คุณต้องการใช้
  ฉันใช้⌘ Command+ ⌥ Option+N

ฉันได้สร้าง AppleScript คล้ายกับของ @ YoshiBotX แต่มีการปรับปรุงบางอย่าง

แนวคิดคือการสร้างเวิร์กโฟลว์อัตโนมัติและกำหนดทางลัดให้กับมันโดยใช้ขั้นตอนต่อไปนี้:

• เปิดอัตโนมัติและสร้างบริการ ;
• ตั้งค่าการป้อนข้อมูลเพื่อการป้อนข้อมูลไม่มีและการประยุกต์ใช้ในการFinder.app ;
• ลากแล้วปล่อยองค์ประกอบเวิร์กโฟลว์Run AppleScriptไปยังพื้นที่สีเทา
• ใส่เนื้อหาของ AppleScript นี้ลงในกล่องข้อความ
• บันทึกเวิร์กโฟลว์ด้วยชื่อที่สมเหตุสมผล (เช่นไฟล์ใหม่ );
• ไปที่การตั้งค่า -> แป้นพิมพ์ -> ทางลัด -> บริการและกำหนดทางลัดให้

ตอนนี้เรามาแสดง AppleScript:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

เพื่อความสะดวกฉันกำลังใส่ AppleScript นี้ในGitHub Gistนี้

คุณสามารถสร้างบริการอัตโนมัติได้ด้วยตัวเอง - มันค่อนข้างง่ายที่จะทำ จากนั้นคุณสามารถกำหนดแป้นพิมพ์ลัดให้กับมันเพื่อให้คุณไม่จำเป็นต้องเปิดใช้งานบริการผ่านเมนูบริการ (ซึ่งคุณสามารถทำได้)

เปิด Automator และเลือก Service เป็นประเภทเอกสารใหม่

ตั้งค่าบริการเพื่อไม่รับอินพุตใน Finder.app และเพิ่มแอคชัน TextEdit New Document ให้กับเวิร์กโฟลว์

บันทึกบริการจากนั้นเปิดการตั้งค่าระบบ→แป้นพิมพ์→ทางลัด→บริการที่คุณจะพบบริการตามรายการทั่วไปที่มีชื่อที่คุณให้สำหรับบริการเมื่อคุณบันทึกไว้

เพิ่มแป้นพิมพ์ลัดลงในบริการโดยเลือกบริการจากนั้นคลิก 'เพิ่มทางลัด'

ที่นี่คุณอาจมีปัญหาหากใช้ทางลัดอยู่แล้ว ดังนั้นจงใช้ความคิดสร้างสรรค์ในการสร้างสิ่งที่เหมาะกับคุณ

คุณสามารถกำหนดทางลัดให้กับสคริปต์เช่นนี้:

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

ตำแหน่งการแทรกเป็นเป้าหมายของหน้าต่าง Finder ที่อยู่ข้างหน้าสุดหรือเดสก์ท็อป

เปิดเทอร์มินัลและประเภท

touch filename

หรือ

> filename

นี่คือการโพสต์ซ้ำของโพสต์ที่ฉันทำเมื่อปี ฉันมีประสบการณ์ที่ดีดังต่อไปนี้

มียูทิลิตี้ที่มีประโยชน์สองตัวที่คุณสามารถดาวน์โหลดและติดตั้งซึ่งจะช่วยให้คุณสร้างไฟล์ข้อความใหม่ (หรือไฟล์ RTF) ในโฟลเดอร์ที่เปิดอยู่ในปัจจุบันที่คุณกำลังดูโดยใช้ Finder

ยูทิลิตีนี้เรียกว่า NewTextFileHere และ NewRTF ที่นี่และสามารถดาวน์โหลดได้

http://mac.softpedia.com/developer/Jonas-Wisser-37498.html

ไอคอนสำหรับแอปเหล่านี้สามารถรวมอยู่ในหน้าต่าง Finder ทั้งหมดของคุณ

Richard Fuhr ที่ฉันต้องการ ขอบคุณสำหรับสิ่งนี้.

One note: ลิงค์ของ URL สำหรับ NewTextFileHere ดูเหมือนว่าจะโหลดไปยังหน้าว่าง แต่ฉันค้นหาและพบแอปที่นี่: http://mac.softpedia.com/progDownload/NewTextFileHere-Download-70374.html

อีกทางเลือกหนึ่งถ้าคุณมีBetterTouchToolsอยู่แล้ว(เคยเป็นแอปฟรีตอนนี้มันมีรุ่นจ่ายตามที่คุณต้องการด้วยระยะเวลาทดลองใช้ 30 วัน) คุณสามารถค้นหาการกระทำ"Utility Actions > Create New File in Current Folder"ที่ทำสิ่งนี้ด้วย ป๊อปอัปเพื่อให้คุณเลือกชื่อ กำหนดทางลัดที่คุณต้องการ (ฉันเลือก Option + Shift + N) และคุณก็พร้อมที่จะไป

ในกรณีที่คุณใช้MacVimมีตัวเลือกFinder -> Servicesในการสร้าง vim buffer ใหม่:

ฉันได้แมปนี้กับทางลัดShiftcmdMในSystem Preferences -> Keyboard -> Shortcuts: