ฉันจะเริ่มการปล่อยสัญญาณ Bluetooth โดยใช้บรรทัดคำสั่งได้อย่างไร


8

ฉันต้องการวิธีที่รวดเร็วในการเริ่มแชร์อินเทอร์เน็ตโดยใช้ iPhone ของฉันหวังว่าเพียงแค่ใช้แป้นพิมพ์ เมื่อใช้เมนูบลูทู ธ ฉันสามารถเลือกตัวเลือกเชื่อมต่อกับเครือข่ายในเมนูย่อยสำหรับอุปกรณ์ของฉัน แต่เป็นไปได้ไหมที่จะทำสิ่งนี้โดยอัตโนมัติ?

ในที่สุดฉันต้องการกำหนดสิ่งนี้ให้กับทางลัดใน (สุดยอดมาก) Alfred.app แต่สิ่งใดก็ตามที่ใช้บรรทัดคำสั่งมิฉะนั้น AppleScript จะทำงาน

เป็นไปได้ไหม ขอบคุณ !!

คำตอบ:


3

ดูเหมือนว่าจะไม่มีพจนานุกรม AppleScript โดยตรงสำหรับการทำงานกับบลูทู ธ ด้วยวิธีนี้

คุณสามารถใช้ GUI สคริปต์ได้ซึ่งโดยทั่วไปจะใช้คุณสมบัติการช่วยสำหรับการเข้าถึงของ Mac OS เพื่อเลือกรายการเมนู ฯลฯ

เขียนขึ้นที่ดีในการเริ่มต้นด้วย GUI AppleScript มีอยู่ในMacOSAutomation.com

ระบบอัตโนมัติ GUI อาจเป็นเรื่องยากหากคุณมีรายการสิ่งที่เปลี่ยนแปลงอยู่ตลอดเวลา แต่หากคุณมีรายการเชื่อมต่อบลูทู ธ ที่ยังคงเหมือนเดิมคุณควรจะยอมรับ

จากนั้นคุณสามารถเรียก AppleScript นี้ผ่าน Alfred


1

http://macscripter.net/viewtopic.php?id=38559

ในลิงค์ด้านบนมีสคริปต์ที่ดีมากที่ฉันเพิ่งปรับปรุงเล็กน้อย โปรดทราบว่ามันใช้ blueutil [ git repo ] [ เว็บไซต์ / ไบนารี ]

เปิดใช้งานบลูทู ธ :

-- Enable Bluetooth and Connect to iPhone

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn on bluetooth.
if execBlueutil("status") contains "Status: off" then
    execBlueutil("on")

    connectDevice()

    doGrowl()

end if

on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

-- Connect Device
on connectDevice()
    tell application "System Preferences"
        activate
        set AppleScript's text item delimiters to "."
        set current pane to pane "com.apple.preference.network"
        set winNetwork to "Network"
        set btooth to "Bluetooth"

        tell application "System Events" to tell process "System Preferences"
            set theRow to row 1 of table 1 of scroll area 1 of window winNetwork whose value of static text 1 contains btooth
            select theRow --clicks the bluetooth row
            --If Bluetooth is already connected, the button will say Disconnect, so we don't want to turn it off:
            try
                click (button 1 of group 1 of window winNetwork whose title is "Connect")
            end try
        end tell
        tell application "System Preferences"
            quit
        end tell
    end tell
end connectDevice

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth is On & iPhone Connected" description ¬
                "Bluetooth has been enabled with iPhone tethered." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

ปิดการใช้งานบลูทู ธ :

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn off Bluetooth.
if execBlueutil("status") contains "Status: on" then
    execBlueutil("off")

    doGrowl()
end if
on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth Off" description ¬
                "Bluetooth has been disabled." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

0

ฉันอยากจะแนะนำให้ใช้ระบบอัตโนมัติสำหรับสิ่งนี้คุณสามารถโทรหาจาก Alfred เพื่อให้ง่าย :)

กระบวนการทำงานอัตโนมัติของฉันในปัจจุบันทำสิ่งนี้:

Click the "bluetooth" menu bar item.
Connect to Network

ใช้วิธีนี้คุณสามารถเกือบทุกอย่างอัตโนมัติภายในหนึ่งนาที

โดยการใช้ไซต์ของเรา หมายความว่าคุณได้อ่านและทำความเข้าใจนโยบายคุกกี้และนโยบายความเป็นส่วนตัวของเราแล้ว
Licensed under cc by-sa 3.0 with attribution required.